start.bat

@echo off
setlocal enabledelayedexpansion

set stage=start
set startroom_key=0

:loop
if not "!pchar!" == "" echo.
call :%stage%
if not "!pchar!" == "" (
  echo 0^) Exit
  set answers=%answers% 0
  set actions=%actions% exit
)
set /p input=%ask%
if not "%answers%" == "" (
  set answer=
  set num=0
  for %%A in (%answers%) do (
    if /i "%input%" == "%%A" (
      set answer=%%A
      set answerIndex=!num!
    )
    set/a num+=1
  )
  if "!answer!" == "" goto loop
  if not "!pchar!" == "" if "!answer!" == "0" goto exit
  call :%stage%_check 2>nul
  set num=0
  for %%A in (%actions%) do (
    if !num! == !answerIndex! set action=%%A
    set/a num+=1
  )
  set stage=!action!
  if !stage! == exit goto exit
) else set stage=%actions%
goto loop


:start
title Tales Of Trinia v0.01
color f
cls
echo .######...####...##......######...####............####...######..........######..#####...######..##..##..######...####..
echo ...##....##..##..##......##......##..............##..##..##................##....##..##....##....###.##....##....##..##.
echo ...##....######..##......####.....####...........##..##..####..............##....#####.....##....##.###....##....######.
echo ...##....##..##..##......##..........##..........##..##..##................##....##..##....##....##..##....##....##..##.
echo ...##....##..##..######..######...####............####...##................##....##..##..######..##..##..######..##..##.
echo ........................................................................................................................
set ask=press enter to continue
set answers=
set actions=welcome
goto :eof


:welcome
color f
cls
echo Welcome to the pre alpha of Tales Of Trinia.
echo DO you want to read the lore of the game? (this is recommended for new players)
echo.
set ask=y/n?
set answers=y n
set actions=lore cselect
goto :eof


:lore
title Intrduction
color f
cls
echo.
echo Trinia is a large city with three races living side by side: Humans, elves and fauns.
echo each race has a protector blessed with magical abilities, these are called guardians
echo and in this game you will play the role of one of them
echo.
echo go to character select or read more?
echo.
echo 1) Read more about the elves
echo 2) Read more about the fauns
echo 3) Read more about the humans
echo 4) Go to character select
echo 5) Go back
set ask=
set answers=1 2 3 4 5
set actions=elflore faunlore humanlore cselect start
goto :eof


:elflore
title Elves
color f
cls
echo The elves are a noble and proud race. They prefer to keep to themselves as they see the other races as lesser beings, not worthy of their time. After the first war when Trinia was established
echo a small group of council members moved to the city with the guardian to make sure the politics of the city would be favorable to the elves.
echo.
echo read more?
echo.
echo 1) Read more about fauns
echo 2) Read more about humans
echo 3) Go to character select
echo 4) Go back
set ask=
set answers=1 2 3 4
set actions=faunlore humanlore cselect start
goto :eof


:humanlore
title Humans
color f
cls
echo The humans are a race not native to the continent on which Trinia resides. After the first war they suddenly arrived at the harbor with counltess wounded, and so many refugees that Trinia had to be expanded
echo to accomodate the newcomers. After settling down the humans have pioneered the scientific front of Trinia, providing artificial leylines to supply the entire city with all the mana it needs.
echo.
echo read more?
echo.
echo 1) Read more about elves
echo 2) Read more about fauns
echo 3) Go to character select
echo 4) Go back
echo.
set ask=
set answers=1 2 3 4
set actions=elflore faunlore cselect start
goto :eof


:faunlore
title Fauns
color f
cls
echo The fauns are a race of goat like humanoids, with the lower body of a goat and the upper body of something between an elf and a human. The fauns are deeply attuned with nature and have a natural
echo ability to sense the mana contents of their environments.
echo.
echo read more?
echo.
echo 1) Read more about elves
echo 2) Read more about humans
echo 3) Go to character select
echo 4) Go back
echo.
set ask=
set answers=1 2 3 4
set actions=elflore humanlore cselect start
goto :eof


:cselect
title Character select
color f
cls
echo SELECT A CHARACTER
echo.
echo 1) Elora (elf)
echo 2) Avalae (faun)
echo 3) Enne (human)
echo 4) Go back to the title
echo 5) Exit
echo.
set ask=
set answers=1 2 3 4 5
set actions=elora avalae enne start exit
goto :eof


:elora
title Elora intro
color 6
cls
echo Elora is the elven guardian of Trinia.
echo Her guardian ability is a limited range teleport that can take her to anywhere she has been before.
echo.
echo Play as Elora?
set ask=y/n?
set answers=y n
set actions=startroom cselect
goto :eof

:elora_check
if /i "%answer%" == "y" (
  set pchar=Elora
  set ga=teleport
  set race=elven
  cls
)
goto :eof


:avalae
title Avalae intro
color 2
cls
echo Avalae is the faun guardian of Trinia.
echo Her guardian ability is future sight, allowing her to plan ahead and beat some enemies in combat
echo by knowing what their next move will be.
echo.
echo Play as Avalae?
set ask=y/n?
set answers=y n
set actions=startroom cselect
goto :eof

:avalae_check
if /i "%answer%" == "y" (
  set pchar=Avalae
  set ga=future sight
  set race=faun
  cls
)
goto :eof


:enne
color 1
cls
echo Enne is the human guardian of Trinia.
echo Her guardian ability is disintegration, allowing her to break down elements she touches and producing a lot of heat in the process
echo.
echo Play as Enne?
set ask=y/n?
set answers=y n
set actions=startroom cselect
goto :eof

:enne_check
if /i "%answer%" == "y" (
  set pchar=Enne
  set ga=disintegration
  set race=human
  cls
)
goto :eof


:startroom
title Start Room
if %startroom_key% == 0 (
  echo You are in a room with a locked door. A key lies on the floor
  echo.
  echo what do you want to do?
  echo 1^) interact with the door
  echo 2^) interact with the key
  set actions=startroom hall
) else (
  echo You are in a room with an unlocked door.
  echo.
  echo what do you want to do?
  echo 1^) go to the next room
  echo 2^) wait for a while
  set actions=hall startroom
)
set ask=
set answers=1 2
goto :eof

:startroom_check
if "%startroom_key%" == "0" (
  if "%answer%" == "1" (
    echo the door won't budge
  ) else (
    echo You picked up the key!
    set startroom_key=1
  )
  echo.
)
goto :eof


:hall
title hall
echo the door swings open and you now find yourself in a hall.
echo.
echo what do you want to do?
echo 1) go back to the previous room
echo 2) enjoy the hall
set ask=
set answers=1 2
set actions=startroom hall
goto :eof


:exit
color 7