on $*:TEXT:/^[!.]masspm ./Si:*: {
  if ($chan) { var %chan = $v1 }
  else {
    var %chan = $2
    tokenize 32 $2-
  }
  if (($nick isop %chan) || ($nick ishop %chan)) {
    if ($2 == $null) { notice $nick You need to specify a message to send. }
    else {
      var %i = 1, %n = 0, %l = %except. [ $+ [ %chan ] ]
      while ($nick(%chan,%i,a,r) !== $null) {
        var %c = $v1
        if (!$istok(%l,%c,32)) {
          var %t = $+(%t,$chr(44),%c)
          inc %n
          if (%n == 20) {
            msg $right(%t,-1) $2-
            var %n, %t
          }
        }
        inc %i
      }
      if (%n) { msg $right(%t,-1) $2- }
    }
  }
}
on $*:TEXT:/^[!.]addexception( .|$)/Si:*: {
  if ($chan) { var %chan = $v1 }
  else {
    var %chan = $2
    tokenize 32 $2-
  }
  if (($nick isop %chan) || ($nick ishop %chan)) {
    var %l = %except. [ $+ [ %chan ] ]
    if ($2 == $null) { notice $nick The exception list for %chan $iif(%l == $null,is empty.,is: %l) }
    elseif ($istok(%l,$2,32)) { notice $nick The nick $2 is already on %chan $+ 's exception list. }
    else {
      set %except. [ $+ [ %chan ] ] %l $2
      notice $nick The nick $2 has been added to %chan $+ 's exception list.
    }
  }
}
on $*:TEXT:/^[!.]delexception( .|$)/Si:*: {
  if ($chan) { var %chan = $v1 }
  else {
    var %chan = $2
    tokenize 32 $2-
  }
  if (($nick isop %chan) || ($nick ishop %chan)) {
    var %l = %except. [ $+ [ %chan ] ]
    if ($2 == $null) { notice $nick The exception list for %chan $iif(%l == $null,is empty.,is: %l) }
    elseif (!$istok(%l,$2,32)) { notice $nick The nick $2 is not on %chan $+ 's exception list. }
    else {
      set %except. [ $+ [ %chan ] ] $remtok(%l,$2,1,32)
      notice $nick The nick $2 has been removed from %chan $+ 's exception list.
    }
  }
}
on $*:TEXT:/^[!.]delexceptlist( .|$)/Si:*: {
  var %chan = $iif($chan,$v1,$2)
  if (($nick isop %chan) || ($nick ishop %chan)) {
    if (%except. [ $+ [ %chan ] ] == $null) { notice $nick The exception list for %chan is already empty. }
    else {
      unset %except. [ $+ [ $chan ] ]
      notice $nick The exception list for %chan has been cleared.
    }
  }
}