on $*:TEXT:/^[.!@]count$/Si:#: {
  if (%maxu. [ $+ [ $chan ] ] == $null) { set %maxu. $+ $chan $nick($chan,0) $ctime }
  tokenize 32 %maxu. [ $+ [ $chan ] ] $iif($left($1,1) == @,msg $chan,.notice $nick)
  $3- $chan has $nick($chan,0) users: @Ops: $nick($chan,0,o) $(|) % $+ Halfops: $nick($chan,0,h,o) $(|) +Voices: $nick($chan,0,v,ho) $(|) Regulars: $nick($chan,0,r) $(|) Max users: $1 at $asctime($2,dd/mm/yyyy) $(|) Wilderness option: $calc($nick($chan,0,a,r) *3) options
}
on !*:JOIN:#: { if ($nick($chan,0) > $gettok(%maxu. [ $+ [ $chan ] ],1,32)) { set %maxu. $+ $chan $v1 $ctime } }
on $*:TEXT:/^[!.]setkey( .|$)/Si:#: {
  if ($nick isop $chan) {
    if ($2 == $null) {
      unset %warkey. $+ $chan
      msg $chan Key removed.
    }
    else {
      set %warkey. $+ $chan $2
      msg $chan Key changed to: $2
    }
  }
}
on $*:TEXT:/^[!.]setmsg( .|$)/Si:#: {
  if ($nick isop $chan) {
    if ($2 == $null) {
      unset %warmsg. $+ $chan
      msg $chan Kick message removed.
    }
    else {
      set %warmsg. $+ $chan $2-
      msg $chan Kick message changed to: $2-
    }
  }
}
on $*:TEXT:/^[!.](warkick|wk)$/Si:#: {
  if ($nick isop $chan) {
    if (($me !ishop $chan) && ($me !isop $chan)) { .notice $nick I can't do this because I'm not an op or halfop! }
    else {
      var %x = $nick($chan,0,r), %km = %warmsg. [ $+ [ $chan ] ]
      while (%x) {
        if ($nick($chan,%x,r) ison $chan) { kick $chan $v1 %km }
        dec %x
      }
      if (%warkey. [ $+ [ $chan ] ] !== $null) { mode $chan +k $v1 }
    }
  }
}