Vegetarianboy30

tic tac toe in branflakes

Jan 17th, 2021
1,014
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. torture.b -- play tic-tac-toe
  2.  
  3. --->--->>>>->->->>>>>-->>>>>>>>>>>>>>>>>>+>>++++++++++[
  4.  <<++[
  5.    --<+<<+<<+>>>>[
  6.      >[<->>+++>>[-]<<<+[<++>>+>>-<<<--]]+>+++++[>>++++++++++<<-]
  7.      >>-.[-]>>+[<<<<+>>+>>-]<<<<<<[>+<-]<<
  8.    ]++++++++++.[-]>++
  9.  ]-->>[-->[-]>]<<[
  10.    >>--[
  11.      -[
  12.        -[
  13.          -[
  14.            -[
  15.              -[
  16.                --[<+++++++>>+<+]<-.----->,[<->-]
  17.                -->[[-<<]>>>>]+<[<[-]>>-]>[,[-]<]
  18.              ]<[
  19.                +[[<<]-[>>]<+<-]>[-<+]<<[<<]-<[>[+>>]>[>]+>[-]]
  20.                <-[[+>>]<-->>[>]++++>>+>]
  21.              ]>
  22.            ]<[
  23.              >-[+<+++]+<+++[+[---->]<<<<<<[>]>[<<[-]>>[>]>]]
  24.              >[<+[---->]+[<]<[[>>]+>++++++++>+>]>>[[>]>>>]<<]
  25.              <<+>++>
  26.            ]>
  27.          ]<[
  28.            -[[>+>+<<-]>[<+>-]+++>>+++++>>]
  29.            <[<<++[-->>[-]++>]>[[-]+>[<<+>>-]>]<]
  30.          ]>
  31.        ]<[
  32.          -[
  33.            --[+<<<<--[+>[-]>[<<+>+>-]<<[>>+<<-]]++[>]]
  34.            <<[>>+>+<<<-]>>>[<<<+>>>-]>
  35.          ]<[<<<[-]+++>[-]>[<+>>>+<<-]+>>>]+>
  36.        ]>
  37.      ]<[
  38.        +[[<]<<[<<]-<->>+>[>>]>[>]<-]<[<]<<+<++[[>+<-]++<[<<->>+]<++]<
  39.        <<<<<<      +> > >+> > >+[
  40.        <<<               ->+>+>+[
  41.        <<<<<<<   +>->+> > >->->+[
  42.        <<<<<         ->+>+> >+>+[
  43.        <<<<            ->->+>->+[
  44.        <<<<<<<<+>-> >+> > >->+>+[
  45.        <<<<<         -> >+> >->+[
  46.        <<<<            +>->+> >+]]]]]]]
  47.        +++[[>+<-]<+++]--->>[[<->-]<+++>>]++[[<->-]>>]>[>]
  48.      ]<
  49.    ]
  50.  ]<
  51. ]
  52.  
  53. This program plays tic-tac-toe. I've given it the first move. It needs
  54. interactive i/o, e.g. a command-line branflakes interpreter or a branflakes
  55. compiler that produces command-line executables. At the '>' prompt, enter
  56. the number of an empty space, followed by a linefeed, to play a move there.
RAW Paste Data

Adblocker detected! Please consider disabling it...

We've detected AdBlock Plus or some other adblocking software preventing Pastebin.com from fully loading.

We don't have any obnoxious sound, or popup ads, we actively block these annoying types of ads!

Please add Pastebin.com to your ad blocker whitelist or disable your adblocking software.

×