# Maintainer:  tuxce <tuxce;net@gmail.com>
# Contributor: Julien MISCHKOWITZ <wain@archlinux.fr>

pkgname=yaourt-git
pkgver=1.2.1.6.gb0649c9
pkgrel=1
pkgdesc="A pacman wrapper with extended features and AUR support"
arch=('any')
url="http://www.archlinux.fr/yaourt-en/"
license=('GPL')
depends=('package-query-git' 'pacman>=4.1')
makedepends=('git')
optdepends=('aurvote: vote for your favorite AUR packages'
            'customizepkg: automatically modify PKGBUILD during install/upgrade'
            'rsync: retrieve PKGBUILD from official repositories')
provides=('yaourt')
conflicts=('yaourt')
backup=('etc/yaourtrc')
source=('git+http://projects.archlinux.fr/yaourt.git')
md5sums=('SKIP')
_gitname=yaourt

pkgver () {
  cd $_gitname/src
  # Git tag
  echo $(git describe --always | sed 's/-/./g')
  # Date
  #date +"%Y%m%d"
}

build() {
  cd $_gitname/src
  make PREFIX=/usr sysconfdir=/etc localstatedir=/var
}

package() {
  cd $_gitname/src
  make PREFIX=/usr sysconfdir=/etc localstatedir=/var DESTDIR="$pkgdir" install
}