// -- A simple Arduino 4x4 matrix keypad example
// Made by Bastiaan van der Plaat

// ### SIMPLE ARDUINO KEYPAD LIBRARY ###
// ~ This library works fine but there is some strange
// ~ behaviour when you press multiple keys at the same time.
// ~ But for the most time the keys will be returend separately

// Keypad size
#define KEYPAD_ROWS 4
#define KEYPAD_COLUMNS 4

// Keypad characters
const char keypad_keys[KEYPAD_ROWS][KEYPAD_COLUMNS]= {
  { '1', '2', '3', 'A' },
  { '4', '5', '6', 'B' },
  { '7', '8', '9', 'C' },
  { '*', '0', '#', 'D' }
};

// Keypad digital pins on the Arduino
const byte keypad_row_pins[KEYPAD_ROWS] = { 5, 6, 7, 8 };
const byte keypad_column_pins[KEYPAD_COLUMNS] = { 9, 10, 11, 12 };

// Keypad initialization function
void keypad_init(void) {
  // Set all the row pins to output and high
  for (byte i = 0; i < KEYPAD_ROWS; i++) {
    pinMode(keypad_row_pins[i], OUTPUT);
    digitalWrite(keypad_row_pins[i], HIGH);
  }

  // Set all the column pins to input pullup
  for (byte i = 0; i < KEYPAD_COLUMNS; i++) {
    pinMode(keypad_column_pins[i], INPUT_PULLUP);
  }
}

// Keypad keys state
byte keypad_keys_state[KEYPAD_ROWS][KEYPAD_COLUMNS] = { 0 };

// Keypad function witch returns the pressed key as a ASCII char
char keypad_get_key(void) {
  // Go over all the row pins
  for (byte y = 0; y < KEYPAD_ROWS; y++) {
    // Set the active row pin low
    digitalWrite(keypad_row_pins[y], LOW);
    // Go over all the column pins
    for (byte x = 0; x < KEYPAD_COLUMNS; x++) {
      // Check if the column pin is also low
      if (digitalRead(keypad_column_pins[x]) == LOW) {
        // The check if the key is not pressed
        if (keypad_keys_state[y][x] == 0) {
          // Set the state to 200 for the release count down
          keypad_keys_state[y][x] = 200;
          // Set the active row high again
          digitalWrite(keypad_row_pins[y], HIGH);
          // Return the pressed character
          return keypad_keys[y][x];
        }
      }
      // If the key is released count a simple counter down from 200 to 0
      else if (keypad_keys_state[y][x] > 0) {
        keypad_keys_state[y][x]--;
      }
    }
    // Set the row pin high again
    digitalWrite(keypad_row_pins[y], HIGH);
  }

  // When no key is pressed return 0
  return 0;
}

// ### MAIN CODE ###

// The password and password buffer vars
#define PASSWORD_LENGTH 4
const char password[PASSWORD_LENGTH + 1] = "1234";
char password_buffer[PASSWORD_LENGTH + 1];
byte password_buffer_position = 0;

void setup() {
  // Init the serial communication
  Serial.begin(9600);

  // Init the keypad
  keypad_init();
}

void loop() {
  // Get the pressed keypad character
  char key = keypad_get_key();

  // If the hashtag key is pressed
  if (key == '#') {
    // Check if the buffer is filled
    if (password_buffer_position == PASSWORD_LENGTH) {
      // Compare the password and the buffer with each other
      if (strcmp(password, password_buffer) == 0) {
        Serial.println("Good password!");
      } else {
        Serial.println("Wrong password!");
      }

      // Clear the password buffer
      while (password_buffer_position != 0) {
        password_buffer[--password_buffer_position] = 0;
      }
    } else {
      Serial.println("Buffer not full!");
    }
  }

  // If the asterisk is pressed clear the password buffer
  else if (key == '*') {
    while (password_buffer_position != 0) {
      password_buffer[--password_buffer_position] = 0;
    }
    Serial.println("Buffer cleared!");
  }

  // Add any other key to the password buffer if there is room
  else if (key != 0) {
    if (password_buffer_position < PASSWORD_LENGTH) {
      password_buffer[password_buffer_position++] = key;
      Serial.println(password_buffer);
    } else {
      Serial.println("Buffer full!");
    }
  }
}