MX_L2.avsi

# putin999氏作
# 2012/12/7
#
#使用例
#
# 155フィールドから14835フィールドがL字の場合
# MX_L2(155,14835,0)
# EraseLOGO(logofile=logofile, start=0, end=7791, interlaced=true)
# MX_L2(155,14835,1)
#
# ロゴを消さない場合は
# MX_L2(155,14835,2)



function MX_L2(clip c,int start_field,int end_field,int mode){
    start=start_field
    end=end_field
    c=c.separatefields()
    final=c.framecount()-1
    w=c.width()
    h=c.height()
    c_=c.trim(start,end)
    final_=c_.framecount()-1
    c_=(mode==0)?c_._L2(0,29,0,0,w,h
            \,4,0,0,0
            \,6.0,0,0,2.3)
            \._L2_resize(30,final_-30,w,h,180,0,float(w)-180,float(h)-68)
            \._L2(1,29,final_-29,0,w,h
            \,176,0,0,68
            \,6.0,0,0,2.3)
       \:(mode==1)?c_._L2(0,29,0,0,w,h
            \,2.0,0,0,2.4
            \,0.28,0,0,0.22)
            \._L2_resize(30, final_-30,w,h,14,0,float(w)-14,float(h)-10)
            \._L2(1,29,final_-29,0,w,h
            \,12,0,0,8
            \,0.31,0,0,0.24)
       \:c_._L2(0,29,0,0,w,h
            \,6.0,0,0,2.6
            \,6.24,0,0,2.50)
            \._L2_resize(30, final_-30,w,h,194,0,float(w)-194,float(h)-78)
            \._L2(1,29,final_-29,0,w,h
            \,186,0,0,75
            \,6.24,0,0,2.48)
    c_=(start==0)?c_
        \:(start==1)?c.trim(0,-1)+c_
        \:c.trim(0,start-1)+c_
    c_=((end==0)||(end==final))?c_
        \:((end==-1)&&(start==final))?c_
        \:(end==-1)?c_+c.trim(start+1,0)
        \:c_+c.trim(end+1,0)
    return c_.weave()
}
function _L2(clip c,int type,int rep,int start,int crnt,int w,int h
                    \,float defl,float deft,float defr,float defb
                    \,float l,float t,float r,float b){
    c_=(type==0)?_L2_resize(c,start+crnt,-1,w,h,defl+l*float(crnt),deft+t*float(crnt)
            \,float(w)-(l*float(crnt))-(r*float(crnt))-defl-defr,float(h)-(b*float(crnt))-(t*float(crnt))-deft-defb)
        \:_L2_resize(c,start+crnt,-1,w,h,defl-l*float(crnt),deft-t*float(crnt)
            \,float(w)-(defl-l*float(crnt))-(defr-r*float(crnt)),float(h)-(defb-b*float(crnt))-(deft-t*float(crnt)))
    return (rep>crnt)?_L2(c_,type,rep,start,crnt+1,w,h,defl,deft,defr,defb,l,t,r,b):c_
}
function _L2_resize(clip c,int start, int end,int t_w,int t_h
                            \,float s_l,float s_t,float s_w,float s_h){
    final=c.framecount()-1
    c_=c.trim(start,end).spline64resize(t_w,t_h,s_l,s_t,s_w,s_h)
    c_=(start==0)?c_
        \:(start==1)?c.trim(0,-1)+c_
        \:c.trim(0,start-1)+c_
    c_=((end==0)||(end==final))?c_
        \:((end==-1)&&(start==final))?c_
        \:(end==-1)?c_+c.trim(start+1,0)
        \:c_+c.trim(end+1,0)
    return c_
}