dvcs-autosync-git PKGBUILD

# Contributor: Daniele Paolella <danielepaolella@email.it>
# Contributor: Dieter P
pkgname=(dvcs-autosync-git
         dvcs-autosync-devel-git)
pkgver=0.5.192.4bea986
pkgrel=1
pkgdesc="A personal Dropbox replacement based on Git"
arch=('any')
url="http://mayrhofer.eu.org/dvcs-autosync"
license=('GPL')
depends=('python2-pyinotify' 'xmpppy' 'python2')
makedepends=('git')
source=('git://gitorious.org/dvcs-autosync/dvcs-autosync.git')
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/dvcs-autosync"
    git checkout master 2> /dev/null
    echo 0.5.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

pkgver_dvcs-autosync-devel-git() {
    cd "$srcdir/dvcs-autosync"
    git checkout origin/devel 2> /dev/null
    echo 0.6.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

package_dvcs-autosync-git() {
    pkgver=$(pkgver)
    cd "$srcdir/dvcs-autosync"
    git checkout master
    python2 setup.py install --root="$pkgdir" --optimize=1
}

package_dvcs-autosync-devel-git() {
    pkgver=$(pkgver_dvcs-autosync-devel-git)
    conflicts=('dvcs-autosync-git')
    cd "$srcdir/dvcs-autosync"
    git checkout origin/devel
    python2 setup.py install --root="$pkgdir" --optimize=1
}