A2048 single file version

EXPORT lib2048_ADD(now, pool)
BEGIN
LOCAL th, elem, pos, m;

FOR th FROM 1 TO SIZE(pool) DO
  pool(th)►elem;
  elem(CEILING(RANDOM(SIZE(elem))))►m;
  WHILE 1 DO
    {CEILING(RANDOM(4)),CEILING(RANDOM(4))}►pos;
    IF now(pos(1),pos(2))==0 THEN
      BREAK;
    END;
  END;
  m►now(pos(1),pos(2));
END;
RETURN now;
END;


EXPORT lib2048_MOVE(now, move)
BEGIN
LOCAL pos_now, pos_prev, next, num_now, num_prev, row,col, score;
LOCAL pos_head, offset_row, offset_col, num_max;

MAKEMAT(0,4,4)►next;0►score;0►num_max;
move(1)►pos_head;move(2)►offset_row;move(3)►offset_col;

//{{4,1},{-1,0},{0,1}}
FOR col FROM 0 TO 3 DO
  0►num_prev;
  pos_head+col*offset_col-offset_row►pos_prev;
  FOR row FROM 0 TO 3 DO
    pos_head+col*offset_col+row*offset_row►pos_now;
    now(pos_now(1),pos_now(2))►num_now;
    IF num_now≠0 THEN
      IF num_now==num_prev THEN
        num_prev*2►num_prev;
        num_prev►next(pos_prev(1),pos_prev(2));
        MAX(num_prev,num_max)►num_max;
        score+num_prev►score;
        0►num_prev;
      ELSE
        pos_prev+offset_row►pos_prev;
        num_now►next(pos_prev(1),pos_prev(2));
        num_now►num_prev;
      END;
    END;
  END;
END;
RETURN {next,score,num_max};
END;


EXPORT lib2048_IFEND(now)
BEGIN
LOCAL row,col,out;
2►out;

FOR row FROM 1 TO 4 DO
  FOR col FROM 1 TO 3 DO
    IF now(row,col)==now(row,col+1) THEN
      1►out;
    END;
  END;
END;

FOR row FROM 1 TO 3 DO
  FOR col FROM 1 TO 4 DO
    IF now(row,col)==now(row+1,col) THEN
      1►out;
    END;
  END;
END;

FOR row FROM 1 TO 4 DO
  FOR col FROM 1 TO 4 DO
    IF now(row,col)==0 THEN
      0►out;
    END;
  END;
END;

RETURN out;
END;


//由于发现以"上左下左上左下左..."的操作就能吊打本AI,故此AI被弃用
// (ㄒoㄒ)/~~ 凭什么人家连瞎子都打不过
EXPORT lib2048_AUTO(now, pool, try, deep)
BEGIN
LOCAL score, p, ppool, out, sum, tha, lsum, thb;
LOCAL thc,p2,t;

{{{1,1},{1,0},{0,1}},{{1,1},{0,1},{1,0}},{{4,1},{-1,0},{0,1}},{{4,4},{0,-1},{-1,0}}}►ppool;
{0,0,0,0}►lsum;

FOR tha FROM 1 TO 3 DO
  ppool(tha)►p;
  0►sum;
  FOR thb FROM 1 TO try DO
    0►score;
    p►p2;
    FOR thc FROM 1 TO deep DO
      lib2048_MOVE(now,{p2(1),p2(2),p2(3)})►out;
      out(1) ► now;
      out(2) + score ► score;
      lib2048_IFEND(now)►t;
      IF t==2 THEN
        BREAK;
      END;
      IF t==0 THEN
        lib2048_ADD(now, {pool})►now;
      END;
      ppool(CEILING(RANDOM(3)))►p2;
    END;
    sum+score►sum;
  END;
  sum►lsum(tha);
END;
RETURN ppool(POS(lsum,MAX(lsum)));
END;


EXPORT lib2048_STAT(now)
BEGIN
LOCAL row, col, score, max;

0►score;0►max;

