thunderbird-theme-adwaita-git-17.0_bfcd5c5-1: PKGBUILD

# Maintainer: Diego Principe <cdprincipe@at@gmail@dot@com>
# Contributor: jtts

pkgname=thunderbird-theme-adwaita-git
pkgver=17.0_bfcd5c5
pkgrel=1
pkgdesc="Adwaita theme for Thunderbird (Matches the default Gnome Shell theme)"
url="https://addons.mozilla.org/en-US/thunderbird/addon/adwaita-thunderbird"
arch=('any')
license=('MPL')
depends=("thunderbird")
makedepends=('unzip' 'git')
provides=('thunderbird-theme-adwaita')
conflicts=('thunderbird-theme-adwaita')
source=("git://github.com/gnome-integration-team/thunderbird-gnome.git#commit=bfcd5c5400f5ae7d7cbdf2fa623efb94a098c46b"
	"0001-Add-white-border-after-tabs-toolbar.patch"
	"0002-Port-.css-for-textbox-menu-notification-from-firefox.patch"
	"0003-Upgrade-to-Thunderbird-24.0.1.patch"
	"0004-Port-changes-in-about-addons-page-from-gnome-firefox.patch")
sha256sums=(SKIP
	    '9c43415902fe1f317d0a6beb21fb06de392940912f2b2b0e43b7801cb6ebbb3f'
            '8f4f542276b4437eeba5acf7351f5333fbc138de6bd11879014520640a84212e'
            '461e34dcde8ef80ee96d3bf0c5fd11e2b8e794bed935a88847e7e07749caf571'
            'c135d69cd894777888e4f0df1bfb305970061c0253b19fbf15452abb9c1173ff')

pkgver() {
  cd $srcdir/thunderbird-gnome
  echo $(cat $srcdir/thunderbird-gnome/theme/install.rdf | grep em:version | cut -f2 -d'>' | cut -f1 -d'<')_$(git rev-parse --short HEAD)
}

prepare() {
  cd $srcdir/thunderbird-gnome
  git am < "$srcdir/0001-Add-white-border-after-tabs-toolbar.patch"
  git am < "$srcdir/0002-Port-.css-for-textbox-menu-notification-from-firefox.patch"
  git am < "$srcdir/0003-Upgrade-to-Thunderbird-24.0.1.patch"
  git am < "$srcdir/0004-Port-changes-in-about-addons-page-from-gnome-firefox.patch"
}

package() {

rel=$(cat $srcdir/thunderbird-gnome/theme/install.rdf | grep em:version | cut -f2 -d'>' | cut -f1 -d'<')
emid=$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' $srcdir/thunderbird-gnome/theme/install.rdf) || return 1
dstdir=$pkgdir/usr/lib/thunderbird/extensions/${emid}

  cd $srcdir/thunderbird-gnome/theme
  install -d $dstdir
  cp -R * $dstdir
  find $pkgdir -type d -exec chmod 0755 {} \;
  find $pkgdir -type f -exec chmod 0644 {} \;
}