set theWord to text returned of (display dialog "What word do you need to synonymizifucate?" default answer "")
set theType to text returned of (display dialog "What kind of word is it? (e.g. adjective, verb, noun, etc.)" default answer "")
activate application "Dictionary"
tell application "System Events" to tell process "Dictionary"
	key code 19 using {command down}
	keystroke contents of theWord & return
end tell
set synonyms to text returned of (display dialog "Paste in the synonyms you would like to include (each separated by a comma)" default answer "")
set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {", "}
set synonyms_list to text items of synonyms
set AppleScript's text item delimiters to ASTID
set theStuff to ""
repeat with synonym in synonyms_list
	set pyscriptpath to quoted form of (POSIX path of (((path to me) as Unicode text) & ":autoSynonym.scptd:Contents:Resources:dict.py"))
	set command to "/usr/bin/python " & pyscriptpath & " " & quoted form of synonym
	set dictresult to (do shell script command)
	set AppleScript's text item delimiters to (return as text)
	set dictitems to text items of dictresult
	set AppleScript's text item delimiters to ASTID
	set i to 1
	try
		repeat
			if (item i of dictitems as string) contains theType then
				set definition to item (i + 1) of dictitems
				exit repeat
			end if
			set i to (i + 1)
		end repeat
	end try
	try
		set firstLetter to character 1 of synonym
		considering case
			if firstLetter is not in "ABCDEFGHIJKLMNOPQRSTUVWXYZ" then set firstLetter to makeUPPER(firstLetter)
			if length of synonym > 1 then
				set lowerletters to text 2 thru (length of synonym) of synonym
				set lowerletters to makelower(lowerletters)
			else
				set lowerletters to ""
			end if
			set newName to firstLetter & lowerletters
			set AppleScript's text item delimiters to {space}
			set synonym to newName as text
			set AppleScript's text item delimiters to {}
			set theStuff to theStuff & synonym & ": " & definition & (return as text)
		end considering
	end try
end repeat
tell application "TextEdit"
	activate
	set text of (make new document) to theStuff
end tell

on makeUPPER(aLetter)
	--see if the letter is in list of lower case letters
	considering case
		set myChar to offset of aLetter in "abcdefghijklmnopqrstuvwxyz"
		--if so, then return the upper case version
		if myChar > 0 then
			return character myChar of "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
		else
			--else return the original character (it might be a number!)
			return aLetter
		end if
	end considering
end makeUPPER

on makelower(theText)
	set newText to ""
	--loop through the letters
	repeat with loop from 1 to (length of theText)
		--convert them to lower case
		set newText to newText & lower(character loop of theText)
	end repeat
	--return the new text
	return newText
end makelower

on lower(aLetter)
	--see if the letter is in list of upper case letters
	considering case
		set myChar to offset of aLetter in "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
		--if so, then return the lower case version
		if myChar > 0 then
			return character myChar of "abcdefghijklmnopqrstuvwxyz"
		else
			--else return the original character (it might be a number!)
			return aLetter
		end if
	end considering
end lower