zone69

///Tyrese17, frog163 © 2012
/*Инструкция по добавлению еще дохуя ворот:
--Увеличить MAX_GATE на кол-во добовляемых ворот;
--В массив `gate` добавить еще одну строчку;
--Have profit!                                      */

#include <a_samp>
#include <streamer>

#define MAX_GATE        2

enum gate_data{
    gate_id,
    gate_model,
    Float:gate_pos[9]
};

new gate[MAX_GATE][gate_data] = {//Syntax: {0, ID модели объекта,{Координата X, Y, Z, rX, rY, rZ,            Координаты открытых ворот moveX, moveY, moveZ}},
    {0,19313,{134.936,1941.448,21.763,0.0,0.0,180.0,            148.869,1941.484,21.763}},
    {0,19313,{285.984,1822.307,20.086,0.0,0.0,270.0,            285.959,1808.317,20.086}}
};

public OnFilterScriptInit(){
    CreateDynamicObject(19312,191.11000061,1870.05297852,21.46599960,0.00000000,0.00000000,0.00000000); // Новый забор, вместо старого
    for(new f; f<MAX_GATE; f++)
        gate[f][gate_id] = CreateDynamicObject(gate[f][gate_model],gate[f][gate_pos][0],gate[f][gate_pos][1],gate[f][gate_pos][2],gate[f][gate_pos][3],gate[f][gate_pos][4],gate[f][gate_pos][5]);
    return true;
}

public OnPlayerConnect(playerid){
    RemoveBuildingForPlayer(playerid,16094,191.1406,1870.0391,21.4766,0.25); // Удаление забора
    RemoveBuildingForPlayer(playerid, 1411, 347.1953, 1799.2656, 18.7578, 0.25);// Удаление забора
    RemoveBuildingForPlayer(playerid, 1411, 342.9375, 1796.2891, 18.7578, 0.25);// Удаление забора
    return true;
}

public OnPlayerCommandText(playerid, cmdtext[]){
    if(!strcmp("/areaopen1", cmdtext, true)) // Ворота 1
        return open_gate(playerid, 0);
    else if(!strcmp("/areaopen2", cmdtext, true)) // Ворота 2
        return open_gate(playerid, 1);
    return false;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys){
    if(newkeys & KEY_CROUCH){
        for(new f; f<MAX_GATE; f++){
            if(IsPlayerInRangeOfPoint(playerid,13.0,gate[f][gate_pos][0],gate[f][gate_pos][1],gate[f][gate_pos][2])){
                open_gate(playerid, f);
                break;
            }
        }
    }
    return true;
}

open_gate(playerid, gateid){
    MoveDynamicObject(gate[gateid][gate_id],gate[gateid][gate_pos][6],gate[gateid][gate_pos][7],gate[gateid][gate_pos][8],4);
    SetTimerEx("close_gate",5000,0,"i",gateid);
    new str[70];
    format(str, 70, "{00d300}Ворота №%d открыты. {d3d3d3}(Закроются автоматически)", gateid+1);
    return SendClientMessage(playerid, -1, str);
}

forward close_gate(gateid);
public close_gate(gateid){
    MoveDynamicObject(gate[gateid][gate_id],gate[gateid][gate_pos][0],gate[gateid][gate_pos][1],gate[gateid][gate_pos][2],4);
    return true;
}