" :source this file in your "main" nim file to activate.
" You can run :source again to switch main file or when nimsuggest crashes.
" You can also :call nimsuggest#run('use') to see all uses of the thing your
" cursor is on.

"call system("killall nimsuggest")
let nimsuggest_job = job_start(["nimsuggest", "--stdin", "--v2", "--debug", "--log", expand("%")], {
            \ "in_mode" : "nl",
            \ "out_mode" : "nl",
            \ "err_io": "out",
            \})
let nimsuggest_ch = job_getchannel(nimsuggest_job)

function! nimsuggest#run(cmd)
    let tmp = tempname() . ".nim"
    call writefile(getline(0, '$'), tmp)
    try
        call ch_sendraw(g:nimsuggest_ch, join([a:cmd, expand("%").';'.tmp, line('.'), col('.') - 1])."\n")
        let lines = []
        while 1
            let line = ch_read(g:nimsuggest_ch)
            if line == ""
                break
            endif

            call add(lines, split(line, '\t'))
        endwhile
    finally
        call delete(tmp)
    endtry
    return lines
endfunction

function! nimsuggest#def()
    let res = nimsuggest#run('def')
    if empty(res)
        return
    endif
    let res = res[0]
    let file = res[4]
    let line = res[5]
    let col = res[6] + 1
    let mybuf = bufnr(file, 1)
    exec 'b ' . mybuf
    setlocal buflisted
    "PP mybuf
    call setpos('.', [mybuf, line, col, 0])
endfunction

function! nimsuggest#suggest()
    let res = nimsuggest#run('sug')
    for row in res
        let row[2] = split(row[2], '\.')[-1]
    endfor
    return res
endfunction

function! nimsuggest#setup()
    nnoremap <silent><buffer> gd :call nimsuggest#def()<cr>
    let b:nim_caas_enabled = 1
endfunction

call nimsuggest#setup()

augroup nimsuggest
    autocmd!
    autocmd! FileType nim call nimsuggest#setup()
augroup END