qbittorrent-fake

pkgname=qbittorrent-fake
pkgver=2.9.2
pkgrel=1
pkgdesc="A bittorrent client written in C++ / Qt4 using libtorrent-rasterbar library (with uTorrent user-agent)"
arch=('i686' 'x86_64')
url="http://www.qbittorrent.org/"
license=('GPL')
depends=('qt' 'libtorrent-rasterbar' 'xdg-utils')
optdepends=('python2: needed for search'
            'geoip: improves peer country resolution')
makedepends=('boost')
provides=('qbittorrent')
conflicts=('qbittorrent')
source=("http://downloads.sourceforge.net/project/qbittorrent/qbittorrent/qbittorrent-${pkgver}/qbittorrent-${pkgver}.tar.gz")
md5sums=('0c2188e0065be57e50c06f5934d5f7a2')

build() {
  cd qbittorrent-${pkgver}
  sed -i -e 's|sessionSettings.user_agent = "qBittorrent "VERSION;|sessionSettings.user_agent = "uTorrent/2210(25302)";|' \
         ./src/qtlibtorrent/qbtsession.cpp
  sed -i -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
         -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
         $(find ./ -name '*.py')
  ./configure --prefix=/usr
  make
}

package() {
  cd qbittorrent-${pkgver}
  make INSTALL_ROOT=${pkgdir} install
}