string_to_real()

/// @param string
/// @jujuadams 2019/04/18

var _string = argument0;

var _fail_value = 0;
var _hit_space  = false;
var _hit_number = false;

var _size = string_length(_string);
for(var _i = _size; _i > 0; _i--)
{
    var _character = string_char_at(_string, _i);
    switch(_character)
    {
        case "0":
        case "1":
        case "2":
        case "3":
        case "4":
        case "5":
        case "6":
        case "7":
        case "8":
        case "9":
        case ".":
        case "-":
            if (_hit_space && _hit_number) return _fail_value;
            _hit_space  = false;
            _hit_number = true;
        break;

        case " ":
            _string = string_delete(_string, _i, 1);
            _hit_space = true;
        break;

        default:
            return _fail_value;
        break;
    }
}

if (string_count("-", _string) > 1) return undefined;
if (string_count(".", _string) > 1) return undefined;

var _negative_pos = string_pos("-", _string);
if (_negative_pos > 1) return undefined;
if (string_pos(".", _string) == (1+_negative_pos)) return undefined;

return real(_string);