Monster Dating Sim

# MAIN CHARACTERS
define p = Character("[player_name]", color="#ffffff", what_prefix='"', what_suffix='"')
define s = Character("Simiko", color="#804020", image="simiko", what_prefix='"', what_suffix='"')
define c = Character("Cro", color="#cccccc", image="cro", what_prefix='"', what_suffix='"')
define e = Character("Eva", color="#8040a0", image="eva", what_prefix='"', what_suffix='"')
define r = Character("Rennie", color="#ff8080", image="rennie", what_prefix='"', what_suffix='"')
define k = Character("Ken", color="#101810", image="ken", what_prefix='"', what_suffix='"')
define j = Character("Jin", color="#408070", image="jin", what_prefix='"', what_suffix='"')

default simiko_points = 0
default cro_points = 0
default eva_points = 0
default rennie_points = 0
default ken_points = 0
default jin_points = 0

# IMPORTANT FLAGS
default flag_embarrassed = False
default flag_stop_bully = False
default flag_ask_about_simiko = False

# OTHER CHARACTERS
define t = Character("Teacher", image="teacher", what_prefix='"', what_suffix='"')
define n = Character("Nina", image="nina", what_prefix='"', what_suffix='"')
define ca = Character("Callieko", image="callieko", what_prefix='"', what_suffix='"')

# TRANSITIONS
define circlewipe = ImageDissolve("imagedissolve circlewipe.png", 1.0, 8)
define flashbulb = Fade(0.2, 0.0, 0.8, color='#fff')
define chardissolve = Dissolve(0.2)

# TRANSFORMS
transform floor:
    yalign 1.5
transform leftfloor:
    xalign 0.0
    yalign 1.5
transform centerfloor:
    xalign 0.5
    yalign 1.5
transform rightfloor:
    xalign 1.0
    yalign 1.5


# SPECIAL IMAGES
image bg classroom sepia = im.Sepia("bg/bg classroom.jpg")
image bg cafeteria sepia = im.Sepia("bg/bg cafeteria.jpg")
image bg library sepia = im.Sepia("bg/bg cafeteria.jpg")
image simiko depressed sepia = im.Sepia("simiko/simiko depressed.png")
image simiko embarrassed sepia = im.Sepia("simiko/simiko embarrassed.png")
image simiko mad sepia = im.Sepia("simiko/simiko mad.png")
image cro sepia = im.Sepia("cro/cro.png")
image cro depressed sepia = im.Sepia("cro/cro depressed.png")
image eva sepia = im.Sepia("eva/eva.png")
image eva smile sepia = im.Sepia("eva/eva smile.png")
image ken work sepia = im.Sepia("ken/ken work.png")
image ken work smile sepia = im.Sepia("ken/ken work smile.png")


# The game starts here.

label start:
    $ player_name = renpy.input("What is your name?")
    $ player_name = player_name.strip()
    if player_name == "":
        $ player_name ="Bendy"
    $ player_name = player_name[0].upper() + player_name[1:]
    "Your name is [player_name]."

    "Please select your pronouns."
menu:
    "He/Him/His":
        $ gender = "male"
        $ ken_points += 1
    "She/Her/Hers":
        $ gender = "female"

if gender == "male":
    $ pronoun_sbj = "he"
    $ pronoun_obj = "him"
    $ pronoun_dpos = "his"
    $ pronoun_ipos = "his"
    $ pronoun_ref = "himself"
    $ Pronoun_sbj = "He"
    $ Pronoun_obj = "Him"
    $ Pronoun_dpos = "His"
    $ Pronoun_ipos = "His"
    $ Pronoun_ref = "Himself"
if gender == "female":
    $ pronoun_sbj = "she"
    $ pronoun_obj = "her"
    $ pronoun_dpos = "her"
    $ pronoun_ipos = "hers"
    $ pronoun_ref = "herself"
    $ Pronoun_sbj = "She"
    $ Pronoun_obj = "Her"
    $ Pronoun_dpos = "Her"
    $ Pronoun_ipos = "Hers"
    $ Pronoun_ref = "Herself"


