!include "ServiceLib.nsh"
!include "LogicLib.nsh"

Name "test"
OutFile "test.exe"
XPStyle on
ShowInstDetails show
RequestExecutionLevel admin

Page instfiles

Function IsPortOpen

  Exch $R0 # port to check
  Exch
  Exch $R1
  Push $0
  Push $1
  Push $2

  System::Call 'iphlpapi::Get$R1Table(*i.r0, *i .r1, i 1) i .r2'
  ${If} $2 != 122 # ERROR_INSUFFICIENT_BUFFER
    StrCpy $R0 ""
    Pop $2
    Pop $1
    Pop $0
    Exch $R1
    Exch
    Exch $R0
    Return
  ${EndIf}

  System::Alloc $1
  Pop $0

  System::Call 'iphlpapi::Get$R1Table(ir0, *i r1, i 1) i .r2'
  ${If} $2 != 0 # NO_ERROR
    System::Free $0
    StrCpy $R0 ""
    Pop $2
    Pop $1
    Pop $0
    Exch $R1
    Exch
    Exch $R0
    Return
  ${EndIf}

  Push $3
  Push $4
  Push $5

  System::Call *$0(i.r2)
  IntOp $2 $2 - 1
  ${For} $3 0 $2
    IntOp $4 $0 + 4  # skip dwNumEntries
    ${If} $R1 == "Tcp"
      IntOp $5 $3 * 20 # sizeof(MIB_TCPROW)
      IntOp $4 $4 + $5 # skip to entry
      System::Call *$4(i,i,i.r4,i,i)
    ${Else}
      IntOp $5 $3 * 8 # sizeof(MIB_UDPROW)
      IntOp $4 $4 + $5 # skip to entry
      System::Call *$4(i,i.r4)
    ${EndIf}
    System::Call ws2_32::ntohs(ir4)i.r4
    ${If} $4 = $R0
      StrCpy $R0 "open"
      ${Break}
    ${EndIf}
  ${Next}

  ${If} $R0 != "open"
    StrCpy $R0 "closed"
  ${EndIf}

  System::Free $0

  Pop $5
  Pop $4
  Pop $3
  Pop $2
  Pop $1
  Pop $0
  Exch $R1
  Exch
  Exch $R0
FunctionEnd

Section ""
  Push "Tcp"
  Push "80"
  Call IsPortOpen
  Pop $0 ; "open" or "closed" or anything else for error
  ${If} $0 == "open"
    DetailPrint "Apache running, stopping..."
    !insertmacro SERVICE "stop" "apache2.2" ""
    Pop $0
    ${If} $0 == "true"
      DetailPrint "Apache stopped"
      loop:
      Push "Tcp"
      Push "80"
      Call IsPortOpen
      Pop $0 ; "open" or "closed" or anything else for error
      ${If} $0 == "open"
        Sleep 50
        Goto loop
      ${EndIf}
      DetailPrint "Port 80 is closed."
    ${Else}
      DetailPrint "Failed to stop Apache"
    ${EndIf}
  ${Else}
    DetailPrint "Port 80 is closed"
  ${EndIf}
Sectionend