LoadByFlag

Sub LoadByFlag()

Const ROW_FIRST = 2
Const COL_ID = 1
Const COL_LOADED = 2
Const COL_BARCODE = 3

Dim pictname As String
Dim pictpath As String
Dim pictext As String

Dim pastehere As Range
Dim pasterow As Long
Dim i As Long
Dim lastrow As Long

Dim pictloaded As Boolean

Dim objFSO As Object
Dim barcodeexists As Boolean

    On Error Resume Next

    pictpath = "D:\Dev\AGC\barcodes\barcode_"
    pictext = ".png"
    Set objFSO = CreateObject("Scripting.FileSystemObject")

    lastrow = Worksheets("Data").Range("A1").CurrentRegion.Rows.Count
    For i = ROW_FIRST To lastrow

        Set pastehere = Cells(i, COL_BARCODE)
        pasterow = pastehere.Row
        Cells(pasterow, COL_BARCODE).Select
        pictname = Cells(i, COL_ID)

        '/// Check for the loaded flag and only insert a picture if not present.
        '/// Also check to make sure the barcode exists.
        pictloaded = Cells(i, COL_LOADED) = "1"
        barcodeexists = objFSO.FileExists(pictpath & pictname & pictext)
        If (Not pictloaded) And barcodeexists Then

           ActiveSheet.Pictures.Insert(pictpath & pictname & pictext).Select
           With Selection
               .Left = Cells(pasterow, COL_BARCODE).Left
               .Top = Cells(pasterow, COL_BARCODE).Top
               .ShapeRange.LockAspectRatio = msoTrue
               .ShapeRange.Height = 80#
               .ShapeRange.Width = 80#
               .ShapeRange.Rotation = 0#
           End With

           '/// Make sure that we update the loaded flag for this row
           Cells(i, COL_LOADED).Value = "1"

        End If

    Next

End Sub