plugins {
  id 'eclipse'
  id 'idea'
  id 'fabric-loom' version '0.2.4-SNAPSHOT' apply false
  id 'maven-publish'
}

import net.fabricmc.loom.task.RunClientTask;
import net.fabricmc.loom.task.RunServerTask;

configurations {
  compile
}

subprojects {
  // https://fabricmc.net/use
  String minecraft_version = '1.14.3'
  String yarn_mappings = '1.14.3+build.1'
  String loader_version = '0.4.8+build.155'
  // https://maven.fabricmc.net/net/fabricmc/fabric
  String fabric_version = '0.3.0+build.187'

  apply plugin: 'fabric-loom'
  apply plugin: 'maven-publish'

  minecraft {}

  dependencies {
    minecraft "com.mojang:minecraft:${minecraft_version}"
    mappings "net.fabricmc:yarn:${yarn_mappings}"
    modCompile "net.fabricmc:fabric-loader:${loader_version}"

    modCompile "net.fabricmc.fabric-api:fabric-api:${fabric_version}"
  }

  configurations {
    compile
  }

  task remapMavenJar(type: Copy, dependsOn: remapJar) {
    afterEvaluate {
      from("${project.buildDir}/libs/$archivesBaseName-${version}.jar")
      into("${project.buildDir}/libs/")
      rename { String fn -> "$archivesBaseName-${version}-maven.jar" }
    }
  }

  sourceCompatibility = JavaVersion.VERSION_1_8
  targetCompatibility = JavaVersion.VERSION_1_8

  publishing {
    publications {
      mavenJava(MavenPublication) {
        artifact(file("${project.buildDir}/libs/$archivesBaseName-${version}-maven.jar")) {
                    builtBy remapMavenJar
        }
        artifact(sourcesJar) {
          builtBy remapSourcesJar
        }
      }
    }

    repositories {
      mavenLocal()
    }
  }

  afterEvaluate {
    artifacts {
      compile file: file("${project.buildDir}/libs/$archivesBaseName-${version}-dev.jar"), type: "jar", builtBy: jar
    }

    processResources {
      inputs.property "version", project.version

      from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
      }

      from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
      }
    }
  }

  jar {
    from "LICENSE"
  }

  tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
  }

  task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
  }
}

project(':rpgcraft') {
  archivesBaseName = 'rpgcraft'
  version = '0.1.0'
  group = 'net.hellomouse'

  dependencies {
    compileOnly 'io.github.prospector.modmenu:ModMenu:1.6.3-95'
  }
}

project(':inwizardry') {
  archivesBaseName = 'inwizardry'
  version = '0.1.0'
  group = 'net.hellomouse'

  dependencies {
    modCompile project(':rpgcraft')
  }
}

tasks.register("runClient", RunClientTask.class) {
  dependsOn(":inwizardry:runClient")
}

tasks.register("runServer", RunServerTask.class) {
  dependsOn(":inwizardry:runServer")
}

tasks.register("build") {
  dependsOn(":rpgcraft:build")
  dependsOn(":inwizardry:build")
}