Advertisement
phlud

pirate.bas

Aug 20th, 2021
6,061
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. 100 REM *******************
  2. 110 REM *  PIRATE ISALND  *
  3. 120 REM *                 *
  4. 130 REM *        BY       *
  5. 140 REM *   DAVID MENY    *
  6. 150 REM *******************
  7. 160 CLS:KEY OFF:DEFINT A-Z
  8. 170 DIM A(45,6),O1$(20),O2$(20),TR(14),IN$(14),RO$(45)
  9. 171 GOSUB 20000:REM INITIALIZE
  10. 172 LOCATE 21,1
  11. 173 PRINT "Pirate Island by David Meny"
  12. 174 PRINT "Copyright 1985, Menco, Inc."
  13. 175 PRINT
  14. 176 PRINT "  In your sleep, you dream of valiant pirates who sail across the seas, finding"
  15. 177 PRINT "secret treasure hidden deep inside dangerous islands."
  16. 178 PRINT "  You dream of adventourous fights to the death between pirates over gold-laced"
  17. 179 PRINT "statues or chest of gold coins from a long time ago."
  18. 180 PRINT "  You dream and dream until the rocking of the seas wakens you on board the ship"
  19. 185 PRINT "'The Eagle's Nest', a pirate ship!":PRINT
  20. 190 GOSUB 15000:REM PRINT ROOM DESCRIPTION
  21. 200 GOSUB 14000:REM PRINT ROOM CONTENTS
  22. 210 IF START=1 THEN MV=MV+1 ELSE 219
  23. 211 IF MV=10 THEN TR(2)=RO ELSE 219
  24. 212 PRINT "The captain walks up to you."
  25. 213 IF FLAG98=1 THEN 216
  26. 214 PRINT "'You fool!! We have been sailing for days now and we haven't found Pirate":PRINT "Island. I shouldn't have trusted you, even though you are my grand son.'"
  27. 215 PRINT "The captain pulls out his cutlass and decapitates you.":GOTO 2000
  28. 216 PRINT "'Congradulations!! We've come ashore on ze' old Pirate Island. Now go ashore by":PRINT "the east starboard deck.' The captain then hands you a bag of silver."
  29. 217 PRINT "'Spend it wisely. It's your payment IF you don't come back.'":TR(2)=25:A(39,2)=22:FLAG97=1:TR(14)=200
  30. 219 PRINT:INPUT ">",A$
  31. 220 IF A$="" THEN PRINT:PRINT "What?":GOTO 210
  32. 230 AS=ASC(A$)
  33. 240 IF AS<65 OR AS>90 THEN PRINT:PRINT "I can only use capital letters, matey.":GOTO 210
  34. 245 IF A$="LOOK UNDER JULIUS" THEN GOSUB 8010:GOTO 210
  35. 246 IF A$="LOOK UNDER PIRATE ISLAND" THEN GOSUB 8150:GOTO 210
  36. 247 IF A$="LOOK UNDER DAVID MENY" THEN GOSUB 8300:GOTO 210
  37. 250 M=LEN(A$):IF M<7 THEN A$=A$+" ":GOTO 250
  38. 260 KW=0:B$=LEFT$(A$,3)
  39. 270 IF B$="INV" OR B$="I  " THEN GOSUB 1000:GOTO 210
  40. 280 IF B$="SCO" THEN GOSUB 1500:GOTO 210
  41. 285 IF B$="DIG" THEN GOSUB 2250:GOTO 210
  42. 286 IF B$="KNO" THEN GOSUB 6500:GOTO 210
  43. 290 IF B$="QUI" OR B$="Q  " THEN GOSUB 2000
  44. 300 IF B$="LOO" OR B$="L  " THEN PRINT:GOTO 190
  45. 305 IF B$="SWI" THEN GOSUB 8500:GOTO 210
  46. 310 IF B$="N  " THEN C$="N  ":KW=1:GOSUB 2500:GOTO 210
  47. 320 IF B$="S  " THEN C$="S  ":KW=1:GOSUB 2500:GOTO 210
  48. 330 IF B$="E  " THEN C$="E  ":KW=1:GOSUB 2500:GOTO 210
  49. 340 IF B$="W  " THEN C$="W  ":KW=1:GOSUB 2500:GOTO 210
  50. 350 IF B$="U  " THEN C$="U  ":KW=1:GOSUB 2500:GOTO 210
  51. 360 IF B$="D  " THEN C$="D  ":KW=1:GOSUB 2500:GOTO 210
  52. 370 N=1
  53. 380 IF MID$(A$,N,1)=" " THEN C$=MID$(A$,N+1,3):IF LEFT$(C$,1)<>" " THEN 410 ELSE 400
  54. 390 IF N<M THEN N=N+1:GOTO 380
  55. 400 PRINT:PRINT "I don't know that word.":GOTO 210
  56. 410 IF B$="GO " OR B$="MOV" OR B$="WAL" THEN KW=1:GOSUB 2500:GOTO 210
  57. 420 IF B$="GET" OR B$="TAK" THEN GOSUB 3000:GOTO 210
  58. 430 IF B$="DRO" OR B$="PUT" THEN GOSUB 3500:GOTO 210
  59. 440 IF B$="OPE" THEN GOSUB 4000:GOTO 210
  60. 450 IF B$="UNL" THEN GOSUB 4500:GOTO 210
  61. 460 IF B$="BUY" THEN GOSUB 5000:GOTO 210
  62. 480 IF B$="CLI" THEN GOSUB 6000:GOTO 210
  63. 490 IF B$="REA" THEN GOSUB 7000:GOTO 210
  64. 510 PRINT:PRINT "I don't know that word."
  65. 520 GOTO 210
  66. 1000 REM INVENTORY
  67. 1010 PRINT "  You are carrying:"
  68. 1020 PRINT
  69. 1030 FOR I=1 TO 14
  70. 1040 IF TR(I)=200 THEN PRINT "    ";IN$(I):FLAG1=1
  71. 1050 NEXT I
  72. 1060 IF FLAG1<>1 THEN PRINT "    nothing"
  73. 1070 FLAG1=0
  74. 1080 RETURN
  75. 1500 REM SCORE
  76. 1510 PRINT
  77. 1520 PRINT "Out of 200 points, you got ";SCORE;" points."
  78. 1521 PRINT "That gives you the rating of ";
  79. 1522 IF SCORE<50 THEN PRINT "a Deck boy."
  80. 1523 IF SCORE>50 AND SCORE<100 THEN PRINT "a Sea Man."
  81. 1524 IF SCORE>100 AND SCORE<150 THEN PRINT "a Bucaneer."
  82. 1525 IF SCORE>150 THEN PRINT "a Sea Captain."
  83. 1530 RETURN
  84. 2000 REM QUIT
  85. 2010 COLOR 0,7:LOCATE 25,50:PRINT "Score:";SCORE:COLOR 7,0:PRINT
  86. 2020 PRINT "Out of 200 points, you got ";SCORE;" points."
  87. 2021 PRINT "That gives you the rating of ";
  88. 2022 IF SCORE<50 THEN PRINT "a Deck boy."
  89. 2023 IF SCORE>50 AND SCORE<100 THEN PRINT "a Sea Man."
  90. 2024 IF SCORE>100 AND SCORE<150 THEN PRINT "a Bucaneer."
  91. 2025 IF SCORE>150 THEN PRINT "a Sea Captain."
  92. 2029 IF EGG=1 THEN PRINT:GOTO 9020
  93. 2030 PRINT:GOTO 9020
  94. 2250 REM DIG ROUTINE
  95. 2251 INPUT "With what";F$:F$=LEFT$(F$,3)
  96. 2252 IF F$<>"SHO" THEN PRINT "You can't use that to dig with.":RETURN
  97. 2260 IF RO<>1 AND RO<>11 AND RO<>21 THEN 2270 ELSE 2290
  98. 2270 IF RO>23 THEN PRINT "If you dig on the ship, you might cause a leak.":RETURN
  99. 2280 PRINT "The ground is too hard here.":RETURN
  100. 2290 IF RO=1 THEN PRINT "You dig into the ground...You hit something! Its a coffin! When you open the":PRINT "coffin, a skeleton pops out, knife first, stabbing you!! The coffin was":PRINT "boobeytrapped!!":RETURN 2000
  101. 2300 IF RO=11 THEN PRINT "You dig but you don't find anything.":RETURN
  102. 2310 PRINT "You dig in the damp soil and soon you come upon a grating in the ground!":TR(13)=21:RETURN
  103. 2500 REM GO ROUTINE
  104. 2510 C$=LEFT$(C$,1)
  105. 2511 IF C$="S" AND RO=39 AND FLAG97=0 THEN PRINT "Are you sure you want to dive into the water?":RETURN
  106. 2520 IF C$="N" AND A(RO,1)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  107. 2530 IF C$="S" AND A(RO,2)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  108. 2540 IF C$="E" AND A(RO,3)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  109. 2550 IF C$="W" AND A(RO,4)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  110. 2560 IF C$="U" AND A(RO,5)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  111. 2570 IF C$="D" AND A(RO,6)=0 THEN PRINT:PRINT "You can't go that way.":RETURN
  112. 2580 IF C$="N" THEN RO=A(RO,1)
  113. 2590 IF C$="S" THEN RO=A(RO,2)
  114. 2600 IF C$="E" THEN RO=A(RO,3)
  115. 2610 IF C$="W" THEN RO=A(RO,4)
  116. 2620 IF C$="U" THEN RO=A(RO,5)
  117. 2630 IF C$="D" THEN RO=A(RO,6)
  118. 2640 IF RO=22 AND FLAG2=0 THEN SCORE=SCORE+20:FLAG2=1
  119. 2650 IF RO=23 AND FLAG3=0 THEN SCORE=SCORE+20:FLAG3=1
  120. 2660 RETURN 190
  121. 3000 REM GET ROUTINE
  122. 3010 IF C$="CHE" AND RO=23 THEN PRINT "The chest is too large and heavy for you to carry.":RETURN
  123. 3020 IF C$="CAP" AND RO=25 THEN PRINT "The captain moves out of the way just as you try to lift him. 'Hey, are you some":PRINT "kind of quier?'":RETURN
  124. 3030 IF C$="COO" AND RO=40 THEN PRINT "The cook slaps your hand. 'Not now, someone might see us.'":RETURN
  125. 3040 IF C$="STE" AND RO=40 THEN PRINT "The cook slaps your hand. 'Wait till it's done.'":RETURN
  126. 3041 IF C$="GAR" AND FLAG98=0 THEN PRINT "'No one messes with my stew makin's.' The cook pulls out a knife and cuts your":PRINT "throat. As you die, you hear the cook mutter, 'Now that'll teach him.'":RETURN 2000
  127. 3042 IF C$="GRA" THEN PRINT "The grate is secured to the grate.":RETURN
  128. 3050 FLAG7=0:FLAG8=0:OBJECT=0
  129. 3060 FOR I=1 TO 14
  130. 3070 IF TR(I)=200 THEN FLAG7=FLAG7+1
  131. 3080 NEXT I
  132. 3090 IF FLAG7>6 THEN PRINT:PRINT "You can't carry anymore.":RETURN
  133. 3100 FOR I=1 TO 12
  134. 3110 IF TR(I)=RO THEN FLAG8=1
  135. 3115 NEXT I
  136. 3120 IF FLAG8=0 THEN PRINT:PRINT "There is nothing here to pick up.":RETURN
  137. 3130 FOR I=1 TO 14
  138. 3140 IF C$=O1$(I) AND TR(I)=RO THEN OBJECT=I
  139. 3150 NEXT
  140. 3160 IF OBJECT=0 THEN PRINT:PRINT "I don't see that here.":RETURN
  141. 3170 TR(OBJECT)=200
  142. 3180 PRINT "Ok."
  143. 3190 IF TR(1)=200 AND FLAG9=0 THEN SCORE=SCORE+15:FLAG9=1
  144. 3200 IF TR(12)=200 AND FLAG10=0 THEN SCORE=SCORE+40:FLAG10=1
  145. 3201 IF TR(9)=200 AND FLAG55=0 THEN SCORE=SCORE+60:FLAG55=1
  146. 3210 RETURN
  147. 3500 REM DROP ROUTINE
  148. 3510 OBJECT=0:FOR I=1 TO 14
  149. 3520 IF C$=O1$(I) THEN OBJECT=I
  150. 3530 NEXT I
  151. 3540 IF OBJECT=0 THEN PRINT "You don't have that!":RETURN
  152. 3550 PRINT "Ok."
  153. 3560 TR(OBJECT)=RO
  154. 3570 RETURN
  155. 4000 REM OPEN ROUTINE
  156. 4010 IF C$<>"DRA" AND C$<>"BOX" AND C$<>"CHE" AND C$<>"DOO" THEN PRINT:PRINT "You can't open that.":RETURN
  157. 4011 PRINT
  158. 4015 IF C$="DRA" AND RO<>26 THEN PRINT "I don't see a dresser here.":RETURN
  159. 4016 IF C$="DRA" AND RO=26 AND FLAG4=1 THEN PRINT "The drawer is already open.":RETURN
  160. 4020 IF C$="DRA" AND FLAG4=0 AND RO=26 THEN PRINT "The drawer is now open. Inside you see your pirate book and your sword.":TR(5)=RO:TR(6)=RO:FLAG4=1:RETURN
  161. 4030 IF C$="BOX" AND TR(11)<>200 THEN PRINT "You don't even have the box.":RETURN
  162. 4040 IF C$="BOX" AND FLAG5=0 AND TR(11)=200 THEN PRINT "Ok, the box is now open. You find a thieve's pick inside.":TR(12)=RO:FLAG5=1:RETURN
  163. 4050 IF C$="BOX" AND FLAG5=1 AND TR(11)=200 THEN PRINT "The box is already open.":RETURN
  164. 4060 IF C$="CHE" AND RO<>23 THEN PRINT "I don't see the chest here.":RETURN
  165. 4070 IF C$="CHE" AND RO=23 AND FLAG70=0 THEN PRINT "You must unlock the chest.":RETURN
  166. 4080 IF C$="CHE" AND RO=23 AND FLAG70=1 THEN PRINT "The chest is already open.":RETURN
  167. 4090 IF C$="DOO" AND RO<>26 AND RO<>29 THEN PRINT "There is no door here.":RETURN
  168. 4100 IF C$="DOO" AND RO=26 AND FLAG11=0 THEN PRINT "The door swings open revealing a passage to the east.":A(26,3)=27:A(27,4)=26:FLAG11=1:RETURN
  169. 4110 IF C$="DOO" AND RO=26 AND FLAG11=1 THEN PRINT "The door is already open.":RETURN
  170. 4120 IF C$="DOO" AND RO=29 THEN PRINT "The door is locked and is the quarters of the captain.":RETURN
  171. 4130 RETURN
  172. 4500 REM unlock routine
  173. 4510 IF C$<>"DOO" AND C$<>"CHE" AND C$<>"GRA" AND C$<>"BOX" THEN PRINT "I cna't unlock that!":RETURN
  174. 4520 IF C$="DOO" THEN PRINT "You don't need to unlock that!":RETURN
  175. 4530 IF C$="BOX" THEN PRINT "You don't need to unlock that!":RETURN
  176. 4540 INPUT "With what";F$:F$=LEFT$(F$,3)
  177. 4550 IF C$="CHE" THEN 4600
  178. 4560 IF F$="KEY" THEN PRINT "The key doesn't fit the grate.":RETURN
  179. 4570 IF F$<>"PIC" THEN PRINT "You can't use that to unlock the grate!":RETURN
  180. 4580 IF FLAG60=1 THEN PRINT "The grate is already unlocked!":RETURN
  181. 4590 PRINT "The grate is now unlocked and opened! The grate reveals a passage downward.":A(21,6)=23:A(23,5)=21:FLAG60=1:RETURN
  182. 4600 IF F$="PIC" THEN PRINT "The pick doesn't fit the chest's lock.":RETURN
  183. 4610 IF F$<>"KEY" THEN PRINT "You can't use that to unlock the chest!":RETURN
  184. 4620 IF FLAG70=1 THEN PRINT "The chest is already unlocked!":RETURN
  185. 4630 PRINT "The chest is now unlocked and opened! The chest reveals a large, gold Spanish coin!":FLAG70=1:TR(9)=23:RETURN
  186. 5000 REM BUY ROUTINE
  187. 5010 INPUT "With what?";F$:F$=LEFT$(F$,3)
  188. 5020 IF C$<>"GAR" THEN PRINT "You can't buy that!":RETURN
  189. 5030 IF FLAG50=1 THEN PRINT "You've already bought the clove of garlic.":RETURN
  190. 5040 IF RO<>40 AND TR(4)<>200 THEN PRINT "I don't see the clove of garlic here.":RETURN
  191. 5050 IF F$<>"BAG" AND F$<>"SIL" THEN PRINT "'You fool! You'd think I'd seatle for less than silver for my garlic!' You are":PRINT " then decapitated!":RETURN 2000
  192. 5060 PRINT "The cook thinks it over then says, 'Well I guess it's a good deal so here.'":PRINT "Then the cooks hands you the clove and takes your bag of silver.":TR(4)=200:TR(14)=255:FLAG50=1
  193. 5070 RETURN
  194. 6000 REM CLIMB ROUTINE
  195. 6010 IF C$<>"MAS" AND C$<>"LAD" THEN PRINT "You can't climb that!":RETURN
  196. 6020 IF C$="MAS" AND RO=33 THEN PRINT "You climb up the mast...Soon you are in the crow's nest.":RO=35:PRINT:RETURN 190
  197. 6030 IF C$="MAS" AND RO=32 THEN PRINT "You climb up the mast...Soon you are in the crow's nest.":RO=34:PRINT:RETURN 190
  198. 6040 IF C$="MAS" THEN PRINT "I can't see a mast here.":RETURN
  199. 6050 IF C$="LAD" AND RO=39 THEN PRINT "If you want to go down the ladder just say so.":RETURN
  200. 6060 IF C$="LAD" THEN PRINT "I don't see a ladder here.":RETURN
  201. 6500 REM KNOCK ROUTINR
  202. 6510 INPUT "What do you want to knock on";F$:F$=LEFT$(F$,3)
  203. 6520 IF F$<>"DOO" THEN PRINT:PRINT "Awesome!!!":RETURN
  204. 6530 IF RO<>29 AND RO<>26 AND RO<>27 THEN PRINT:PRINT "I don't see a door here.":RETURN
  205. 6540 IF RO=29 AND FLAG12=0 THEN PRINT:PRINT "You knock on the door and wait. Soon the captain comes and ushers you in.":RO=25:FLAG12=1:PRINT:RETURN 190
  206. 6545 IF RO=29 AND FLAG12=1 THEN PRINT:PRINT "There is no answer.":RETURN
  207. 6550 PRINT:PRINT "Nothing happens."
  208. 6560 RETURN
  209. 7000 REM READ ROUTINE
  210. 7010 IF C$<>"BOO" AND C$<>"NOT" THEN PRINT:PRINT "You can't read that!":RETURN
  211. 7015 IF C$="NOT" THEN 7190
  212. 7020 IF TR(5)<>200 THEN PRINT:PRINT "You aren't even carrying the book!":RETURN
  213. 7030 PRINT
  214. 7060 PRINT "     This is Julius the Pirate's book on pirates. Included"
  215. 7070 PRINT "     are many entries on other pirates, ships and treasures."
  216. 7080 PRINT "     You skim through the book until you find a large entry"
  217. 7090 PRINT "     on an ancient Spanish coin worth thousands of dollar"
  218. 7100 PRINT "     and located on an island close by here. The lattitude"
  219. 7110 PRINT "     is 45 degrees and the longitude is 24 degrees."
  220. 7120 PRINT
  221. 7130 PRINT "     You notice that at the bottom of the last page that there"
  222. 7140 PRINT "     is some text reading:"
  223. 7150 PRINT
  224. 7160 PRINT "     For other refrences on Julius the Pirate, look under Julius"
  225. 7170 PRINT "     in a card catalog found in every ship library."
  226. 7180 RETURN
  227. 7190 IF RO<>42 THEN PRINT:PRINT "You can't see any note here.":RETURN
  228. 7200 PRINT
  229. 7210 PRINT "     To find a book in the many books in our wondourous library,"
  230. 7220 PRINT "     look under the subject and then go find the book. I hope"
  231. 7230 PRINT "     the books will entertain you and widen your horizons and"
  232. 7240 PRINT "     be sure to put the books back, OR ELSE!!!"
  233. 7250 PRINT
  234. 7260 PRINT "                                        -Jonny the Captain"
  235. 7270 RETURN
  236. 8000 REM LOOK UNDER ROUTINE
  237. 8010 IF RO<>42 THEN PRINT "You can't find information on that here. Try the ship's library open 24 hours a":PRINT "day!":RETURN
  238. 8020 PRINT
  239. 8030 PRINT "    You look through the card catalog, find a book on Julius"
  240. 8040 PRINT "    the Pirate, go get the book along the racks, and find this"
  241. 8050 PRINT "    entry:":PRINT
  242. 8060 PRINT "    Julius the Pirate was a great pirate, know for his daring"
  243. 8070 PRINT "    adventures and finding rare and valuable treasures. His"
  244. 8080 PRINT "    most famous treasure find was the Spanish gold coin, an"
  245. 8090 PRINT "    original coin since only one was made and it was minted in"
  246. 8100 PRINT "    in 1635. Julius died before he could collect the coin but"
  247. 8110 PRINT "    left the degrees of the island that the famous coin is"
  248. 8120 PRINT "    supposed to be on, in his pirate book passed on through his"
  249. 8130 PRINT "    generations. The last known recorded inheritered of the book"
  250. 8131 PRINT "    was Humphry Goodfellow, who died in a fire at his house. The"
  251. 8132 PRINT "    whereabouts of the book is unknown.":PRINT
  252. 8133 PRINT "    You read on till you find the last paragraph, which you are"
  253. 8134 PRINT "    shocked by:":PRINT
  254. 8135 PRINT "    Julius the Pirate was a great pirate, but he had a problem"
  255. 8136 PRINT "    with his left eye, which made him put marks 5 degrees west"
  256. 8137 PRINT "    of the original on longitude and latitude maps."
  257. 8138 PRINT "    MORE?"
  258. 8139 IF INKEY$="" THEN 8139
  259. 8140 RETURN
  260. 8150 IF RO<>42 THEN PRINT "You can't find information on that here. Try the ship's library open 24 hours a":PRINT "day!":RETURN
  261. 8160 PRINT
  262. 8170 PRINT "    Pirate Island is one of the most scariest islands in the"
  263. 8180 PRINT "    whole ocean. The name of the island has sent chills down"
  264. 8190 PRINT "    the spines of many young sea-going sailors. The bravest"
  265. 8200 PRINT "    captains have steered away from the island just to stay"
  266. 8210 PRINT "    out of the horrors that superstision have provided."
  267. 8220 PRINT "    Legends have it that the valuable Spanish gold coin rests"
  268. 8230 PRINT "    on Pirate Island but to date, no one has even tried to"
  269. 8240 PRINT "    find the coin. But then again, we don't record ALL voyages!"
  270. 8250 RETURN
  271. 8300 IF RO<>42 THEN PRINT "You can't find information on that here. Try the ship's library open 24 hours a":PRINT "day!":RETURN
  272. 8310 PRINT
  273. 8320 PRINT "    David Meny is one of the greatest pirates on the seven seas!"
  274. 8330 PRINT "    He has written his way out of a jail cell and found the Spanish"
  275. 8340 PRINT "    silver coin, second in value to only the famous gold coin made"
  276. 8350 PRINT "    by the Spainards. He continues to roam the free world"
  277. 8360 PRINT "    in search of adventure and intrigue."
  278. 8370 RETURN
  279. 8500 REM SWIM ROUTINE
  280. 8510 IF RO<>11 AND RO<>44 AND RO<>45 AND RO<>22 THEN PRINT "You can't swim here!":RETURN
  281. 8520 IF RO=44 OR RO=45 THEN PRINT "You swim around for awhile then end up where you are now.":RETURN
  282. 8530 IF RO=22 THEN PRINT "The water is to shallow to swim here.":RETURN
  283. 8540 PRINT "You swim out into the bay...."
  284. 8550 RO=44:RETURN 190
  285. 8990 END
  286. 9000 REM end of game
  287. 9010 PRINT "You have died. Too bad."
  288. 9020 INPUT "Would you like to start over";F$
  289. 9030 F$=LEFT$(F$,1)
  290. 9040 IF F$="Y" OR F$="y" THEN GOTO 9090
  291. 9050 IF F$="N" OR F$="n" THEN GOTO 9070
  292. 9060 PRINT "Please answer the question.":GOTO 9020
  293. 9070 PRINT:PRINT "Ok. See you next time on Pirate Island."
  294. 9080 FOR I=1 TO 100:NEXT I:CLS:END
  295. 9090 FLAG1=0:FLAG2=0:FLAG3=0:FLAG4=0:FLAG5=0:FLAG6=0:FLAG6=0:FLAG7=0:FLAG8=0:FLAG9=0:FLAG10=0:FLAG11=0:FLAG12=0:FLAG13=0:FLAG14=0:FLAG15=0:FLAG40=0:FLAG55=0:FLAG50=0:FLAG60=0:FLAG70=0:FLAG95=0:FLAG96=0:FLAG97=0:FLAG99=0:FLAG99=0:FLAG100=0
  296. 9100 RO=26
  297. 9110 TR(1)=35:TR(2)=25:TR(3)=8:TR(4)=40:TR(5)=255:TR(6)=255:TR(7)=23:TR(8)=40:TR(9)=255:TR(10)=36:TR(11)=45:TR(12)=255:TR(13)=255:TR(14)=255
  298. 9111 A(26,3)=0:A(27,4)=0:A(21,6)=0:A(23,5)=0
  299. 9120 CLS:GOTO 172
  300. 14000 REM PRINT ROOM CONTENTS
  301. 14020 FLAG99=0:JKH=0:FOR I=1 TO 14
  302. 14030 IF TR(I)=RO THEN JKH=I
  303. 14031 IF JKH<>I THEN 14040
  304. 14035 IF FLAG99=0 THEN PRINT O2$(JKH):ELSE PRINT O2$(JKH)
  305. 14036 FLAG99=1:JKH=I
  306. 14040 NEXT
  307. 14050 RETURN
  308. 15000 REM ROOM DESCRIPTION
  309. 15010 COLOR 0,7
  310. 15020 LOCATE 25,1
  311. 15030 PRINT "                                                                               "
  312. 15040 LOCATE 25,3:PRINT RO$(RO)
  313. 15050 LOCATE 25,50:PRINT "Score:";SCORE
  314. 15060 COLOR 7,0
  315. 15065 PRINT RO$(RO)
  316. 15066 IF RO>39 THEN 15090
  317. 15070 ON RO GOSUB 15110,15150,15150,15175,15210,15240,15280,15320,15210,15210,15360,15400,15210,15450,15490,15520,15560,15450,15450,15600,15640,15680,15720,15760,15800,15850,15890,15920,15950,16000,16040,16080,16120,16170,16170,16190,16230,16270,16320
  318. 15071 IF RO<>25 THEN 15080
  319. 15072 PRINT:PRINT "The captain looks at you the says, 'Well what's then longitude of Pirate":INPUT "Island";F1:INPUT "'Ok, now what's the latitude";F2
  320. 15073 PRINT "'You better be right or you'll regret you ever woke up this morning! Now leave.'":IF F1=F4 AND F2=F3 THEN FLAG98=1:START=1:RO=29:PRINT:RETURN 190
  321. 15074 START=1:RO=29:FLAG98=0:RETURN 190
  322. 15080 RETURN
  323. 15090 ST=RO-39:ON ST GOSUB 16360,16410,16440,16480,16510,16550
  324. 15100 RETURN
  325. 15110 REM ROOM 1
  326. 15120 PRINT "You are on the top of a high cliff overlooking the blue waters of the ocean. A"
  327. 15130 PRINT "path leads down. The soil is damp here."
  328. 15140 RETURN
  329. 15150 REM ROOM 2 AND 3
  330. 15160 PRINT "You are in a large rain forest."
  331. 15170 RETURN
  332. 15175 REM ROOM 4
  333. 15180 PRINT "You are on a small path leading out of a large rain forest to the west. In the"
  334. 15190 PRINT "center of the path there is a large tree."
  335. 15200 RETURN
  336. 15210 REM ROOM 5,9,10 AND 13
  337. 15220 PRINT "This is a thick forest covered by many trees, all of which are unclimbable."
  338. 15230 RETURN
  339. 15240 REM ROOM 6
  340. 15250 PRINT "You are standing below a large cliff. A path leads up to the cliff while an"
  341. 15260 PRINT "east/west path heads towards a cove and a meadow."
  342. 15270 RETURN
  343. 15280 REM room 7
  344. 15290 PRINT "You are near a large rock which has probably stood here for many hundreds of"
  345. 15300 PRINT "years. A small path leads south."
  346. 15310 RETURN
  347. 15320 REM room 8
  348. 15330 PRINT "You are in a large tree above a small path. The many leaves and branches"
  349. 15340 PRINT "prevent you from going any further up, while a large stump leads down."
  350. 15350 RETURN
  351. 15360 REM room 11
  352. 15370 PRINT "You are standing on the shore of an inland cove. The clear, blue waters of"
  353. 15380 PRINT "the ocean are of to the east, while a murky smell comes from the south. The"
  354. 15385 PRINT "soil is damp here."
  355. 15390 RETURN
  356. 15400 REM room 12
  357. 15410 PRINT "You are standing in a large meadow where birds sing and deer play. The tall,"
  358. 15420 PRINT "lush grass beneath you is stamped out, forming a path to the north, south and"
  359. 15430 PRINT "west."
  360. 15440 RETURN
  361. 15450 REM rooms 14,18 and 19
  362. 15460 PRINT "This is a murky, dismal swamp where hideous creatures hide when they are not on"
  363. 15470 PRINT "the hunt. A path leads to the west."
  364. 15480 RETURN
  365. 15490 PRINT "You are standing, or rather were standing, in a large pond of quick sand."
  366. 15500 PRINT "You are slowly...slowly...slowly...sinking."
  367. 15510 RETURN 9000
  368. 15520 REM room 16
  369. 15530 PRINT "You are walking along a beach path which surrounds the southwest part of the"
  370. 15540 PRINT "island. To the east you can see a beach, while to the west comes a murky smell."
  371. 15550 RETURN
  372. 15560 REM room 17
  373. 15570 PRINT "This is a sandy beachy coming out of the water. Palm tress line the shore and"
  374. 15580 PRINT "a path leads to the west and to the east. Another path heads north."
  375. 15590 RETURN
  376. 15600 REM room 20
  377. 15610 PRINT "You are standing in a dark cave leading out of a swamp. From the east comes"
  378. 15620 PRINT "squeaky noises (Maybe you aren't the only one on this island)."
  379. 15630 RETURN
  380. 15640 REM room 21
  381. 15650 PRINT "You are in a cave with many bats. The ground is damp here. ";:IF TR(4)<>200 THEN PRINT " The bats see you and attack.":PRINT "You have many bat bites and slowly...slowly...slowly die.":RETURN 9000
  382. 15660 PRINT " The bats, seeing your garlic, stay far back."
  383. 15670 RETURN
  384. 15680 REM room 22
  385. 15690 PRINT "You are in a shallow cove, so shallow that you can stand up. To the north there"
  386. 15700 PRINT "is a sandy beach, while to all other directions there is deep water."
  387. 15710 FLAG40=1:RETURN
  388. 15720 REM room 23
  389. 15730 PRINT "You are in a secret cave below a grate. From up above you can hear squeaky"
  390. 15740 PRINT "noises."
  391. 15750 RETURN
  392. 15760 REM room 24
  393. 15770 PRINT "This is the wheelhouse of the ship where the ship is directed. A navigator is"
  394. 15780 PRINT "here directing the wheel over the blue water of the ocean."
  395. 15790 RETURN
  396. 15800 REM room 25
  397. 15810 PRINT "You are in the captain's quarters, a large room with many sea equipment along"
  398. 15820 PRINT "the including a compass and an old relic made out of gold. There is a large,"
  399. 15830 PRINT "wooden desk here containg top-secret information."
  400. 15840 RETURN
  401. 15850 REM room 26
  402. 15860 PRINT "You are in your cabin, a small room with minor furnishments. The only"
  403. 15870 PRINT "furnishments are a bed and a dresser with only one drawer. A large wooden door"
  404. 15871 PRINT "is on the east wall."
  405. 15880 RETURN
  406. 15890 REM room 27
  407. 15900 PRINT "You are in the north end of a hallway running north to south."
  408. 15910 RETURN
  409. 15920 REM room 28
  410. 15930 PRINT "You are on the port section of the ship's deck. To the north there is the "
  411. 15940 PRINT "ship's wheelhouse. Also the mid deck is to the south."
  412. 15945 RETURN
  413. 15950 REM room 29
  414. 15960 PRINT "You are on the ship's port deck. To the west is another portdeck and to the"
  415. 15970 PRINT "south there is the mid deck. To the east there is a passageway leading to the"
  416. 15980 PRINT "wheelhouse and to the north there is a large door leading to the captain's"
  417. 15981 PRINT "quarters."
  418. 15990 RETURN
  419. 16000 REM room 30
  420. 16010 PRINT "You are in the crew's cabin portion of the ship. There are many bunks and gear"
  421. 16020 PRINT "here that belongs to other people, so don't touch it."
  422. 16030 RETURN
  423. 16040 REM room 31
  424. 16050 PRINT "This is a hallway running north to south. To the west is the crew's cabin while"
  425. 16060 PRINT "up there is the mid deck."
  426. 16070 RETURN
  427. 16080 REM room 32
  428. 16090 PRINT "You are on the ship's mid deck. Another mid deck is off to the east while the"
  429. 16100 PRINT "ship's port and starboard decks are off to the north and south. A large mast is"
  430. 16105 PRINT "here with a crow's nest on top of it."
  431. 16110 RETURN
  432. 16120 REM room 33
  433. 16130 PRINT "You are on one of two mid decks. This mid deck has a ladder leading down to the"
  434. 16140 PRINT "decks below. Also the port and starboards are off to the north and south while"
  435. 16150 PRINT "a large mast is above you. On the top of the mast, there is a crow's nest."
  436. 16160 RETURN
  437. 16170 REM room 34 and 35
  438. 16180 PRINT "You are in a crow's nest, a lookout site for land, storms and other ships."
  439. 16181 RETURN
  440. 16190 REM room 36
  441. 16200 PRINT "You are in the ship's mess hall where every day hungry crewmen are fed. To the"
  442. 16210 PRINT "south is the galley and to the east is a hallway."
  443. 16220 RETURN
  444. 16230 REM room 37
  445. 16240 PRINT "You are in a hallway running north to south. To the west is the ship's mess"
  446. 16250 PRINT "hall."
  447. 16260 RETURN
  448. 16270 REM room 38
  449. 16280 PRINT "You are on the starboard deck of the ship. To the east there is another"
  450. 16290 PRINT "starboard deck, while to the north there is a mid deck. To the south there is"
  451. 16300 PRINT "the ship's library."
  452. 16310 RETURN
  453. 16320 REM room 39
  454. 16330 PRINT "This is the ship's starboard deck. There is a ladder here, leading down to a"
  455. 16340 PRINT "hallway and a deck to the north and to the west."
  456. 16341 IF RO<>39 THEN 15100
  457. 16342 IF FLAG40<>1 THEN 15100
  458. 16343 PRINT
  459. 16344 IF RO=39 AND FLAG40=1 AND TR(9)=200 THEN PRINT "As you come back aboard the ship, the captain greets you. 'Welcome back, matey!":PRINT "Congradulations, you found the coin. Now we will all be":PRINT "rich!'":SCORE=SCORE+55:EGG=1:RETURN 2000
  460. 16345 IF RO=39 AND FLAG40=1 AND TR(9)<>200 THEN PRINT "As you come back aboard the ship, the captain greets you. 'Welcome back, matey!":PRINT "What? You didn't find the coin. I'll kill you for that!' The captain"
  461. 16346 PRINT "then pulls out his sword and kills you!":RETURN 2000
  462. 16350 RETURN
  463. 16360 REM room 40
  464. 16370 PRINT "This is the ship's galley where food is prepared. A large stove is against the"
  465. 16380 PRINT "south wall and many ingredients awaiting to be prepared in the stew the cook is"
  466. 16390 PRINT "making."
  467. 16400 RETURN
  468. 16410 REM room 41
  469. 16420 PRINT "You are in the south end of a hallway running north to south."
  470. 16430 RETURN
  471. 16440 REM room 42
  472. 16450 PRINT "You are in the ship's library with many books lining the wall. A card catalog is"
  473. 16460 PRINT "here and a card catalog reference note is pinned on top of the card catalog."
  474. 16470 RETURN
  475. 16480 REM room 43
  476. 16490 PRINT "You are under water. You are sinking in the soft sand......."
  477. 16500 RETURN 9000
  478. 16510 REM ROOM 44
  479. 16520 PRINT "You are swimming on the top of the water in an inland cove. Off to the east is"
  480. 16530 PRINT "the shore of the cove."
  481. 16540 RETURN
  482. 16550 REM room 45
  483. 16560 PRINT "You are on the bottom of a cove. The sand here is sturdy, thus you don't sink."
  484. 16570 RETURN
  485. 19990 END
  486. 20000 REM INITIALIZE
  487. 20010 RO=26:SCORE=0
  488. 20015 F3=45:F4=29
  489. 20020 FOR I=1 TO 45
  490. 20030 FOR J=1 TO 6
  491. 20040 READ A(I,J)
  492. 20050 NEXT J
  493. 20060 NEXT I
  494. 20070 FOR I=1 TO 14
  495. 20080 READ O1$(I),O2$(I),TR(I),IN$(I)
  496. 20090 NEXT I
  497. 20100 FOR I=1 TO 45
  498. 20110 READ RO$(I)
  499. 20120 NEXT I
  500. 20130 RETURN
  501. 25000 REM DATA STATEMENTS
  502. 25010 DATA 0,0,0,0,0,6:REM ROOM 1
  503. 25020 DATA 2,2,3,2,0,0:REM ROOM 2
  504. 25030 DATA 2,3,4,0,6,0:REM ROOM 3
  505. 25040 DATA 0,0,0,3,8,0:REM ROOM 4
  506. 25050 DATA 0,5,10,9,0,0:REM ROOM 5
  507. 25060 DATA 0,0,12,11,1,3:REM ROOM 6
  508. 25070 DATA 0,17,0,0,0,0:REM ROOM 7
  509. 25080 DATA 0,0,0,0,0,4:REM ROOM 8
  510. 25090 DATA 5,10,13,9,0,0:REM ROOM 9
  511. 25100 DATA 5,19,10,9,0,0:REM ROOM 10
  512. 25110 DATA 6,15,12,0,0,0:REM ROOM 11
  513. 25120 DATA 6,16,0,11,0,0:REM ROOM 12
  514. 25130 DATA 9,0,0,18,0,0:REM ROOM 13
  515. 25140 DATA 0,19,14,20,0,0:REM ROOM 14
  516. 25150 DATA 0,0,0,0,0,0:REM ROOM 15
  517. 25160 DATA 12,0,17,15,0,0:REM ROOM 16
  518. 25170 DATA 7,22,18,16,0,0:REM ROOM 17
  519. 25180 DATA 13,0,0,17,0,0:REM ROOM 18
  520. 25190 DATA 14,18,19,10,0,0:REM ROOM 19
  521. 25200 DATA 0,0,21,14,0,0:REM ROOM 20
  522. 25210 DATA 0,0,0,20,0,0:REM ROOM 21
  523. 25220 DATA 17,39,43,43,43,43:REM ROOM 22
  524. 25230 DATA 0,0,0,0,21,0:REM ROOM 23
  525. 25240 DATA 0,0,29,28,0,0:REM ROOM 24
  526. 25250 DATA 0,29,0,0,0,0:REM ROOM 25
  527. 25260 DATA 0,0,0,0,0,0:REM ROOM 26
  528. 25270 DATA 0,31,0,0,0,0:REM ROOM 27
  529. 25280 DATA 24,32,29,0,0,0:REM ROOM 28
  530. 25290 DATA 0,33,24,28,0,0:REM ROOM 29
  531. 25300 DATA 0,0,31,0,0,0:REM ROOM 30
  532. 25310 DATA 27,37,0,30,33,0:REM ROOM 31
  533. 25320 DATA 28,38,33,0,0,0:REM ROOM 32
  534. 25330 DATA 29,39,0,32,0,31:REM ROOM 33
  535. 25340 DATA 0,0,0,0,0,32:REM ROOM 34
  536. 25350 DATA 0,0,0,0,0,33:REM ROOM 35
  537. 25360 DATA 0,40,37,0,0,0:REM ROOM 36
  538. 25370 DATA 31,41,0,36,39,0:REM ROOM 37
  539. 25380 DATA 32,42,39,0,0,0:REM ROOM 38
  540. 25390 DATA 33,0,0,38,0,37:REM ROOM 39
  541. 25400 DATA 36,0,0,0,0,0:REM ROOM 40
  542. 25410 DATA 37,0,0,0,0,0:REM ROOM 41
  543. 25420 DATA 38,0,0,0,0,0:REM ROOM 42
  544. 25430 DATA 0,0,0,0,0,0:REM ROOM 43
  545. 25431 DATA 0,0,11,0,0,45:REM ROOM 44
  546. 25432 DATA 0,0,0,0,44,0:REM ROOM 45
  547. 25440 DATA "SHO","There is an old shovel here.",35,"a shovel"
  548. 25450 DATA "CAP","The captain of the ship is here.",25,""
  549. 25460 DATA "KEY","There is a shiny key laying near you.",8,"a key"
  550. 25470 DATA "GAR","There is a clove of garlic near you.",40,"a clove of garlic"
  551. 25480 DATA "BOO","There is a bounded book here.",255,"a book"
  552. 25490 DATA "SWO","A sharp sword is here.",255,"a sharp sword"
  553. 25500 DATA "CHE","There is an old pirate chest here.",23,""
  554. 25510 DATA "COO","The ship's cook is here, cooking a stew.",40,""
  555. 25520 DATA "COI","There is a Spanish coin here.",255,"a gold coin"
  556. 25530 DATA "TRA","There is a tray here full of discarded food.",36,"a tray"
  557. 25531 DATA "BOX","Near you, there is small box.",45,"a box"
  558. 25532 DATA "PIC","There is a thieve's pick here.",255,"a thieve's pick"
  559. 25533 DATA "GRA","There is a metal grate here.",255,""
  560. 25534 DATA "BAG","A bag of silver coins is here.",255,"a bag of silver coins"
  561. 25535 DATA High Cliff,Rain Forest,Rain Forest,Small Path,Thick Forest,Near Cliff
  562. 25540 DATA Rock,Up A Tree,Thick Forest,Thick Forest,Inland Cove,Meadow
  563. 25550 DATA Thick Forest,Swamp,Quicksand,Beach Path,Sandy Beach,Swamp,Swamp
  564. 25560 DATA Dark Cave,Bat Cave,Shallow Cove,Secret Cave,Wheelhouse
  565. 25570 DATA Captain's Quarters,Your Cabin,Hallway,Port Deck,Port Deck
  566. 25580 DATA Crew's Cabin,Hallway,Mid Deck,Mid Deck,Crow's Nest,Crow's Nest
  567. 25590 DATA Mess Hall,Hallway,Starboard Deck,Starboard Deck,Galley,Hallway
  568. 25600 DATA Ship's Library,Under Water,Top of the Bay,Bottom of the Bay
  569. ,Hallway,Starboard Dec
Advertisement
RAW Paste Data Copied
Advertisement