// BNF description of Eggsembly syntax
<syntax>     ::= <optws> <line> | <syntax> <endline> <optws> <line>
<line>       ::=  <keyword>
                | <push>
                | <hatch>
                | "build" <ws> <id> <optws> "{" <endline> <syntax> "}"
                | "while" <torf>    <optws> "{" <endline> <syntax> "}"
                | "if"    <torf>    <optws> "{" <endline> <syntax> "}"
                | <var>
                | <optws>

<endline>    ::= <optws> <EOL> | <endline> <endline>
<torf>       ::= "true"        | "false"
<optws>      ::= " " <optws>   | ""
<ws>         ::= " " <ws>      | " "
<id>         ::= <alunder>     | <id> <alnumunder>
<func>       ::= <id>          | <func> "." <func>

<letter>     ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J" | "K" | "L" | "M"
               | "N" | "O" | "P" | "Q" | "R" | "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z"
               | "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m"
               | "n" | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"

<digit>      ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

<symbol>     ::= "|" | " " | "!" | "#" | "$" | "%" | "&" | "("
               | ")" | "*" | "+" | "," | "-" | "." | "/" | ":"
               | ";" | ">" | "=" | "<" | "?" | "@" | "[" |"\\"
               | "]" | "^" | "_" | "`" | "{" | "}" | "~"

<alnum>      ::= <letter> | <digit>
<alunder>    ::= <letter> | "_"
<alnumunder> ::= <alnum>  | "_"
<any>        ::= <letter> | <digit> | <symbol>
<strchrs1>   ::= <any>    | "'"     | '\"'
<strchrs2>   ::= <any>    | '"'     | "\'"
<string1>    ::= <any>    | <strchrs1> <any>
<string2>    ::= <any>    | <strchrs2> <any>

<num>        ::= <num> <digit> | <digit>
<keyword>    ::= "axe" | "chicken" | "add" | "fox" | "rooster" | "compare" | "pick" | "peck" | "fr" | "bbq"
<str>        ::= '"' <string1> '"' | "'" <string2> "'"
<value>      ::= <str> | <num>
<push>       ::= "push" <ws> <value>
<hatch>      ::= "hatch" <ws> <func>

<var>        ::= <id> <optws> "[" <optws> <num> <optws> "]" <optws> "=" <optws> <value>
               | <id> <optws> "[" <optws> <num> <optws> "]" <optws> "=" <optws> "Top"
               | <id> <optws> "[" <optws> <num> <optws> "]"
               | <id> <optws> "=" <optws> <value>
               | <id> <optws> "=" <optws> "Top"
               | <id>