SHARE
TWEET

mire pour thomson TO7/8/9/+ MO5/6

a guest Sep 17th, 2010 152 Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. 5 ' MIRE POUR THOMSON
  2. 10 CLEAR,,65
  3. 20 LOCATE 0,0,0:CONSOLE,,0
  4. 30 DEFINT A-Z
  5. 40 ' definition caracteres
  6. 50 FOR NIV=0 TO 64
  7. 60   LOCATE 0,0: PRINT "Definition niveau:";NIV;" ";
  8. 70   RESTORE 390
  9. 80   FOR I=0 TO 7
  10. 90     V(I) = 0: W=1
  11. 100     FOR J=0 TO 7
  12. 110       READ A
  13. 120       IF NIV>A THEN V(I)=V(I)+W
  14. 130       W = W*2
  15. 140     NEXT
  16. 150   NEXT
  17. 160   DEFGR$(NIV)=V(0),V(1),V(2),V(3),V(4),V(5),V(6),V(7)
  18. 170   PRINT GR$(NIV);"                "
  19. 180 NEXT
  20. 190 NIV=64
  21. 200 PAL=15
  22. 210 BASE = 1+16+256
  23. 220 SCREEN 7,0,0:LOCATE 0,0:PRINT"                                        "
  24. 230 PALETTE 1,PAL*BASE:BOXF(0,8)-(319,199),1
  25. 240 A=8:B=5
  26. 250 BOXF(A,B)-(39-A,25-B)GR$(NIV):PALETTE 1,PAL*273:CONSOLE,,1
  27. 260 DO
  28. 270   LOCATE 0,0: PRINT USING "pal==## niv==## (###%)  pc==###";PAL;NIV;INT(NIV*100/64);INT(255*(NIV/64.0)^0.454545)
  29. 280   A$=INPUT$(1)
  30. 290   IF A$=CHR$(3) THEN EXIT
  31. 300   IF A$=CHR$(8) AND NIV>0 THEN NIV=NIV-1:BOXF(A,B)-(39-A,25-B)GR$(NIV)
  32. 310   IF A$=CHR$(9) AND NIV<64 THEN NIV=NIV+1:BOXF(A,B)-(39-A,25-B)GR$(NIV)
  33. 320   IF A$=CHR$(10) AND PAL>0 THEN PAL=PAL-1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  34. 330   IF A$=CHR$(11) AND PAL<15 THEN PAL=PAL+1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  35. 340   IF A$="0" THEN BASE=273:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  36. 350   IF A$="1" THEN BASE=1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  37. 360   IF A$="2" THEN BASE=16:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  38. 370   IF A$="3" THEN BASE=256:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
  39. 380 LOOP
  40. 390 DATA 0,48,12,60,3,51,15,63
  41. 400 DATA 32,16,44,28,35,19,47,31
  42. 410 DATA 8,56,4,52,11,59,7,55
  43. 420 DATA 40,24,36,20,43,27,39,23
  44. 430 DATA 2,50,14,62,1,49,13,61
  45. 440 DATA 34,18,46,30,33,17,45,29
  46. 450 DATA 10,58,6,54,9,57,5,53
  47. 460 DATA 42,26,38,22,41,25,37,21
RAW Paste Data
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy. OK, I Understand
 
Top