<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet exclude-result-prefixes="query cmd dncv soap-env"
version="1.0"
xmlns:cmd="http://www.novell.com/nxsl/java/com.novell.nds.dirxml.driver.XdsCommandProcessor"
xmlns:dncv="http://www.novell.com/nxsl/java/com.novell.nds.dirxml.driver.DNConverter"
xmlns:query="http://www.novell.com/nxsl/java/com.novell.nds.dirxml.driver.XdsQueryProcessor"
xmlns:soap-env="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <!-- parameters passed in from the Identity Manager engine -->
    <xsl:param name="srcQueryProcessor"/>
    <xsl:param name="destQueryProcessor"/>
    <xsl:param name="srcCommandProcessor"/>
    <xsl:param name="destCommandProcessor"/>
    <xsl:param name="dnConverter"/>
    <xsl:param name="fromNds"/>
    <!-- This is for testing the stylesheet outside of Identity Manager so things are pretty to look at -->
    <xsl:strip-space elements="*"/>
    <xsl:preserve-space elements="value component password check-password"/>
    <xsl:output indent="yes" method="xml"/>
    <!-- ################################################## -->
    <!-- We first check if sending data to OPUS is allowed, -->
    <!-- and if a valid MANumber is present in the document -->
    <!-- ################################################## -->
    <xsl:template match="add" xmlns:java="java:dk.unic.infotjeneste.webservice.returTyper" xmlns:m="https://infotjeneste.uni-c.dk" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
        <xsl:if test="'~drv.data.opus.ret~' = 'true'">

            <xsl:variable name="lMANumber" select="add-attr[@attr-name='xAttrMANumber']/value"/>
            <xsl:if test="$lMANumber">
                <xsl:message>#### Calling Prepare Employments Communication Data Template ####</xsl:message>
                <xsl:call-template name="PrepareEmploymentCommunicationData">
                    <xsl:with-param name="lMANumber" select="$lMANumber"/>
                </xsl:call-template>
            </xsl:if>
        </xsl:if>
        <xsl:if test="'~drv.data.opus.ret~' != 'true'">
            <xsl:message>#### Not calling Prepare Employments Communication Data Template since the GCV is set to false ####</xsl:message>
        </xsl:if>
    </xsl:template>

    <!-- ############################################### -->
    <!-- Prepare Employments Communication Data Template -->
    <!-- ############################################### -->
    <xsl:template name="PrepareEmploymentCommunicationData" xmlns:soap="http://www.w3.org/2003/05/soap-envelope">

        <xsl:param name="lMANumber"/>

        <xsl:message>#### Driver document MANumber: <xsl:value-of select="$lMANumber"/> ####
        </xsl:message>
        <xsl:variable name="lCN" select="add-attr[@attr-name='cn']/value"/>
        <xsl:message>#### Driver document CN: <xsl:value-of select="$lCN"/> ####
        </xsl:message>
        <xsl:variable name="lTelephoneNumber" select="add-attr[@attr-name='telephonenumber']/value"/>
        <xsl:message>#### Driver document Telephone Number: <xsl:value-of select="$lTelephoneNumber"/> ####
        </xsl:message>
        <xsl:variable name="lMobile" select="add-attr[@attr-name='mobile']/value"/>
        <xsl:message>#### Driver document Mobile: <xsl:value-of select="$lMobile"/> ####
        </xsl:message>
        <xsl:variable name="lEmail" select="add-attr[@attr-name='mail']/value"/>
        <xsl:message>#### Driver document Mail: <xsl:value-of select="$lEmail"/> ####
        </xsl:message>
        <xsl:variable name="lITBruger" select="add-attr[@attr-name='xAttrITBruger']/value"/>
        <xsl:message>#### Driver document IT Bruger: <xsl:value-of select="$lITBruger"/> ####
        </xsl:message>
        <xsl:variable name="lCurrentDate" select="add-attr[@attr-name='CurrentDate']/value"/>
        <xsl:message>#### Driver document Current date: <xsl:value-of  select="$lCurrentDate"/> ####
        </xsl:message>

        <xsl:message>#### Updating Communication Data for MANumber: <xsl:value-of select="$lMANumber"/> ####</xsl:message>
        <xsl:if test="$lCN">
            <xsl:message>#### Updating CN to <xsl:value-of select="$lCN"/> ####</xsl:message>
            <xsl:call-template name="ModifyEmployment">
                <xsl:with-param name="lMANumber" select="$lMANumber"/>
                <xsl:with-param name="lValue" select="$lCN"/>
                <xsl:with-param name="lKommunikationsart" select="'0001'"/>
                <xsl:with-param name="lCurrentDate" select="$lCurrentDate"/>
            </xsl:call-template>
        </xsl:if>
        <xsl:if test="$lTelephoneNumber">
            <xsl:message>#### Updating TelephoneNumber to <xsl:value-of select="$lTelephoneNumber"/> ####</xsl:message>
            <xsl:call-template name="ModifyEmployment">
                <xsl:with-param name="lMANumber" select="$lMANumber"/>
                <xsl:with-param name="lValue" select="$lTelephoneNumber"/>
                <xsl:with-param name="lKommunikationsart" select="'0020'"/>
                <xsl:with-param name="lCurrentDate" select="$lCurrentDate"/>
            </xsl:call-template>
        </xsl:if>
        <xsl:if test="$lMobile">
            <xsl:message>#### Updating Mobile to <xsl:value-of select="$lMobile"/> ####</xsl:message>
            <xsl:call-template name="ModifyEmployment">
                <xsl:with-param name="lMANumber" select="$lMANumber"/>
                <xsl:with-param name="lValue" select="$lMobile"/>
                <xsl:with-param name="lKommunikationsart" select="'9021'"/>
                <xsl:with-param name="lCurrentDate" select="$lCurrentDate"/>
            </xsl:call-template>
        </xsl:if>
        <xsl:if test="$lEmail">
            <xsl:message>#### Updating Email to <xsl:value-of select="$lEmail"/> ####</xsl:message>
            <xsl:call-template name="ModifyEmployment">
                <xsl:with-param name="lMANumber" select="$lMANumber"/>
                <xsl:with-param name="lValue" select="$lEmail"/>
                <xsl:with-param name="lKommunikationsart" select="'0010'"/>
                <xsl:with-param name="lCurrentDate" select="$lCurrentDate"/>
            </xsl:call-template>
        </xsl:if>
        <xsl:if test="$lITBruger">
            <xsl:message>#### Updating ITBruger to <xsl:value-of select="$lITBruger"/> ####</xsl:message>
            <xsl:call-template name="ModifyEmployment">
                <xsl:with-param name="lMANumber" select="$lMANumber"/>
                <xsl:with-param name="lValue" select="$lITBruger"/>
                <xsl:with-param name="lKommunikationsart" select="'9905'"/>
                <xsl:with-param name="lCurrentDate" select="$lCurrentDate"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

    <!-- ########################################### -->
    <!-- ####### Modify Employments Template ####### -->
    <!-- ########################################### -->
    <xsl:template name="ModifyEmployment" xmlns:soap="http://www.w3.org/2003/05/soap-envelope">
        <xsl:param name="lMANumber"/>
        <xsl:param name="lValue"/>
        <xsl:param name="lKommunikationsart"/>
        <xsl:param name="lCurrentDate"/>
        <xsl:message>#### Kommunikationsart for update: <xsl:value-of select="$lKommunikationsart"/> ####</xsl:message>
        <xsl:message>#### Updating with value: <xsl:value-of select="$lValue"/> ####</xsl:message>
        <xsl:variable name="query-modifyEmployment">
            <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:urn="urn:oio:medarbejder:1.0.0" xmlns:urn1="urn:oio:sagdok:3.0.0">
                <soapenv:Header/>
                <soapenv:Body>
                    <urn:RetInput>
                        <urn1:ModtagerRef>
                            <urn1:UUIDIdentifikator/>
                            <urn1:URNIdentifikator>urn:oio:kmd:lpe:modtager:<xsl:value-of select="'~drv.data.opus.customerid~'"/>
                            </urn1:URNIdentifikator>
                        </urn1:ModtagerRef>
                        <urn1:MedarbejderRef>
                            <urn1:UUIDIdentifikator/>
                            <urn1:URNIdentifikator>urn:oio:kmd:lpe:medarbejder:<xsl:value-of select="$lMANumber"/>
                            </urn1:URNIdentifikator>
                        </urn1:MedarbejderRef>
                        <urn:AttributListe>
                            <urn:Egenskaber>
                                <xsl:if test="$lValue">
                                    <urn:Kommunikation>
                                        <urn:Gyldighedsstart>
                                            <xsl:value-of select="$lCurrentDate"/>
                                        </urn:Gyldighedsstart>
                                        <urn:Gyldighedsstop>9999-12-31</urn:Gyldighedsstop>
                                        <urn:Sekvensnummer>000</urn:Sekvensnummer>
                                        <urn:Kommunikationsart>
                                            <xsl:value-of select="$lKommunikationsart"/>
                                        </urn:Kommunikationsart>
                                        <urn:KommunikationsID>
                                            <xsl:value-of select="$lValue"/>
                                        </urn:KommunikationsID>
                                    </urn:Kommunikation>
                                </xsl:if>
                            </urn:Egenskaber>
                        </urn:AttributListe>
                    </urn:RetInput>
                </soapenv:Body>
            </soapenv:Envelope>
        </xsl:variable>

        <xsl:variable name="result-modifyEmployment" select="query:query($destQueryProcessor,$query-modifyEmployment)"/>

        <xsl:if test="$result-modifyEmployment//ns1:StandardRetur//ns1:StatusKode=0" xmlns:ns1="urn:oio:sagdok:3.0.0">
            <xsl:message>#### Modify Employment with MANumber: <xsl:value-of select="$lMANumber"/> on kommunikationsart: <xsl:value-of select="$lKommunikationsart"/> with value: <xsl:value-of select="$lValue"/> was successful. ####</xsl:message>
        </xsl:if>
        <xsl:if test="$result-modifyEmployment//ns1:StandardRetur//ns1:StatusKode=101" xmlns:ns1="urn:oio:sagdok:3.0.0">
            <xsl:message>#### Modify Employment with MANumber: <xsl:value-of select="$lMANumber"/> on kommunikationsart: <xsl:value-of select="$lKommunikationsart"/> with value: <xsl:value-of select="$lValue"/> was unsuccessful. This can be because the value attempted to be set is empty, and the value is already empty in OPUS. This results in error 101. If the value attempted to be set is CN (kommunikationsart 0001) and this value already exists on another employment, the call results in an error aswell. This might be because of data inconsistence (the value is on an employment it was not expected to be on). ####</xsl:message>
        </xsl:if>

    </xsl:template>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>