OUTPUT_FORMAT("elf32-avr32", "elf32-avr32", "elf32-avr32")

OUTPUT_ARCH(avr32:uc)

ENTRY(_start)

MEMORY
{
  FLASH  (rxai!w) : ORIGIN = 0x80000000, LENGTH = 0x00001FE0
  FLASH2 (rxai!w) : ORIGIN = 0x80001FE0, LENGTH = 0x00000020
  INTRAM (wxa!ri) : ORIGIN = 0x00000004, LENGTH = 0x000017FC
}

PHDRS
{
  FLASH PT_LOAD;
  FLASH2 PT_LOAD;
  INTRAM_ALIGN PT_NULL;
  INTRAM_AT_FLASH PT_LOAD;
  INTRAM PT_NULL;
  CONST_INTRAM_AT_FLASH PT_LOAD;
}

SECTIONS
{
  __heap_size__ = DEFINED(__heap_size__) ? __heap_size__ : 0;
  __stack_size__ = DEFINED(__stack_size__) ? __stack_size__ : 1K;

/*===================*/
/* Section Parameter */
/*===================*/

  .HWparams :
  {
    *(.HWparams)
  } >FLASH2 AT>FLASH2 :FLASH2

/*===================*/
/* Section ROM       */
/*===================*/
  PROVIDE (__executable_start = 0x80000000); . = 0x80000000;
  .interp :
  {
    *(.interp)
  } >FLASH AT>FLASH :FLASH
  .reset :
  {
    *(.reset)
  } >FLASH AT>FLASH :FLASH
  .text :
  {
    *(.text)
  } >FLASH AT>FLASH :FLASH
  .lalign :
  {
    . = ALIGN(8);
    PROVIDE(_data_lma = .);
  } >FLASH AT>FLASH :FLASH


/*===================*/
/* Section RAM       */
/*===================*/
  . = ORIGIN(INTRAM);
  .dalign :
  {
    . = ALIGN(8);
    PROVIDE(_data = .);
  } >INTRAM AT>INTRAM :INTRAM_ALIGN
  .ctors :
  {
    KEEP (*crtbegin*.o(.ctors))
    KEEP (*(EXCLUDE_FILE (*crtend*.o ) .ctors))
    KEEP (*(SORT(.ctors.*)))
    KEEP (*(.ctors))
  } >INTRAM AT>FLASH :INTRAM_AT_FLASH
  .dtors          :
  {
    KEEP (*crtbegin*.o(.dtors))
    KEEP (*(EXCLUDE_FILE (*crtend*.o ) .dtors))
    KEEP (*(SORT(.dtors.*)))
    KEEP (*(.dtors))
  } >INTRAM AT>FLASH :INTRAM_AT_FLASH
  .ddalign :
  {
    . = ALIGN(8);
  } >INTRAM AT>FLASH :INTRAM_AT_FLASH
  .data :
  {
    *(.data .data.* .gnu.linkonce.d.*)
    KEEP (*(.gnu.linkonce.d.*personality*))
    SORT(CONSTRUCTORS)
  } >INTRAM AT>FLASH :INTRAM_AT_FLASH
  .balign :
  {
    . = ALIGN(8);
    PROVIDE(_edata = .);
  } >INTRAM AT>FLASH :INTRAM_AT_FLASH
  PROVIDE (edata = .);
  __bss_start = .;
  .bss :
  {
    *(.dynbss)
    *(.bss .bss.* .gnu.linkonce.b.*)
    *(COMMON)
    . = ALIGN(8);
  } >INTRAM AT>INTRAM :INTRAM
  . = ALIGN(8);
  _end = .;
  PROVIDE (end = .);
  __heap_start__ = ALIGN(8);
  .heap           :
  {
    *(.heap)
    . = __heap_size__;
  } >INTRAM AT>INTRAM :INTRAM
  __heap_end__ = .;
  .stack          :
  {
    _stack = .;
    *(.stack)
    . = __stack_size__;
    _estack = .;
  } >INTRAM AT>INTRAM :INTRAM
  _const_lma = LOADADDR(.const);
  .const ALIGN(0x400) : AT ( (LOADADDR(.balign) + SIZEOF (.balign) + 7) & ~ 7 )
  {
    _const = .;
    *(.evba)
    *(.hash)
    *(.dynsym)
    *(.dynstr)
    *(.gnu.version)
    *(.gnu.version_d)
    *(.gnu.version_r)
    *(.rel.init)
    *(.rela.init)
    *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*)
    *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
    *(.rela.fini)
    *(.rel.fini)
    *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*)
    *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
    *(.rel.data.rel.ro*)
    *(.rela.data.rel.ro*)
    *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*)
    *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
    *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*)
    *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
    *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*)
    *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
    *(.rel.ctors)
    *(.rela.ctors)
    *(.rel.dtors)
    *(.rela.dtors)
    *(.rel.got)
    *(.rela.got)
    *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*)
    *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
    *(.rel.plt)
    *(.rela.plt)
    KEEP (*(.init))
    *(.plt)
    *(.text._unhandled_interrupt .text.udd_interrupt .stub .gnu.linkonce.t.*)
    KEEP (*(.text.*personality*))
    *(.gnu.warning)
    KEEP (*(.fini))
    PROVIDE (__etext = .);
    PROVIDE (_etext = .);
    PROVIDE (etext = .);
    *(.rodata .rodata.* .gnu.linkonce.r.*)
    *(.rodata1)
    *(.eh_frame_hdr)
    KEEP (*(.eh_frame))
    KEEP (*(.gcc_except_table)) *(.gcc_except_table.*)
  } >INTRAM :CONST_INTRAM_AT_FLASH
  . = ALIGN(8);
  _econst = .;
}