Ghost typer.cmd

@echo off
setlocal enableextensions enabledelayedexpansion

color 1e
rem set_ConsoleWindow  winWidth  winHeight  bufWidth  bufHeight WindowTitle
call :set_ConsoleWindow 80 20 80 20 Ghost_Typer

:var
set "self=%~n0"
set "self.full=%~f0"
set "self.save_file="%temp%\%self%.sav""
call :init_Irvanview
::erzeuge Backspace   (Variable %BS%)
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
set /a count=0
:: aendere den wert in der naechsten Zeile  für die  Verzoegerung
set /a _delay=30000
set "imagepath=Images"
md %imagepath% >nul 2>&1

:main
color 0b
echo.
call :type Lorem ipsum dolor sit amet, consectetuer adipiscing elit.
call :type Aenean commodo ligula eget dolor. Aenean massa.
echo.
call :type Cum sociis natoque penatibus et magnis dis parturient montes,
call :type nascetur ridiculus mus. Donec quam felis, ultricies nec, pellentesque eu,
call :type pretium quis, sem. Nulla consequat massa quis enim. Donec pede justo,
call :type fringilla vel, aliquet nec, vulputate eget, arcu.
echo.

color 3f
call :create_avs
echo. & echo ...fertig...
pause
:end_main
exit /b

:subroutines

:type
set /a imgnr+=1
set "line=%*
set "char=!line:~%count%,1!"
:: Batch-Trick: Ausgabe ohne Linefeed mit set /p "= string"<nul
if not "%char%"=="" set /p "=.%BS%%char%" <nul
if /i "%dummymode%"=="1" (call :delay %_delay%) else (call :capture)

if "%char%"=="" echo. & set /a count=0 &  exit /b
set /a count+=1
goto :type

:delay
for /L %%b in (1,1,%1) do rem
exit /b

:capture
start "" /wait "C:\Program Files (x86)\IrfanView\i_view32.exe" /capture=3 /convert=%imagepath%\%imgnr%.png
exit /b

:set_ConsoleWindow
mode con: cols=%1 lines=%2
powershell -command "&{$H=get-host;$W=$H.ui.rawui;$B=$W.buffersize;$B.width=%3;$B.height=%4;$W.buffersize=$B;$W.WindowTitle='%5'}" >nul 2>&1 || echo fehler
exit /b

:create_avs
echo Erzeuge "%~n0.avs"
echo ImageReader("%imagepath%\%%d.png", 1, 362, 24.0 , use_DevIL=true).ConvertToRGB32 >"%self%.avs"
echo front=sharpen(1.0).sharpen(1.0).Spline64Resize(1280,720) >>"%self%.avs"
echo Blur(1.58).BilinearResize(Width()/24, Height()/24, 0.1, -0.1) >>"%self%.avs"
echo glow=BilinearResize(1280,720) >>"%self%.avs"
echo mask_clip = Mask(front, front.GreyScale.Levels(0, 1.0, 75, 0, 255)) >>"%self%.avs"
echo Overlay(glow, front, mask=ShowAlpha(mask_clip),  mode="blend", opacity=1) >>"%self%.avs"
echo ConvertToYV12() >>"%self%.avs"

exit /b

:init_Irvanview
if exist %self.save_file% (
  rem import some constant variables from file (this is much faster then searching for Irvanview each time)
  for /f  "usebackq delims=" %%a in (%self.save_file%) do ( set "%%a")
  goto :end_init_iv)
rem search for Irvanview on Drive and Stop after first Hit.
echo Suche  IrfanView...
echo.
for /f "delims=" %%F in ('dir /b /s "c:/i_view32.exe" 2^>nul') do (set "self.irvanview="%%F"" && goto found)
echo Kann IrfanView nicht auf Laufwerk C:\ finden
echo Fuehre Batch  im Dummy Modus aus
echo Es wird  keine Animation  gespeichert

set "dummymode=1" & goto :end_init_iv
:found
set "self.filelist_base=%temp%\%self%.file.list"
rem save all Variables to File
set self.>%self.save_file%
:end_init_iv
echo ...Vorbereiten...
ping localhost -n 5 >nul
cls
exit /b