alias power {
  var %a 1,%b 1,%c 0,%d 0,%e 0
  while (%a <= $scon(0)) {
    scon %a
    var %e $calc(%e + $chan(0))
    while (%b <= $chan(0)) {
      if ($me isop $chan(%b)) { var %c $calc(%c + $nick($chan(%b),0)) | inc %d | inc %b }
      inc %b
    }
    var %b 0
    inc %a
  }
  ;  echo -a I am op in %d $+ / %e channels on $scon(0) Networks. I currently pwn %c people.
  echo -a I am op in %d $+ / %e channels on 1 Network. I currently pwn %c people.

}

; ------------------------------
; Channel Clonescanner, v1.0 - By Segosa.
;
; -> EXPLANATION
;
; This script will scan a channel for
; clones (users connected to the server
; twice) and will echo each host and its
; clones in a colour coded and easy to
; read format.
;
; NOTE: This script will /who the channel
; before it starts scanning it. (This is to
; fill mIRC's IAL up with its addresses.
;
; -> INSTALLATION
;
; To load the script, place this file in
; your mIRC directory and type:
; /load -rs clonescan.mrc
;
; -> USAGE
;
; The syntax of the command is /cscan [#channel].
; if the channel is specified, it will scan for
; clones in there. Otherwise the script will scan
; the active channel.
;
; -> CONFIGURATION
;
; Configuration lines are in this format:
; alias cscan.NAME return VALUE
; where NAME is the name of the configuration
; option and VALUE is 1 (enabled) or 0 (disabled)
;
; Menu display:
;
; Enable this option if you want a Clonescan option
; to be added to each channel's right click menu.

alias cscan.menu return 1

; -> END OF CONFIGURATION
;
; DO NOT EDIT ANYTHING BELOW THIS UNLESS YOU KNOW WHAT YOU ARE DOING
; ------------------------------------------------------------------
; ------------------------------------------------------------------


alias cscan {
  var %d = linesep $iif($active == Status Window,-s,$active)
  if ((!$chan) && (!$1)) {
    %d | echo -ca ctcp * Error: specify a channel to scan for clones! | %d
    return
  }
  if (($1) && ($1 !ischan)) {
    %d | echo -ca ctcp * Error: you are not on the channel you specified | %d
    return
  }
  set %do_cscan $iif($1,$1,$chan)
  set %ds_cscan $iif($active == Status Window,status,$active)
  who %do_cscan
}

alias -l cscan2 {
  var %i = 1,%a
  var %tc = 0,%th = 0

  var %chan = $1

  linesep %chan
  cscan.echo -c ctcp %ds_cscan - Scanning for clones on %chan
  while (%i <= $nick(%chan,0)) {
    if ($ialchan($address($nick(%chan,%i),2),%chan,0) > 1) {
      if ($istok(%a,$remove($address($nick(%chan,%i),2),*!*@),32)) {
        inc %i
        continue
      }
      inc %th
      %a = $addtok(%a,$remove($address($nick(%chan,%i),2),*!*@),32)
      var %b = 1
      cscan.echo -c info %ds_cscan * Clones from $remove($address($nick(%chan,%i),2),*!*@) $+ :
      while (%b <= $ialchan($address($nick(%chan,%i),2),%chan,0)) {
        cscan.echo -c info %ds_cscan $chr(160) $+ $chr(160) $+ $chr(160) %b $+ . $ialchan($address($nick(%chan,%i),2),%chan,%b).nick ( $+ $ialchan($address($nick(%chan,%i),2),%chan,%b).user $+ )
        inc %b
        inc %tc
      }
    }
    inc %i
  }
  if (%tc > 0) dec %tc
  cscan.echo -c ctcp %ds_cscan - Finished scanning for clones, %tc clone $+ $iif(%tc != 1,s) from %th host $+ $iif(%th != 1,s) found
  linesep %chan
  unset %ds_cscan
}

alias -l cscan.echo {
  if ($3 == status) echo $1 $+ s $2 $4-
  else echo $1-
}

menu channel {
  $iif($cscan.menu,Clonescan): cscan
}

raw 315:*: {
  if (%do_cscan == $2) {
    unset %do_cscan
    cscan2 $2
    halt
  }
}

raw 352:*: if (%do_cscan) halt