gogglesmm

# Maintainer: Sander Jansen <s.jansen@gmail.com>
pkgname=gogglesmm-hg
pkgver=100
pkgrel=1
pkgdesc="Goggles Music Manager"
arch=('i686' 'x86_64')
url="http://code.google.com/p/gogglesmm/"
license=('GPL3')
conflicts=('gogglesmm')
depends=('fox-devel>=1.7.28' 'libgaplayer' 'dbus-core' 'taglib>=1.6.3' 'sqlite3' 'libgcrypt')
makedepends=('mercurial' 'pkgconfig' 'librsvg' 'glproto' 'dri2proto' )
md5sums=() #generate with 'makepkg -g'

_hgroot="http://code.google.com/p"
_hgrepo="gogglesmm"

build() {
  cd $srcdir
  msg "Connecting to Mercurial server...."

  if [[ -d $_hgrepo ]]; then
    cd $_hgrepo
    hg pull -u
    msg "The local files are updated."
  else
    hg clone $_hgroot/$_hgrepo
  fi

  msg "Mercurial checkout done or server timeout"
  msg "Starting build..."

  rm -rf $srcdir/$_hgrepo-build
  cp -r $srcdir/$_hgrepo $srcdir/$_hgrepo-build
  cd $srcdir/$_hgrepo-build

  ./configure prefix=/usr
  make
  make svg2png
}

package() {
  cd $srcdir/$_hgrepo-build
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: