defmodule DateTimeGenerator do
  import StreamData

  @moduledoc """
  DateTimeGenerator generates Elixir `Date`s, `Time`s, `DateTime`s, and `NaiveDateTime`s to be used
  with property-based testing.
  """

  @defaults %{
    year_range: 1970..2050,
    month_range: 1..12,
    day_range: 1..31,
    hour_range: 1..23,
    minute_range: 1..59,
    second_range: 1..59,
    time_zones: ["Etc/UTC"]
  }

  def date(), do: date(@defaults)

  def date(%{} = opts) do
    opts = Map.merge(@defaults, opts)

    tuple({integer(opts.year_range), integer(opts.month_range), integer(opts.day_range)})
    |> bind_filter(fn tuple ->
      case Date.from_erl(tuple) do
        {:ok, date} -> {:cont, constant(date)}
        _ -> :skip
      end
    end)
  end

  def time(), do: time(@defaults)

  def time(%{} = opts) do
    opts = Map.merge(@defaults, opts)

    tuple({integer(opts.hour_range), integer(opts.minute_range), integer(opts.second_range)})
    |> map(&Time.from_erl!/1)
  end

  def naive_datetime(), do: naive_datetime(@defaults)

  def naive_datetime(%{} = opts) do
    opts = Map.merge(@defaults, opts)

    tuple({date(opts), time(opts)})
    |> map(fn {date, time} ->
      {:ok, naive_datetime} = NaiveDateTime.new(date, time)
      naive_datetime
    end)
  end

  def datetime(), do: datetime(@defaults)

  def datetime(%{} = opts) do
    opts = Map.merge(@defaults, opts)

    tuple({naive_datetime(opts), member_of(opts.time_zones)})
    |> map(fn {naive_datetime, time_zone} ->
      DateTime.from_naive!(naive_datetime, time_zone)
    end)
  end

end