pkgbase=freeciv-git
pkgname=('freeciv-git' 'freeciv-gtk3-git' 'freeciv-sdl-git' 'freeciv-qt-git')
pkgver=2.6
pkgrel=1
pkgdesc='A multiuser clone of the famous Microprose game of Civilization'
arch=('i686' 'x86_64')
url='http://freeciv.org'
license=('GPL')
depends=('hicolor-icon-theme')
makedepends=('git' 'curl' 'libtool' 'python' 'gtk3' 'qt5-base' 'sdl2_image' 'sdl2_mixer' 'sdl2_gfx' 'sdl2_ttf')
conflicts=('freeciv' 'freeciv-svn' 'freeciv-sdl')
options=('!libtool')
source=('git+https://github.com/freeciv/freeciv.git')
sha256sums=('SKIP')

prepare() {
  cd freeciv

  autoreconf -vi
}

build() {
  cd freeciv

  ./configure --prefix=/usr --sysconfdir=/etc --enable-shared \
    --enable-client=gtk3,sdl2,qt

  make
}

package_freeciv-git() {
  cd freeciv

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/bin/freeciv-{gtk3,sdl2,qt}
  rm -rf "${pkgdir}"/usr/share/applications/freeciv{,-sdl2,-qt}.desktop
}

package_freeciv-gtk3-git() {
  depends=('freeciv-git' 'gtk3')

  cd freeciv

  install -dm 755 "${pkgdir}"/usr/bin
  install -dm 755 "${pkgdir}"/usr/share/applications
  install -m 755 client/freeciv-gtk3 "${pkgdir}"/usr/bin/
  install -m 755 client/freeciv.desktop "${pkgdir}"/usr/share/applications/
}

package_freeciv-sdl-git() {
  depends=('freeciv-git' 'sdl2_image' 'sdl2_mixer' 'sdl2_gfx' 'sdl2_ttf')

  cd freeciv

  install -dm 755 "${pkgdir}"/usr/bin
  install -dm 755 "${pkgdir}"/usr/share/applications
  install -m 755 client/freeciv-sdl2 "${pkgdir}"/usr/bin/
  install -m 755 client/freeciv-sdl2.desktop "${pkgdir}"/usr/share/applications/
}

package_freeciv-qt-git() {
  depends=('freeciv-git' 'qt5-base')

  cd freeciv

  install -dm 755 "${pkgdir}"/usr/bin
  install -dm 755 "${pkgdir}"/usr/share/applications
  install -m 755 client/freeciv-qt "${pkgdir}"/usr/bin/
  install -m 755 client/freeciv-qt.desktop "${pkgdir}"/usr/share/applications/
}

# vim: ts=2 sw=2 et: