gloobus-preview PKGBUILD

# Maintainer: György Balló <ballogy@freestart.hu>
pkgname=gloobus-preview
pkgver=0.4.5.263
_pkgver=0.4.5-ubuntu11~ppa288+1~webupd8~precise
pkgrel=1
pkgdesc="An extension of Gnome designed to enable a full screen preview of any kind of file"
arch=(i686 x86_64)
url="http://gloobus.net/"
license=(GPL)
depends=(gtksourceview2 gstreamer0.10-base-plugins poppler-glib libspectre djvulibre taglib python2-gconf xdg-utils)
makedepends=(bzr automake libtool coreutils gcc)
optdepends=('unoconv: preview LibreOffice compatible documents')
options=(!libtool)
install="${pkgname}.install"
source=("https://launchpad.net/~gloobus-dev/+archive/${pkgname}/+files/${pkgname}_${_pkgver}.tar.gz")
md5sums=(b0963c78634425cb9ee1e4f4de670a08)

build() {
  cd "${srcdir}/${pkgname}"
  sed -i 's@^#!.*python$@#!/usr/bin/python2@' src/gloobus-preview-configuration

  # Disable failing on warnings
  sed -i 's/ -Werror//g' configure.ac

  ./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make -j8
}

package() {
  cd "$srcdir/$pkgname"

  make -j8 DESTDIR="$pkgdir/" install
}