TrigBODCollector.euo

gosub TrigStatusMenu

;************************
;******** Config  *******
;************************
set %smithID FXNB
set %smithBag TFNVLND

set %tailorID MBVCU
set %tailorBag OKUNVBE

set %tamingID XXXX
set %tamingBag OKUNVBE

set %carpID XXXX
set %carpBag OKUNVBE

set %numChars 5
set %char1 0
set %char2 1
set %char3 2
set %char4 3
set %char5 4

;************************
;******* Main Loop ******
;************************
;gosub login 2
while 1 > 0
{
  set %startTime #sysTime
  set %endTime %startTime + 3750000



  for %loopi 1 %numChars
  {
     menu set update_status Collecting for %account char slot %char . %loopi
     gosub MainLoopCall %char . %loopi
     wait 1s
  }

  set %timeToWait %endTime - #sysTime
  set %timeToWait %timeToWait / 1000
  for %loopTime 1 %timeToWait
  {
     set %timeLeft %timeToWait - %loopTime
     menu set update_status %timeLeft seconds until starting
     wait 1s
  }
}

sub MainLoopCall
  gosub login %1
  gosub openpack

  ;; Smith
  gosub getNewBod %smithID
  gosub moveDeedsToBag %smithBag

  ;; Tailor
  gosub getNewBod %tailorID
  gosub moveDeedsToBag %tailorBag

  ;; Taming
  gosub getNewBod %tamingID
  gosub moveDeedsToBag %tamingBag

  ;; Carp
  gosub getNewBod %carpID
  gosub moveDeedsToBag %carpBag

  gosub logout
return

sub moveDeedsToBag
  set %targetBag %1
  Menu set sub_status Moving Deeds
  finditem EYM
  while #FINDCNT > 0
  {
    exevent drag #findid 1
    exevent dropc %targetBag ;
    sleep 500
    finditem EYM
  }
return

sub openpack
  set #LOBJECTID #BACKPACKID
  event macro 17 0
  gosub waitgump for container_gump 230_204 5
return

sub getNewBod
   set %currentVendor %1
   gosub useVendor %currentVendor 3
   if #RESULT = #FALSE
   {
      event SysMessage Couldn't find vendor %currentVendor
      return
   }
   wait 1s
   click 75 75
   wait 2s
   set %clickOffY #contsizey - 30
   gosub click_offset 105 %clickOffY
   wait 1s
return

sub useVendor
        set !useVendorCnt 0
        set !_vendorID %1
        set !_contextOption %2
        finditem !_vendorID G_9
        if #findkind = -1
                return #false
        exevent popup !_vendorID !_contextOption
return #true

sub logout
   Menu set sub_status Logging out!
_logoutLoop:
   wait 1
   if #contname = MainMenu_gump
      return

   if #contname = YesNo_gump
   {
      set %x #contposx + 120
      set %y #contposy + 90
      click %x %y

   }
   if #contname = paperdoll_gump
   {
      contpos #clixres 0
      wait 2
      set !paperDollX #clixres + 210
      click !paperDollX 110
      gosub waitgump for YesNo_gump 178_108 5
      goto _logoutLoop
   }
   if #contname <> paperdoll_gump
   {
      event macro 8 1
      gosub waitgump for paperdoll_gump 262_324 5
      goto _logoutLoop
   }

return

sub login
Menu set sub_status Begin Login
set %charnum %1
_loginLoop:
  if #contname = MainMenu_gump && #contsize = 640_480
  {
     Menu set sub_status Enter Account Details
     ;gosub enterAccountPass
     gosub clickgreen
     Menu set sub_status Wait for Accept
     gosub waitgump notfor MainMenu_gump 640_480 25
     goto _loginLoop
  }

  if #contname = normal_gump && #contsize = 640_480
  {
     Menu set sub_status Click Next for Shard
     gosub clickgreen
     Menu set sub_status Wait for Char Select
     gosub waitgump for normal_gump 2_2 25
     goto _loginLoop
  }

  if #contname = normal_gump && #contsize = 2_2
  {
     click 370 165
     Menu set sub_status Click first Char
     gosub waitgump notfor normal_gump 2_2 25
     goto _loginLoop
  }

  if #contname = Login_gump
  {
     Menu set sub_status Select Char
     set %x 370
     set %y 165 + 40 * %charnum
     click %x %y
     gosub clickgreen
     Menu set sub_status Wait til logged in
     gosub waitgump notfor Login_gump 640_480 25
     goto _loginLoop
  }
  if #CLILOGGED = 0
     goto _loginLoop
return

;************************
;******* Enter Acc ******
;************************
; takes char number argument
sub enterAccountPass
  click 400 360
  gosub sendstring %account
  click 400 400
  gosub sendstring %mypass
return


;************************
;******* Send Str  ******
;************************
sub sendstring
  str Len %1
  set %len #strRes
  for %i 1 16
  	{
  	key back ; delete current if any
  	wait 1
  	}
  for %i 1 %len
  	{
  	str Mid %1 %i 1
  	key #strRes
  	wait 1
  	}
return

;************************
;***** Click Green ******
;************************
sub clickgreen
  set %x 620
  set %y 445
  click %x %y ; the green arrow
  wait 5
return

;************************
;****** Wait Gump *******
;************************
sub waitgump
  ;%1 = for or notfor %2 = kind of gump %3 = size %4= timeout
  set %timout #scnt + %4
  _wfgloop:
  if #scnt > %timout
  	return
  wait 10
  if %1 = for && ( #contname <> %2 || #contsize <> %3 )
  	goto _wfgloop
  if %1 = notfor && #contname = %2 && #contsize = %3
  	goto _wfgloop
return

sub click_offset
	set %clickx #contposx + %1
	set %clicky #contposy + %2
	click %clickx %clicky f
return


sub TrigStatusMenu
        menu Clear
        menu Window Title TrigBodCollector
        menu Window Color Black
        menu Window Size 250 60
        menu Font Transparent #true
        menu Font Align Right
        menu Font Name MS Sans Serif
        menu Font Size 10
        menu Font Style b
        menu Font Color Lime
        menu Font Align Left
        menu Font BGColor None
        menu Text status 10 5 Status:
        menu Font Style
        menu Font Size 8
        menu Text update_status 60 7 Loading...
        menu Font Size 10
        menu Font Color Window
        menu Font Style b
        menu Font BGColor Black

        menu Text sub_status 30 30 Loading...
        menu Font Style
        menu Font Size 8


        menu HideEUO
        menu Show 650 25
return