Advertisement
Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- (
- SynthDef( \help_SPE3_Mridangam, { |out, t_amp|
- var sound;
- sound = Resonz.ar(
- WhiteNoise.ar(70) * Decay2.kr( t_amp, 0.002, 0.1 ),
- 60.midicps,
- 0.02,
- 4
- ).distort * 0.4;
- Out.ar(out, sound);
- DetectSilence.ar(sound, doneAction: Done.freeSelf);
- }).add;
- SynthDef( \help_SPE3_Drone, { |out|
- var sound;
- sound = LPF.ar(
- Saw.ar([60, 60.04].midicps)
- +
- Saw.ar([67, 67.04].midicps),
- 108.midicps,
- 0.007
- );
- Out.ar(out, sound);
- }).add;
- )
- (
- // percussion solo in 10/8
- var stream, pat, amp;
- pat = Pseq([
- Pseq(#[0.0], 10),
- // intro
- Pseq(#[0.9, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0], 2),
- Pseq(#[0.9, 0.0, 0.0, 0.2, 0.0, 0.0, 0.0, 0.2, 0.0, 0.0], 2),
- Pseq(#[0.9, 0.0, 0.0, 0.2, 0.0, 0.2, 0.0, 0.2, 0.0, 0.0], 2),
- Pseq(#[0.9, 0.0, 0.0, 0.2, 0.0, 0.0, 0.0, 0.2, 0.0, 0.2], 2),
- // solo
- Prand([
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.0, 0.2, 0.0, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.2, 0.0, 0.7, 0.0, 0.2, 0.0, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.0, 0.2, 0.0, 0.7, 0.0, 0.2]),
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.2, 0.2, 0.0, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.0, 0.2, 0.2, 0.7, 0.2, 0.0]),
- Pseq(#[0.9, 0.2, 0.2, 0.7, 0.2, 0.2, 0.2, 0.7, 0.2, 0.2]),
- Pseq(#[0.9, 0.2, 0.2, 0.7, 0.2, 0.2, 0.2, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.2, 0.2, 0.2, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.4, 0.0, 0.4, 0.0, 0.4, 0.0, 0.4, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.4, 0.0, 0.0, 0.4, 0.2, 0.4, 0.2]),
- Pseq(#[0.9, 0.0, 0.2, 0.7, 0.0, 0.2, 0.0, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.7, 0.0, 0.0, 0.0, 0.7, 0.0, 0.0]),
- Pseq(#[0.9, 0.7, 0.7, 0.0, 0.0, 0.2, 0.2, 0.2, 0.0, 0.0]),
- Pseq(#[0.9, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0])
- ], 30),
- // tehai : 7 beat motif 3 times sharing 1st beat with next 7x3
- // and again the third time:
- // 123456712345671234567 123456712345671234567
- // 123456712345671234567
- // ! ! ! !
- // 1234567890123456789012345678901234567890123456789012345678901
- Pseq(#[2.0, 0.0, 0.2, 0.5, 0.0, 0.2, 0.9,
- 1.5, 0.0, 0.2, 0.5, 0.0, 0.2, 0.9,
- 1.5, 0.0, 0.2, 0.5, 0.0, 0.2], 3),
- Pseq(#[5], 1), // sam
- Pseq(#[0.0], inf)
- ]);
- stream = pat.asStream;
- Task({
- Synth(\help_SPE3_Drone);
- loop({
- if( ( amp = stream.next ) > 0,
- { Synth(\help_SPE3_Mridangam, [ \t_amp, amp ]) }
- );
- (1/8).wait;
- })
- }).play
- )
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement