<DesignerCategory("UserControl")>
Public Class MyComboBox : Inherits ComboBox

    <Editor(GetType(CollectionEditor), GetType(UITypeEditor))>
    <DesignerSerializationVisibility(DesignerSerializationVisibility.Content)>
    <Category("(Extended) Appearance")>
    Public Shadows ReadOnly Property Items As MyItemCollection
        Get
            Return Me.itemsB
        End Get
    End Property
    Private ReadOnly itemsB As MyItemCollection

    <DebuggerStepThrough>
    Public Sub New()
        MyBase.DrawMode = DrawMode.OwnerDrawFixed
        Me.itemsB = New MyItemCollection(Me)
    End Sub

    Protected Overrides Sub OnDrawItem(ByVal e As DrawItemEventArgs)

        e.DrawBackground()
        e.DrawFocusRectangle()

        ' Check if it is an item from the Items collection.
        If (e.Index < 0) Then
            ' not an item, draw the text.
            Using brush As New SolidBrush(e.ForeColor)
                e.Graphics.DrawString(Me.Text, e.Font, brush, e.Bounds.Left, e.Bounds.Top)
            End Using

        Else
            ' Get the item to draw.
            Dim item As MyItem = Me.Items(e.Index)
            Using brush As New SolidBrush(e.ForeColor)
                e.Graphics.DrawString(item.Text, e.Font, brush, e.Bounds.Left, e.Bounds.Top)
            End Using

        End If

        MyBase.OnDrawItem(e)

    End Sub

End Class

<DesignerCategory("Code")>
<DefaultMember("Item")>
<ListBindable(False)>
Public Class MyItemCollection : Inherits ObjectCollection

    Sub New(ByVal owner As MyComboBox)
        MyBase.New(owner)
    End Sub

    <Browsable(False)>
    <DesignerSerializationVisibility(DesignerSerializationVisibility.Hidden)>
    Default Public Overloads Property Item(ByVal index As Integer) As MyItem
        Get
            Return DirectCast(MyBase.Item(index), MyItem)
        End Get
        Set(ByVal value As MyItem)
            MyBase.Item(index) = value
        End Set
    End Property

    ' Original property:
    '
    '<Browsable(False)>
    '<DesignerSerializationVisibility(DesignerSerializationVisibility.Hidden)>
    'Default Public Overrides Property Item(ByVal index As Integer) As Object
    '    Get
    '        Return MyBase.Item(index)
    '    End Get
    '    Set(value As Object)
    '        MyBase.Item(index) = value
    '    End Set
    'End Property

End Class

<DesignerCategory("Code")>
<Browsable(False)>
<ToolboxItem(False)>
Public NotInheritable Class MyItem

    Public Property Text As String

    Public Sub New()
        Me.New(String.Empty)
    End Sub

    Public Sub New(ByVal text As String)
        Me.Text = text
    End Sub

End Class

Private Sub InitializeComponent()
    Me.MyComboBox1 = New WindowsApplication52.MyComboBox()
    Dim MyItem1 As WindowsApplication52.MyItem = New WindowsApplication52.MyItem()
    MyItem1.Text = "Test"
    Me.MyComboBox1.Items.AddRange(New Object() {MyItem1})

    ' ...
End Sub

Public Class Form1 : Inherits Form

    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles MyBase.Shown

        MessageBox.Show(String.Format("There are '{0}' items in the collection.", MyComboBox1.Items.Count))

    End Sub

End Class