// Auto-ignore script with wildcard (e.g. clantag) support by DES|Bukz
// Requires tools.cfg

initialize [eikellist] []
initialize [aiscript aiwildcards] 0

// add2ai -- Used to add names to the auto-ignore list, supports multiple entires at the same time
// via multiple arguments (up to 24).
alias add2ai [
  if (> $numargs 0) [
    loop x $numargs [add2list eikellist (getalias (format "arg%1" (+ $x 1)))]
    echo (c 0)Your auto-ignore list has sucessfully been updated!
    checkclients
  ] [
    echo (c 3)"/add2ai requires at least 1 argument (name)..."
  ]
]

// checkclients -- Used to check all clients on a server against entries in the auto-ignore list.
alias checkclients [
  if (> (listlen $eikellist) 0) [
    loop w (+ (curhighestcn) 1) [
      loop u (listlen $eikellist) [
        if $aiwildcards [
          if (strstr (findpn $w) (at $eikellist $u)) [
            ignore $w
          ] []
        ] [
          if (strcmp (findpn $w) (at $eikellist $u)) [
            ignore $w
          ] []
        ]
      ]
    ]
  ] []
]

alias showai [echo $eikellist]

// clearai -- Used to remove all entires in the auto-ignore list, will unignore any players that were
// on the list before doing so. TODO: Support for an optional argument that will only remove specific
// entires if they exist.
alias clearai [
  if (= $arg1 1) [
    loop f (+ (curhighestcn) 1) [
      loop e (listlen $eikellist) [
        if $aiwildcards [
          if (strstr (findpn $f) (at $eikellist $e)) [
            clearignored $f
          ] []
        ] [
          if (strcmp (findpn $f) (at $eikellist $e)) [
            clearignored $f
          ] []
        ]
      ]
    ]
    alias eikellist []
    echo (c 2)The contents of your auto-ignore list has been cleared!
  ] []
]

// To avoid recursive bloat on the client, plug checkclients into msa and some other specific
// events, to ensure automation of the script.
addcheck_msa [if (&& (= $aiscript 1) (= $connected 1)) [checkclients] []]

add2conloop [
if_conline_has "connected:" [if (&& (= $aiscript 1) (= $connected 1)) [checkclients] []] [] // Check clients upon a new connection
if_conline_has "is now known as" [if (&& (= $aiscript 1) (= $connected 1)) [checkclients] []] [] // Check clients upon a name change
]

alias ai [showmenu "Auto-Ignore"]

newmenu "Auto-Ignore"
menuitemcheckbox [Use wildcards?] [$aiwildcards] [aiwildcards = $arg1]
menuitemcheckbox [Enable script?] [$aiscript] [aiscript = $arg1]
menuitem [] -1
menuitemvar [concat (c 0)Add to auto-ignore list] [closemenu "Auto-Ignore"; saycommand "/add2ai "]
menuitemvar [concat (c 3)Clear auto-ignore list] [showmenu "Clear AI Confirm"]
menuitemvar [concat (c 2)Show auto-ignore list] [showai]
menuitem [] -1
menuitem [           OK] [closemenu "Auto-Ignore"; checkclients]

newmenu "Clear AI Confirm"
menuinitselection [4]
menuitem [Are you sure you want to delete all] -1
menuitem [entries from your auto-ignore list?] -1
menuitem [] -1
menuitemvar [concat (c 0)Yes] [clearai 1]
menuitemvar [concat (c 3)No] [closemenu "Clear AI Confirm"]

add2menu Misc [menuitem [Auto-ignore settings] [showmenu "Auto-Ignore"]]

docsection [AI];

docident [add2ai] [Adds names to your auto-ignore list.];
docargument [N] [The name you wish to add.];
docexample [/add2ai unarmed] [Result: Adds "unarmed" to the auto-ignore list.];
docexample [/add2ai unarmed wildjoe fatn00b] [Result: Adds all 3 names to the auto-ignore list.];
docremark [Multiple names can be added to the list at once by using multiple arguments (up to 24). If wildcard support is enabled, clan tags may be used instead of full names, to block multiple clients with a single entry.];

docident [clearai] [Clears the entire contents of your auto-ignore list.];
docargument [X] [Must be 1 to work.];
docexample [/clearai 1] [Result: Clears the auto-ignore list.];

docident [showai] [Shows the current contents of your auto-ignore list.];

docident [ai] [Shows the auto-ignore script menu.];

// Example script usage of add2ai.
// Adds "|FOO|" to the client's auto-ignore list only if wildcard support is enabled and "|FOO|"
// does not already exist in the list. From then on, while the wildcard feature is enabled,
// anyone with "|FOO|" anywhere in their name will be auto-ignored. If wildcard support is disabled,
// only clients with the exact name "|FOO|" will be auto-ignored.
//
// if $aiwildcards [
//  loop i (listlen $eikellist) [
//    if (strcmp (at $eikellist $i) |FOO|) [tmpfound = 1] [tmpfound = 0]
//  ]
//  if $tmpfound [] [add2ai |FOO|]
// ] []