FOR row FROM 1 TO 4 DO
  FOR col FROM 1 TO 4 DO
    IF now(row, col) ≥ 4 THEN
      now(row, col)►max;
      score + 2 ^ ((LOG(now(row, col)) / LOG(2)) - 1)►score;
    END;
    IF now(row, col) > max THEN
      now(row, col)►max;
    END;
  END;
END;

RETURN {score, max};
END;


EXPORT lib2048_UNLUCKY(now)
BEGIN
LOCAL row, col, stat, big, count, poss, pos;
{0, 0, 0}►big;
{0, 0, 0}►count;
{{},{},{}}►poss;

lib2048_STAT(now)►stat;
stat(2)►big(1);

IF big(1) ≤ 256 THEN
  RETURN {0, now};
END;

big(1) / 2 ► big(2);
big(2) / 2 ► big(3);

FOR row FROM 1 TO 4 DO
  FOR col FROM 1 TO 4 DO
    IF now(row, col) == big(1) THEN
      CONCAT(poss(1),{{row, col}}) ► poss(1);
      count(1) + 1 ► count(1);
    END;
    IF now(row, col) == big(2) THEN
      CONCAT(poss(2),{{row, col}}) ► poss(2);
      count(2) + 1 ► count(2);
    END;
    IF now(row, col) == big(3) THEN
      CONCAT(poss(3),{{row, col}}) ► poss(3);
      count(3) + 1 ► count(3);
    END;
  END;
END;

IF count(1) ≥ 2 THEN
  poss(1) ► pos;
  pos(1) ► pos;
  big(1) * 2 ► now(pos(1),pos(2));

  poss(1) ► pos;
  pos(2) ► pos;
  0 ► now(pos(1),pos(2));
  RETURN {1, now, big(1) * 2};
END;

IF count(1) ≥ 1 AND count(2) ≥ 2 THEN
  poss(1) ► pos;
  pos(1) ► pos;
  big(1) * 2 ► now(pos(1),pos(2));

  poss(2) ► pos;
  pos(1) ► pos;
  0 ► now(pos(1),pos(2));

  poss(2) ► pos;
  pos(2) ► pos;
  0 ► now(pos(1),pos(2));
  RETURN {1, now, big(1) * 2};
END;

IF count(1) ≥ 1 AND count(2) ≥ 1 AND count(3) ≥ 2 THEN
  poss(1) ► pos;
  pos(1) ► pos;
  big(1) * 2 ► now(pos(1),pos(2));

  poss(2) ► pos;
  pos(1) ► pos;
  0 ► now(pos(1),pos(2));

  poss(3) ► pos;
  pos(1) ► pos;
  0 ► now(pos(1),pos(2));

  poss(3) ► pos;
  pos(2) ► pos;
  0 ► now(pos(1),pos(2));
  RETURN {1, now, big(1) * 2};
END;

RETURN {0, now};
END;


EXPORT lib2048_INVERT(flash, delay, times)
BEGIN
LOCAL th;

IF flash == 0 THEN
  RETURN flash;
END;

FOR th FROM 1 TO times DO
  WAIT(delay);
  INVERT;
END;
END;


END;

EXPORT lib2048_REDRAW(completely,now,show_text,score,num_max)
BEGIN
LOCAL row, col, num_now, long, color, th;

IF completely THEN
  RECT_P();

  FOR th FROM 0 TO 124 STEP 31 DO
    LINE_P(th,0,th,124,0);
    LINE_P(0,th,124,th,0);
  END;
END;

IF show_text THEN
  TEXTOUT_P("当前得分:" + string(score),143,15,2,0,255,3);
  TEXTOUT_P("最大数字:" + string(num_max),143,39,2,0,255,3);
END;

FOR row FROM 1 TO 4 DO
  FOR col FROM 1 TO 4 DO
    now(row,col)►num_now;
    IF num_now==0 THEN
      RECT_P(31*col-29,31*row-29,31*col-2,31*row-2,3);
    ELSE
      0►color;
      FLOOR(LOG(num_now))+1►long;
      RECT_P(31*col-29,31*row-29,31*col-2,31*row-2,color);
      TEXTOUT_P(num_now,31*col-15-3*long,31*row-22,1,3);
    END;
  END;
