ESM:DebugLog.psc

ScriptName ESM:DebugLog Const DebugOnly
{ Script for debug logging functions }




Bool Function OpenLog() DebugOnly Global

    Return Debug.OpenUserLog( "ESM_Debug_Log" )

EndFunction




Function CloseLog() DebugOnly Global

    Debug.CloseUserLog( "ESM_Debug_Log" )

EndFunction




String Function AddReferenceToTrace( String sBase, ScriptObject sAdd ) DebugOnly Global

    If( sAdd == None )
        Return sBase
    EndIf

    If( sBase != "" )
        sBase += " :: "
    EndIf

    Return sBase + sAdd

EndFunction




String Function AddStringToTrace( String sBase, String sAdd ) DebugOnly Global

    If( sAdd == "" )
        Return sBase
    EndIf

    If( sBase != "" )
        sBase += " :: "
    EndIf

    Return sBase + sAdd

EndFunction



Function WriteInfo( ScriptObject soCaller = None, String sFunction = "", String sMessage = "" ) DebugOnly Global

    String sTrace

    sTrace = AddReferenceToTrace( sTrace, soCaller )
    sTrace = AddStringToTrace( sTrace, sFunction )
    sTrace = AddStringToTrace( sTrace, sMessage )

    Debug.TraceUser( "ESM_Debug_Log", sTrace, 0 )

EndFunction




Function WriteWarning( ScriptObject soCaller = None, String sFunction = "", String sMessage = "" ) DebugOnly Global

    String sTrace

    sTrace = AddReferenceToTrace( sTrace, soCaller )
    sTrace = AddStringToTrace( sTrace, sFunction )
    sTrace = AddStringToTrace( sTrace, "Warning" )
    sTrace = AddStringToTrace( sTrace, sMessage )

    Debug.TraceUser( "ESM_Debug_Log", sTrace, 1 )

EndFunction




Function WriteError( ScriptObject soCaller = None, String sFunction = "", String sMessage = "" ) DebugOnly Global

    String sTrace

    sTrace = AddReferenceToTrace( sTrace, soCaller )
    sTrace = AddStringToTrace( sTrace, sFunction )
    sTrace = AddStringToTrace( sTrace, "ERROR" )
    sTrace = AddStringToTrace( sTrace, sMessage )

    Debug.TraceUser( "ESM_Debug_Log", sTrace, 2 )

EndFunction