Shader "Phigames/Mesh Distortion" {

	Properties {
		_D("Distortion", range (-255,255)) = -20
		_CP("Color Strength", Range(0,255)) = 1
		_RP ("Rim Fade Power", Range(0.1, 8)) = 1
	}

	Category {

		Tags { "Queue"="Transparent" "RenderType"="Transparent" }
		ZWrite Off

		SubShader {

			GrabPass {}

			Pass {

				CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				//#pragma multi_compile_fog
				#include "UnityCG.cginc"

				struct v2f {
					float4 color : COLOR;
					float4 vertex : SV_POSITION;
					float4 uvgrab : TEXCOORD0;
					float3 normal : TEXCOORD1;
					UNITY_FOG_COORDS(3)
				};

				float _D;
				sampler2D _GrabTexture;
				float4 _GrabTexture_TexelSize;
				float _CP;
				float _RP;

				v2f vert (appdata_full v)
				{
					v2f o;
					o.color = v.color;
					o.vertex = UnityObjectToClipPos(v.vertex);
					o.uvgrab = ComputeGrabScreenPos(o.vertex);
			    	o.normal = UnityObjectToViewPos(v.normal);

			    	// apply inverse rim distortion, to fade out normals away from camera
					half rim = dot (normalize(ObjSpaceViewDir(v.vertex)), v.normal);
					o.normal *= smoothstep(1 - _RP, 1, rim);

					UNITY_TRANSFER_FOG(o,o.vertex);
					return o;
				}

				half4 frag (v2f i) : SV_Target
				{
					half3 refracted = i.normal * abs(i.normal) * length(_GrabTexture_TexelSize.xy) * i.color.a * _D;
				    i.uvgrab.xy = refracted.xy * i.uvgrab.w + i.uvgrab.xy;
				    half4 refr = tex2Dproj( _GrabTexture, UNITY_PROJ_COORD(i.uvgrab ));
				    refr *= lerp(half4(1,1,1,1), i.color, length(refr.xy) * i.color.a * (abs(_D) / 255) * _CP);
				    UNITY_APPLY_FOG(i.fogCoord, refr);
				    return refr;
				}

				ENDCG
			}
		}
	}
}