@AbapCatalog.sqlViewName: 'CMAINTORDOPERTP'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Operation with Draft'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel: {
  representativeKey : 'MaintenanceOrderOperation',
  semanticKey: ['MaintenanceOrderOperation', 'MaintenanceOrder'],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  transactionalProcessingDelegated: true
}

@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@UI: {
    headerInfo: {
      description: {
          value: 'OperationDescription',
          type: #STANDARD
      },
      title: {
          value: 'MaintenanceOrderOperation',
          type: #STANDARD
      },
      typeName: 'Maintenance Order Operation',
      typeNamePlural: 'Maintenance Order Operations'
    }
}

define view C_MaintOrderOperationTP
  as select from I_MaintOrderOperationTP as I_MaintOrderOperationTP
  association [0..1] to C_PMWorkCenterVH        as _WorkCenterVH             on  $projection.OperationWorkCenter = _WorkCenterVH.WorkCenter
                                                                             and $projection.Plant               = _WorkCenterVH.Plant
  association [1..1] to C_MaintOrderTP          as _MaintOrderTP             on  $projection.MaintenanceOrder = _MaintOrderTP.MaintenanceOrder
  association [0..*] to C_MaintOrderComponentTP as _MaintOrderComponentTP    on  $projection.MaintenanceOrder          = _MaintOrderComponentTP.MaintenanceOrder
                                                                             and $projection.MaintenanceOrderOperation = _MaintOrderComponentTP.MaintenanceOrderOperation
  association [0..1] to I_PMTimeUnitVH          as _PlannedWorkUnitOfMeasure on  $projection.OperationPlannedWorkUnit = _PlannedWorkUnitOfMeasure.UnitOfMeasure
  association [0..1] to I_PMContactCardEmployee as _PersonResponsible        on  $projection.OperationPersonResponsible = _PersonResponsible.PersonnelNumber
  association [0..*] to I_WorkCenterText        as _WorkCenterText           on  _WorkCenterText.WorkCenterInternalID = $projection.OperationWorkCenterInternalID
                                                                             and _WorkCenterText.WorkCenterTypeCode   = 'A'
{
        @ObjectModel.foreignKey.association: '_MaintOrderTP'
  key   I_MaintOrderOperationTP.MaintenanceOrder,
        @ObjectModel.text.element:  [ 'OperationDescription' ]
        @UI: {
          fieldGroup: { qualifier:'MalfunctionReportWorkItem', position:10, label: 'Work Item', importance: #HIGH, type: #WITH_NAVIGATION_PATH },
          lineItem: { position: 10, importance: #HIGH}
        }
        @EndUserText.label: 'Work Item'
  key   I_MaintOrderOperationTP.MaintenanceOrderOperation,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderOperationForEdit,

        I_MaintOrderOperationTP.TechnicalObject,
        I_MaintOrderOperationTP.TechObjIsEquipOrFuncnlLoc,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderRoutingNumber,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderOperationCounter,
        I_MaintOrderOperationTP.OperationControlKey,

        @EndUserText.label: 'Description'
        I_MaintOrderOperationTP.OperationDescription,

        I_MaintOrderOperationTP.Equipment,
        I_MaintOrderOperationTP.FunctionalLocation,
        I_MaintOrderOperationTP.Plant,
        @UI.hidden: true
        I_MaintOrderOperationTP.OperationWorkCenterInternalID,

        @UI.lineItem: [ { position: 20 } ]
        @Consumption.valueHelp: '_WorkCenterVH'
        @ObjectModel.text.association: '_WorkCenterText'
        I_MaintOrderOperationTP.OperationWorkCenter,
        @Consumption.hidden: true
        I_MaintOrderOperationTP.OperationWorkCenterTypeCode,

        @UI.lineItem: [ { position: 30 } ]
        @EndUserText.label: 'Assigned To'
        @UI.textArrangement: #TEXT_ONLY
        @ObjectModel.foreignKey.association: '_PersonResponsible' -- may have to remove this when trying to use In parameter for workcenter
        cast( I_MaintOrderOperationTP.OperationPersonResponsible as eams_person_responsible ) as OperationPersonResponsible,

        @ObjectModel.virtualElement
        @ObjectModel.readOnly: true
        @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_PERSRESP_EXIT'
        @UI.hidden: true
        cast( '' as xfeld )                                                                   as UserIsPersonResponsible,

        @UI.lineItem: [ { position: 40, importance: #LOW } ]
        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
        @EndUserText.label: 'Planned Effort'
        I_MaintOrderOperationTP.OperationPlannedWork,
        @ObjectModel.foreignKey.association: '_PlannedWorkUnitOfMeasure'
        @Consumption.valueHelp: '_PlannedWorkUnitOfMeasure'
        I_MaintOrderOperationTP.OperationPlannedWorkUnit,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderOperationInternalID,
        @UI.lineItem: [ { position: 50 } ]
        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
        @EndUserText.label: 'Actual Effort'
        I_MaintOrderOperationTP.ConfirmationTotalQuantity,

        @UI.hidden: true
        I_MaintOrderOperationTP.EAMOverallObjectStatusProfile,
        @UI.lineItem: [ { position: 70 } ]
        @UI.textArrangement: #TEXT_ONLY
        I_MaintOrderOperationTP.EAMOverallObjectStatus,

        @UI.lineItem: [ { position: 60 } ]
        @ObjectModel.readOnly: true
        I_MaintOrderOperationTP.IsFinallyConfirmed,

        @Consumption.hidden: true
        OperationSupplier,
        @Consumption.hidden: true
        _Supplier,


        /* Associations */
        @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
        _MaintOrderComponentTP,
        @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _MaintOrderTP,
        I_MaintOrderOperationTP._TechnicalObject,
        I_MaintOrderOperationTP._TechObjIsEquipOrFuncnlLoc,
        _PlannedWorkUnitOfMeasure,
        I_MaintOrderOperationTP._WorkCenter,
        _WorkCenterText,
        _WorkCenterVH,
        _PersonResponsible,
        I_MaintOrderOperationTP._StatusObjectActiveStatus,
        I_MaintOrderOperationTP._OverallStatus
}
where
  I_MaintOrderOperationTP.IsDeleted = ''