Opera Next 12.00 Alpha

# Maintainer: ruario
# Contributor: RobertMe
# Contributor: BlackEagle
# Contributor: Skunnyk
# Contributor: totoloco
pkgname=opera-next # Set to opera if you want to replace your main/stable build
_bigrelease=12.00
_buildver=1105
_randomizer=alpha
pkgver=${_bigrelease}_${_buildver}
pkgrel=1
pkgdesc="A fast and secure web browser and Internet suite. Alpha version."
url="http://my.opera.com/desktopteam/blog/"
depends=('gcc-libs' 'libxt' 'freetype2' 'libxext')
replaces=('opera-devel')
optdepends=('gtk2: GTK integration'
        'kdebase-runtime: KDE4+ integration'
        'gstreamer0.10-base-plugins: HTML5 open codecs support'
        'gstreamer0.10-good: HTML5 open codecs support'
        'gstreamer0.10-ffmpeg: HTML5 not so open codecs support'
        'gstreamer0.10-bad-plugins: HTML5 not so open codecs support')
install=opera-next.install
options=(!strip !zipman)
license=('custom:opera')
arch=('i686' 'x86_64')
_arch=i386
[ "$CARCH" = "x86_64" ] && _arch=x86_64
source=(http://snapshot.opera.com/unix/${_randomizer}_${_bigrelease}-${_buildver}/opera-next-${_bigrelease}-${_buildver}.${_arch}.linux.tar.xz)
md5sums=('5aeed8e165fa3ec0bfc538454bde2f27')
[ "$CARCH" = "x86_64" ] && md5sums=('c8371bc85b3baef0f2cab8b92d159c93')

# Uncomment the following line, if you want your User Agent to include Arch Linux.
#_opdistro="Arch Linux"

package() {

    # 'Install' Opera into $pkgdir
    opera-next-${_bigrelease}-${_buildver}.${_arch}.linux/install --prefix /usr --name ${pkgname} --repackage "${pkgdir}/usr"
    install -D -m 644 "${pkgdir}/usr/share/${pkgname}/defaults/license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/license.txt"

    # Insert an Arch User Agent string if set
    if [ -n "${_opdistro}" ]
    then
        mkdir -p "${pkgdir}/usr/share/${pkgname}/custom/defaults"
        echo "[ISP]" > "${pkgdir}/usr/share/${pkgname}/custom/defaults/operaprefs.ini"
        echo "Id=${_opdistro}" >> "${pkgdir}/usr/share/${pkgname}/custom/defaults/operaprefs.ini"
        chmod 644 "${pkgdir}/usr/share/${pkgname}/custom/defaults/operaprefs.ini"
    fi
}