//***************************************************
//TP 2
//***************************************************
 //*****************************************************
//affichage des systèmes d'équations linéaires
//*****************************************************

function str2=clean_complexe(str1)
//pour afficher correctement le coefficient de x_i
//cas général nombre complexe: (a+ib)x
// cas particuliers (réel ou imaginaire pur):  ax ou ibx
if grep(str1,'%i')<>[] then str2=strsubst(str1,'%i','i')
                            if (grep(str2,'+')<>[])|(grep(str2,'-')<>[]) then str2='('+str2+')'
                            end
                            str2=strsubst(str2,'*','')
                       else str2=str1
end
endfunction


function str2=un(str1)
//comme clean_complexe mais gère le cas particulier
//des coefficients  +1 et -1
if grep(str1,'%i')<>[] then str2=strsubst(str1,'%i','i')
                            if (grep(str2,'+')<>[])|(grep(str2,'-')<>[]) then str2='('+str2+')'
                            end
                            str2=strsubst(str2,'*','')
        elseif stripblanks(str1)=="1" then str2=" "
               elseif stripblanks(str1)=="-1" then str2="-"
                                              else str2=str1
end
endfunction

function sol=plus(bool)
//ecrire le signe + seulement si nécessaire!
if bool then sol=""
else sol="+"
end
endfunction


function L=affichage(A,y)
//affiche un système d'équations A*x=y
// à p équations et n inconnues
// sous forme de chaine de caractères
// avec les variables x_1,x_2,...,x_n
A=clean(A);
y=clean(y);
signe=sign(A);
abso=abs(A);
[p,n]=size(A);
//conversion des coefficients en chaines de caractères
//+justification à droite (tous les nombres ont la même "longueur")
B=justify(string(A),'r');
Y=justify(string(y),'r');
// transformation du système matriciel (A,y)
// en une liste L de p équations à n inconnues (x_1,x_2 ....x_n)
// cas particulier de la variable x_1 (pas de "+" devant les nombres positifs)
for i=1:p
    if signe(i,1)==0 then L(i)=''
                     else L(i)=un(B(i,1))+' x_1'
    end
end
L=justify(L,'r');
//traitement des variables x_2 jusqu'à x_n
//si le coefficient de x_j=0 alors on ne met rien
for j=2:n
    K=string(zeros(p,1))
    for i=1:p
        K(i)=''
        if signe(i,j)<>0 then
               if signe(i,j)==-1 then K(i)='  '+un(B(i,j));
                                 else bool=(sum(abso(i,1:j-1),'c')==0)|(signe(i,j)==-1);
                                      K(i)=plus(bool)+un(B(i,j));
               end
        end
    end
    K=justify(K,'r');
    for i=1:p
        if signe(i,j)<>0 then K(i)=K(i)+' x_'+string(j);
        end
    end
    L=L+justify(K,'r');
end
// second membre ....=y_i
for i=1:p
    if (sum(abso(i,:))==0) then L(i)='0';
    end
    L(i)=L(i)+'='+clean_complexe(Y(i))
end
L=justify(L,'r');
endfunction
 //******************************************************
// système de 3 équations linéaires à 3 inconnues
//******************************************************

A=[1 1 1; 1 -1 2; -1 2 1]
y=[2;9;-2]
affichage(A,y)
 //**************************************************
// Méthode de Gauss
//**************************************************
function [A,y]=permutation(A,y,i,l)
    line_i = A(i, :)
    A(i, :) = A(l, :)
    A(l, :) = line_i

    y_i = y(i)
    y(i) = y(l)
    y(l)= y_i
endfunction

function [A,y]=elimination(A,y,i,j)
    [p,n]=size(A)
    for k=i+1:p
        y(k)= A(i,j)*y(k)-A(k,j)*y(i)
        A(k,:)=A(i,j)*A(k,:)-A(k,j)*A(i,:)
    end
endfunction

function [A, y]=Gauss(A,y)
    [p,n]=size(A)
    i=1
    j=1
    while i<p && j<=n
        l=i;
        while A(l,j)==0
            if l<p
                l=l+1
            else
                if j<n
                    j=j+1
                    l=1
                else
                   i=p
                   j=n
                end
            end
        end
        if i<>l
            [A,y]=permutation(A,y,i,l)
        end
        [A,y]=elimination(A,y,i,j)
        i=i+1
        j=j+1
        disp(affichage(A,y))
    end
endfunction

function x=solvetrisup(A,y)
    //A matrice p*n triangulaire supérieure
    //y vecteur colonne à p lignes
    //x= solution de A*x=y ou [] sinon
endfunction