#include <MsgBoxConstants.au3>
#include <misc.au3>

opt("WinTitleMatchMode", 4)

; ********** Configuration **********
Global $__BUFFS[4] =  ["Purity of Fire", "Purity of Ice", "Vitality", "Clear"]

Global $__MOUSE_SPEED_FASTEST = 3
Global $__MOUSE_SPEED_SLOWEST = 5
Global $__BUFF_BTN[2] = [1660, 1045]
Global $__BUFF_BTN_KEYBIND = "{F4}"
Global $__FLASK_KEYS[4] = ["4", "3", "5", "2"]

Global Const $__WAIT_MIN_DELAY = 100
Global Const $__WAIT_MAX_DELAY = 150
Global Const $__GAME_WINDOW_TITLE = "Path of Exile"
Global Const $__CONFIG_FILE = "config.ini"

; ********** Bind keys **********
HotKeySet("{F5}", "ActivateBuffs")
HotKeySet("{§}", "ActivateFlasks")
HotKeySet("{F8}", "ConfigureBuffs")

; ********** Internal variables - Do not touch! **********
Global $gameWindowHandle = WinGetHandle($__GAME_WINDOW_TITLE)

; ********** Start of program **********
While 1
   ;Avoid CPU overload
   Sleep(100)
WEnd

Func ActivateBuffs()
    If WinGetTitle("[ACTIVE]") == $__GAME_WINDOW_TITLE Then
        For $i = 0 to UBound($__BUFFS) - 1
            Local $buffX = IniRead($__CONFIG_FILE, $__BUFFS[$i], "X", 0)
            Local $buffY = IniRead($__CONFIG_FILE, $__BUFFS[$i], "Y", 0)

            MouseClick("left", $__BUFF_BTN[0], $__BUFF_BTN[1], 1, Random($__MOUSE_SPEED_FASTEST, $__MOUSE_SPEED_SLOWEST, 1))
            Sleep(Random($__WAIT_MIN_DELAY, $__WAIT_MAX_DELAY, 1))
            MouseClick("left", $buffX, $buffY, 1, Random($__MOUSE_SPEED_FASTEST, $__MOUSE_SPEED_SLOWEST, 1))
            Sleep(Random($__WAIT_MIN_DELAY, $__WAIT_MAX_DELAY, 1))
            Send($__BUFF_BTN_KEYBIND)
            Sleep(Random($__WAIT_MIN_DELAY, $__WAIT_MAX_DELAY, 1))
        Next
    EndIf
EndFunc

Func ActivateFlasks()
   If WinGetTitle("[ACTIVE]") == $__GAME_WINDOW_TITLE Then
        For $i = 0 to UBound($__FLASK_KEYS) - 1
            Send($__FLASK_KEYS[$i])
            Sleep(Random($__WAIT_MIN_DELAY, $__WAIT_MAX_DELAY, 1))
        Next
   EndIf
EndFunc

Func ConfigureBuffs()
    If WinGetTitle("[ACTIVE]") == $__GAME_WINDOW_TITLE Then
        For $i = 0 to UBound($__BUFFS) -1

            ToolTip("Mouseover " & $__BUFFS[$i] & " and Press F6")

            Do
                Sleep(100)
            Until _IsPressed(75) = 1

            $mousePos = MouseGetPos()
            IniWrite($__CONFIG_FILE, $__BUFFS[$i], "X", $MousePos[0])
            IniWrite($__CONFIG_FILE, $__BUFFS[$i], "Y", $MousePos[1])

            ToolTip("")
        Next
    EndIf
EndFunc