archlinux-pkgbuild-onioncat-git.txt

# Maintainer: revel <revelΘmuub·net>
# Contributor: jwwolf <jwwolf+arch@gmail.com>
# Contributor: anon@publicdomain

# dear maintainers
# please upload onioncat source archives to github.com
# so we can at least verify checksums
# like
# https://www.cypherpunk.at/ocat/download/Source/0.2.2/onioncat-0.2.2.r578.tar.gz{,.asc}
# which is currently not accessible --> http 403 forbidden

# also
# please fix configure.ac
# and src/.deps/*.Po
# see build() function

_pkgnamepfx=onioncat
pkgname=${_pkgnamepfx}-git
_pkgverpfx=0.2.2.
pkgver=${_pkgverpfx}r245.8e7f6eb
pkgrel=1
pkgdesc='An IP-Transparent Tor Hidden Service Connector'
arch=('i686' 'x86_64')
url='https://www.onioncat.org/'
license=('GPL3')
depends=('tor' 'net-tools')
makedepends=('git')
provides=("$_pkgnamepfx")
conflicts=("$_pkgnamepfx")

# in microsoft-github we trust ... not
install=
source=('git+https://github.com/rahra/onioncat.git')

noextract=()
md5sums=('SKIP')

build() {
    cd "$srcdir/$_pkgnamepfx"

    # patch svn --> git
    # 'EOF' disables variable expansion
cat << 'EOF' | patch -p1
--- a/configure.ac
+++ b/configure.ac
@@ -1,6 +1,6 @@

 AC_PREREQ(2.62)
-define([svnversion], esyscmd([sh -c "echo -n $(( `svnversion | tr -d 'M'` + 1 ))"]))dnl
+define([svnversion], esyscmd([sh -c 'printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"']))dnl
 AC_INIT([onioncat],[[0.2.2.r]svnversion],[rahra@cypherpunk.at])
 AM_INIT_AUTOMAKE([-Wall -Werror])
 AC_CONFIG_HEADERS([config.h])
EOF

    aclocal
    autoconf
    # ... otherwise configure will complain about aclocal version mismatch

    ./configure --prefix=/usr

    # create dummy *.Po files
    mkdir src/.deps
    while read f
    do
        echo touch src/.deps/$f
        touch src/.deps/$f
    done < <(grep -o -E './\$\(DEPDIR\)/[^ ]*.Po' src/Makefile.in | cut -c13-)

    make
}

package() {
    cd "$srcdir/$_pkgnamepfx"
    make DESTDIR="$pkgdir/" install
}

pkgver() {
    cd "$srcdir/$_pkgnamepfx"
    # Git, no tags available
    printf "%sr%s.%s" ${_pkgverpfx} "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}