Rocksmith Intro Skip

@echo off
set "rocksmith-path=C:\Program Files (x86)\Steam\steamapps\common\Rocksmith2014"
set "ce-path=C:\Program Files (x86)\Cheat Engine 6.7"
set "speed=10"
set "duration=10"
set "loginTime=5"

set "ce-script=%ce-path%\autorun\RocksmithIntroSkip.lua"

pushd %rocksmith-path%
start "" Rocksmith2014.exe
popd

:searchrocksmith
@tasklist|find "Rocksmith2014"
IF %ERRORLEVEL% == 0 GOTO rocksmithfound
TIMEOUT /T 1
GOTO searchrocksmith

:rocksmithfound
FOR /F %%T IN ('Wmic process where^(Name^="Rocksmith2014.exe"^)get ProcessId^|more +1') DO (
SET /A ProcessId=%%T) &GOTO SkipLine
:SkipLine
echo ProcessId = %ProcessId%

(
echo openProcess(tonumber(%ProcessId%^)^)
echo speedhack_setSpeed(%speed%^)
echo function pressEnter(timer^)
echo doKeyPress(VK_RETURN^)
echo timer.destroy(^)
echo t=createTimer(nil^)
echo timer_onTimer(t, chooseProfile^)
echo timer_setInterval(t, %loginTime%*1000^)
echo timer_setEnabled(t, true^)
echo end
echo function chooseProfile(timer^)
echo doKeyPress(VK_RETURN^)
echo timer.destroy(^)
echo t=createTimer(nil^)
echo timer_onTimer(t, resetSpeed^)
echo timer_setInterval(t, 3*1000^)
echo timer_setEnabled(t, true^)
echo end
echo function resetSpeed(timer^)
echo speedhack_setSpeed(1.0^)
echo timer.destroy(^)
echo end
echo t=createTimer(nil^)
echo timer_onTimer(t, pressEnter^)
echo timer_setInterval(t, %duration%*1000^)
echo timer_setEnabled(t, true^)
)>"%ce-script%"

start "" "%ce-path%\Cheat Engine.exe"

TIMEOUT /T 60
del "%ce-script%"
@taskkill /im "cheatengine-x86_64.exe"