TinyBasic Fixed Point Mandelbrot

1 rem Fixed point character mandelbrot - VinCBR900
2 let B = 15000: rem Right Edge = 1.5
3 let C = 15000: rem Top Edge = 1.5
4 let D =-15000: rem Bottom Edge = -1.5
5 let E = 200: rem Max Iteration Depth
6 let F = 350: rem X Step Size
7 let G = 750: rem Y Step Size
8 let A =-21000: rem Left Edge = -2.1
9 rem Tweaked from RosettaCode
10 goto 100
32 Print " "; : Return
48 Print "0"; : Return
49 Print "1"; : Return
50 Print "2"; : Return
51 Print "3"; : Return
52 Print "4"; : Return
53 Print "5"; : Return
54 Print "6"; : Return
55 Print "7"; : Return
56 Print "8"; : Return
57 Print "9"; : Return
64 Print "@"; : Return
70 goto 1000
100 For L = C To D Step -G: rem Y0
110 For K = A To B-1 Step F: rem X0
120 let V = 0: rem Y
130 let U = 0: rem X
140 let I = 32: rem Char To Be Displayed
150 For O = 0 To E-1: rem Iteration
160 let X = (U/10 * U) / 1000: rem X*X
170 let Y = (V/10 * V) / 1000: rem Y*Y
180 If (X + Y > 40000) then goto 200
190 goto 250
200 let I = 48 + O: rem Print Digit 0...9
210 If (O > 9) then let I=64: rem If Iteration Count > 9,
220 goto 290
250 let Z = X - Y + K: rem Temp = X*X - Y*Y + X0
260 let V = (U/10 * V) / 500 + L: rem Y = 2*X*Y + Y0
270 let U = Z: rem X = Temp
280 Next O
290 Gosub I: rem  Ins_char(I)
300 Next K
310 Print
320 Next L