int numElements = 25;
int[] arr_H = new int[numElements];
int[] arr_S = new int[numElements];
int[] arr_B = new int[numElements];

void setup() {
  size(500, 500);
  background(255);

  colorMode(HSB, 360, 100, 100);
  noStroke();

  initializeArray(arr_H, 360);
  initializeArray(arr_S, 100);
  initializeArray(arr_B, 100);
}

void draw() {
  generateColors();
}

void initializeArray(int [] someArr, int maxValue) {
  for (int i = 0; i < someArr.length; i++) {
    someArr[i] = (int)random(maxValue);
  }
}

void generateColors() {

  float w = width/float(arr_H.length);

  for (int i = 0; i < arr_H.length; i++) {
    pushMatrix();

      translate(i*w, 0);

      // DRAW RECTANGLE
      fill(arr_H[i], arr_S[i], arr_B[i]);
      rect(0, 0, w, height);

      // SHOW HUE VALUE
      fill(0, 0, 100);
      textAlign(CENTER);
      text(arr_H[i], w/2, height/2-20);
      text(arr_S[i], w/2, height/2);
      text(arr_B[i], w/2, height/2+20);

    popMatrix();
  }
}

void keyPressed() {
  switch(key) {
    case 'h': arr_H = sort(arr_H); break;
    case 's': arr_S = sort(arr_S); break;
    case 'b': arr_B = sort(arr_B); break;
    case 'H': arr_H = reverse(arr_H); break;
    case 'S': arr_S = reverse(arr_S); break;
    case 'B': arr_B = reverse(arr_B); break;
    case 'r':
      initializeArray(arr_H, 360);
      initializeArray(arr_S, 100);
      initializeArray(arr_B, 100);
      break;
  }

  generateColors();
}