label apr_02_class:
    scene bg room

    "Standing outside of my new classroom, I reach my hand out to open the door, but I hesitate."

    "What kind of school year will this be?"

    "Will I make friends? Or will I be stuck in my old ways?"

    "The future holds infinite potential, but I'll never reach it if I don't first open the door."

    "..."

    "Okay. Maybe I'm being a little dramatic. I should just go inside already."

    # TODO: sound effect for door opening
    scene bg classroom
    with flashbulb

    "The teacher stops mid-sentence and looks at me."

    show teacher
    with chardissolve
    t "Ah, you must be the transfer student."

    p "Yes, sorry I'm late."

    t "Why don't you come up and introduce yourself?"

    p "Ah, sure thing."

menu:
    'Get a good look at the class.':
        $ flag_embarrassed = True
        jump look_class
    '"My name is..."':
        jump my_name_is

label look_class:
    "I walk to the front of the class and meet the gazes of my fellow classmates."

    scene cg classmates:
        xalign 0.0 yalign 0.0
        block:
            linear 10.0 xalign 1.0
            linear 10.0 xalign 0.0
            repeat
    with dissolve

    "Everyone looks pretty ordinary."

    "I guess that's to be expected, though."

    "If this were an anime or game, something crazy would happen, like meeting a werewolf, or maybe a robot or ghost."

    "Maybe I'm getting too old for that stuff. I finally have a chance to start fresh, and I shouldn't waste it."

    scene cg classmates

    show teacher
    with chardissolve

    t "Ahem. Are you alright?"

    scene bg classroom
    with Dissolve(.2)

    show teacher

    p "Huh?"

    "I hear giggles from my classmates, and I realize I've just been staring at them silently this whole time."

    "Not wanting to stand up here another second, I quickly introduce myself."

    p "My name is [player_name]. It's nice to meet you."

    jump seat_assignment

label my_name_is:
    "I walk to the front of the class to introduce myself."

    p "My name is [player_name]. I'm from (INSERT TOWN), and my parents moved here because (REASON). It's nice to meet you all."

    # TODO: fix this with more info

label seat_assignment:
    t "I hope you'll all get along with [player_name]. [Pronoun_sbj]'ll be with you until graduation."

    t "Now then, where should you sit... Ah, how about the empty seat in the second row?"

    define s_anon = Character("Brunette student", color="#804020", what_prefix='"', what_suffix='"')

    show teacher at right
    with move
    show simiko at left
    with chardissolve
    s_anon "Teacher, that's Ken's seat. [Pronoun_sbj] can sit next to me though!"

    t "Ah, that's right. Why don't you have a seat next to Simiko?"

    hide teacher
    with chardissolve

if flag_embarrassed:
    "I slump down in the seat next to the girl whose name is apparently Simiko, and the teacher resumes where she left off."

    "Simiko whispers to me."

    show simiko at center
    with move

    s "Haha, what was that? You totally spaced out."

    p "Oh, it was nothing. I just got lost in thought."

    show simiko smile
    s "You seem interesting. Let's be friends!"

    p "Huh? Oh, okay."

    show simiko smile at left
    with move
    show teacher stern at right
    with chardissolve
    t "I know everyone's excited about the new student, but please, no talking during class."

    show simiko
    s "We'll talk later, okay?"

    $ simiko_points += 1

    jump apr_02_after_class

else:
    "I sit down next to the girl whose name is apparently Simiko, and the teacher resumes where she left off."

label apr_02_after_class:
    # TODO: time ticking sound
    scene bg black
    with circlewipe
    scene bg classroom
    with circlewipe
    show teacher
    with chardissolve

    t "...which is why even the noble gases can be in the liquid and solid states under certain conditions. Does anyone know what conditions will cause this?"

    # TODO: play classroom bell sound
    "The bell rings."

    t "Oh my, is class over already? Time flies when you're having fun. We'll have to pick up with this tomorrow."

    hide teacher
    with chardissolve

    "I breathe a sigh of relief. That lesson went in one ear and right out the other. I've never been good at chemistry."

    show simiko smile:
        xanchor 0.5
        xpos 0.5
        ypos 0.0
        zoom 2.0
    with chardissolve
    s "Hey! Hey hey!"

    "Simiko is leaning in uncomfortably close to my face."

    p "Hey!"

    s "Let's get lunch together! This is your first day, right? I can show you around."

    p "Oh, uh... Sure!"

    show simiko beaming:
        ypos 0.0
        zoom 2.0
    "Simiko smiles triumphantly."

    show simiko beaming:
        yanchor 1.0
        ypos 1.0
        zoom 1.0
    with chardissolve
    s "Alright! Let's go!"