END;

END;

EXPORT A2048()
BEGIN
LOCAL score, num_max, now, next, key, output, th;
LOCAL show_text, add_when_nothing_changed, load, unlucky_protect, move_pool, flash, ifend_output, pool;


//参数区
//0为否,1为是

//随机池
//默认为{2,2,2,2,2,2,2,2,2,4}
{2,2,2,2,2,2,2,2,2,4}►pool;

//是否显示当前得分和最大数字
1►show_text;

//当按下一个方向键,数字没有任何变化时,是否添加新的数字
//原版2048游戏中为否
1►add_when_nothing_changed;

//启动时加载的关卡
//[0],代表从头开始,随机生成两个方块
//应为一个4×4的矩阵,如有错误,程序可能会崩溃!
//如[[0,0,0,0],[0,0,0,0],[0,0,0,0],[4,4,2,2]]►load;
[0]►load;

//开启非酋保护,在一些很不幸运的情况下提供一些帮助
//(每局游戏只有一次保护)
//(包括加载的关卡)
//详情请查看lib2048_UNLUCKY(now)
1►unlucky_protect;

//开启闪烁效果
1►flash;

//参数区结束


//初始化变量
0►score;MAKEMAT(0,4,4)►next;0►num_max;
{0,0,0,0,0,0,0,0,{{1,1},{1,0},{0,1}},{{4,4},{0,-1},{-1,0}},0,0,0,{{1,1},{0,1},{1,0}},{{4,1},{-1,0},{0,1}}}►move_pool;

//加载输入的关卡
load►now;
IF now == [0] THEN
  MAKEMAT(0,4,4)►now;
  lib2048_ADD(now, {pool,pool})►now;
ELSE
  lib2048_STAT(now)►output;
  output[1]►score;
  output[2]►num_max;
END;

//绘制界面
lib2048_REDRAW(1,now,show_text,score,num_max);

//主循环
WHILE 1 DO
  //获取按键,进行移动,处理结果,进行重绘
  GETKEY►key;

  IF POS({9,10,14,15},key)==0 THEN
    CONTINUE;
  END;
  lib2048_MOVE(now,move_pool(key))►output;

  output(1) ► next;
  output(2) + score ► score;
  MAX(num_max,output(3)) ► num_max;

  lib2048_REDRAW(0,next,show_text,score,num_max);

  lib2048_IFEND(next)►ifend_output;

  //如果有空位,添加新的方块
  IF ifend_output == 0 THEN
    IF next≠now OR add_when_nothing_changed THEN
      WAIT(0.2);
      lib2048_ADD(next, {pool})►next;
      lib2048_REDRAW(0,next,show_text,score,num_max);
    END;
  END;

  //判定是否死亡
  IF ifend_output == 2 THEN
    lib2048_UNLUCKY(next)►output;
    IF unlucky_protect == 0 OR output(1) == 0 THEN
      TEXTOUT_P("你死了!",143,63,2,0,255,3);
      INVERT;
      WAIT(3);
      FREEZE;
      BREAK;
    END;

    0►unlucky_protect;
    lib2048_INVERT(flash,0.5,2);
    WAIT(0.5);

    //清空键盘缓冲区
    FOR th FROM 1 TO 20 DO
      GETKEY;
    END;
    MSGBOX("酋长大人,你触发了非酋保护!");

    lib2048_REDRAW(1,next,show_text,score,num_max);
    lib2048_INVERT(flash,0.5,5);
    WAIT(0.5);

    output(2) ► next;
    output(3) + score ► score;
    output(3) ► num_max;

    lib2048_REDRAW(1,next,show_text,score,num_max);
    WAIT(0.1);
    lib2048_INVERT(flash,0.1,6);
  END;

  next►now;

END;
END;

//space.bilibili.com/14228634