;;;TeraTerm ログインスクリプト


;;;変数宣言
GTWName   = 'FIXME'  ;ゲートウェイホストの名前
SVCName   = 'FIXME'  ;サービス機の名前
loginhost = 'FIXME'  ;ログインするホスト
gateAcc   = 'FIXME'  ;gateのアカウント
sshport   = 'FIXME'  ;sshのポート

UsernamePrompt = 'login:'                             ;Usernameプロンプト
PasswordPrompt = 'Password:'                          ;Passwordプロンプト
PasswordPrompt_ssh = "'s password: "                  ;sshでサービス機にログインするときのPasswordプロンプト
PasswordPrompt_ssh_SunOS = "パスワード: "              ;sshでサービス機にログインするときのPasswordプロンプト(Solaris機)
Username_gate = gateAcc                               ;gateのユーザー名
getpassword 'gate.dat' 'password_gate' Password_gate  ;gateのパスワード（パスワードファイルから取得）
Username = gateAcc                                    ;ログインアカウント
getpassword 'gate.dat' 'password_gate' Password       ;パスワード（パスワードファイルから取得）

;;;sshでgateに繋ぐ準備
SSHLogin_gtw = GTWName
strconcat SSHLogin_gtw ':'
strconcat SSHLogin_gtw sshport
strconcat SSHLogin_gtw ' '
strconcat SSHLogin_gtw '/ssh /auth=password'
strconcat SSHLogin_gtw ' '
strconcat SSHLogin_gtw '/user='
strconcat SSHLogin_gtw gateAcc
strconcat SSHLogin_gtw ' '
strconcat SSHLogin_gtw '/passwd='
strconcat SSHLogin_gtw Password_gate

LogPath      = 'C:\data\log\teraterm\'  ;ログファイル格納ディレクトリ
LogExtension = '.log'                   ;ログファイル末尾に付ける拡張子

;;;日付時刻の取得
getdate strDate
strcopy strDate 1 4 yyyy  ;年
strcopy strDate 6 2 mm    ;月
strcopy strdate 9 2 dd    ;日
gettime strTime
strcopy strTime 1 2 hh24  ;時
strcopy strTime 4 2 mi    ;分
strcopy strTime 7 2 ss    ;秒

;;;ログファイル名を組み立てる
LogFile = LogPath
strconcat LogFile SVCname
strconcat LogFile '.'
strconcat LogFile Username
strconcat LogFile '.'
strconcat LogFile yyyy
strconcat LogFile mm
strconcat LogFile dd
strconcat LogFile '-'
strconcat LogFile hh24
strconcat LogFile mi
strconcat LogFile ss
strconcat LogFile LogExtension

;;;ログ採取開始
logopen LogFile 1 0


;;;ゲートウェイホストに接続
connect SSHLogin_gtw
settitle SVCName  ;ステータスバーにサービス機の名前をセット

;;;サービス機にログイン sshで繋ぐ
pause 1
wait '$'
send 'ssh -p ' sshport ' -l ' Username ' ' loginhost#13

wait 'Are you sure you want to continue connecting (yes/no)?' PasswordPrompt_ssh
if result = 1 then
    ;;;ホストに初めてsshログイン
    sendln 'yes'
    wait PasswordPrompt_ssh PasswordPrompt_ssh_SunOS
elseif result = 2 then
    ;;;sshは経験済み
    goto inputPasswd
endif

:inputPasswd
sendln password


; OK, auto login complete.