kernel-netbook PKGBUILD

# Maintainer: Dieghen89 <dieghen89@gmail.com>

pkgbase=kernel-netbook
pkgname=('kernel-netbook' 'kernel-netbook-headers')
_basekernel=2.6.34
pkgver=2.6.34
pkgrel=2
_kernver="$_basekernel-netbook"
arch=('i686')
license=('GPL2')
url=('http://code.google.com/p/kernel-netbook')
patchname=patch-${pkgver}-1-ARCH

md5sums=('10eebcb0178fb4540e2165bfd7efc7ad'
         '84c3297451b709a0ed97b40b2fca6fc5'
         '0466d863405e1ab99d5e288fe886e852'
         '654a8f089e4cef3eac9d343b112fa7e3'
         '28c0444733547d60aff8e9068c9b13d3')

#bfs_patch=$_basekernel-sched-bfs-313

######################
#  external drivers  #
######################

#Broadcom-wl:
broadcom_ver=5.60.48.36
broadcom=hybrid-portsrc-x86_32-v${broadcom_ver}
#stk11xx:
stk11xx_ver=2.1.0
stk11xx=stk11xx-$stk11xx_ver

##### Sources #####
source=(ftp://ftp.kernel.org/pub/linux/kernel/v2.6/linux-${_basekernel}.tar.bz2
    ftp://ftp.archlinux.org/other/kernel26/${patchname}.bz2
    http://www.broadcom.com/docs/linux_sta/${broadcom}.tar.gz
    http://switch.dl.sourceforge.net/sourceforge/syntekdriver/stk11xx-$stk11xx_ver.tar.gz
    config)
    #wl_linux.patch)
    #http://ck.kolivas.org/patches/bfs/$bfs_patch.patch)

build() {
#Section: Kernel
  cd ${srcdir}/linux-$_basekernel
  #patching the kernel with bfs scheduler
  #patch -Np1 < ${srcdir}/$bfs_patch.patch
  #patching the kernel with arch patchset
  patch -Np1 -i ${srcdir}/$patchname

  # copy config
  cp ../config ./.config

  make prepare

  # make defconfig
  # configure kernel
  # use menuconfig, if you want to change the configuration
  make menuconfig
  # make gconfig
  # yes "" | make config

  # build kernel
  make || return 1
}

package_kernel-netbook() {
  pkgdesc="Static kernel with KMS for netbooks with Intel Atom N270/N280/N450 such as eeepc with the add-on of external firmware (broadcom-wl, stk11xx) - Old kernel26-901 - Only Intel graphic card"
  depends=('coreutils' 'module-init-tools')
  install=kernel-netbook.install
  optdepends=('crda: for wireless regulatory domain support')
  groups=(eee)

  cd ${srcdir}/linux-$_basekernel
  # install our modules
  mkdir -p $pkgdir/{lib/modules,boot}
  make INSTALL_MOD_PATH=$pkgdir modules_install || return 1

  # remove the junk symlinks
  rm -r $pkgdir/lib/modules/$_kernver/{source,build}

  # install the kernel
  install -D -m644 ${srcdir}/linux-$_basekernel/System.map $pkgdir/boot/System.map-netbook
  install -D -m644 ${srcdir}/linux-$_basekernel/arch/x86/boot/bzImage ${pkgdir}/boot/vmlinuz-netbook
  install -D -m644 ${srcdir}/linux-$_basekernel/.config $pkgdir/boot/kconfig-netbook

  # set correct depmod command for install
  sed -i -e "s/KERNEL_VERSION=.*/KERNEL_VERSION=${_kernver}/g" $startdir/$pkgname.install

#Section: Broadcom-wl
  cd ${srcdir}/
  sed -i '190i\MODULE_LICENSE("Mixed/Proprietary"); \n' ${srcdir}/src/wl/sys/wl_linux.c
  #sed -i 's|#include <linux/autoconf.h>|#include <generated/autoconf.h>|' ${srcdir}/src/include/linuxver.h
  #patch ${srcdir}/src/wl/sys/wl_linux.c wl_linux.patch || return 1
  #patch -i ${srcdir}/wl_linux.patch ${srcdir}/src/include/linuxver.h

  sed -i '/linux\/autoconf.h/d' "$srcdir/src/include/linuxver.h"

  KBUILD_NOPEDANTIC=1 make -C ${srcdir}/linux-$_basekernel M=`pwd` || return 1
  install -D -m 755 wl.ko ${pkgdir}/lib/modules/$_kernver/kernel/drivers/net/wireless/wl.ko || return 1

#Section: stk11xx
  cd $srcdir/stk11xx-$stk11xx_ver || return 1
  make -C $srcdir/linux-${_basekernel}/ SUBDIRS=$srcdir/stk11xx-2.1.0 modules || return 1
  install -D -m 644 $srcdir/stk11xx-$stk11xx_ver/stk11xx.ko $pkgdir/lib/modules/$_kernver/kernel/drivers/media/video
  install -D -m 644 $srcdir/stk11xx-$stk11xx_ver/README $pkgdir/usr/share/stk11xx.readme
}

package_kernel-netbook-headers() {
  KARCH=x86
  pkgdesc="Header files and scripts for building modules for kernel-netbook"
  cd ${srcdir}/linux-$_basekernel
  mkdir -p ${pkgdir}/lib/modules/${_kernver}
  cd ${pkgdir}/lib/modules/${_kernver}
  ln -sf ../../../usr/src/linux-${_kernver} build
  cd ${srcdir}/linux-$_basekernel
  install -D -m644 Makefile \
    ${pkgdir}/usr/src/linux-${_kernver}/Makefile
  install -D -m644 kernel/Makefile \
    ${pkgdir}/usr/src/linux-${_kernver}/kernel/Makefile
  install -D -m644 .config \
    ${pkgdir}/usr/src/linux-${_kernver}/.config
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/include

  for i in acpi asm-generic config linux math-emu media net pcmcia scsi sound trace video; do
    cp -a include/$i ${pkgdir}/usr/src/linux-${_kernver}/include/
  done

  # copy arch includes for external modules
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/arch/x86
  cp -a arch/x86/include ${pkgdir}/usr/src/linux-${_kernver}/arch/x86/

  # copy files necessary for later builds, like nvidia and vmware
  cp Module.symvers ${pkgdir}/usr/src/linux-${_kernver}
  cp -a scripts ${pkgdir}/usr/src/linux-${_kernver}
  # fix permissions on scripts dir
  chmod og-w -R ${pkgdir}/usr/src/linux-${_kernver}/scripts
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/.tmp_versions

  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/kernel

  cp arch/$KARCH/Makefile ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/
  cp arch/$KARCH/Makefile_32.cpu ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/
  # add headers for lirc package
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video
  cp drivers/media/video/*.h  ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/
  for i in bt8xx cpia2 cx25840 cx88 em28xx et61x251 pwc saa7134 sn9c102 usbvideo zc0301; do
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/$i
  cp -a drivers/media/video/$i/*.h ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/$i
  done
  # add docbook makefile
  install -D -m644 Documentation/DocBook/Makefile \
    ${pkgdir}/usr/src/linux-${_kernver}/Documentation/DocBook/Makefile
  # add dm headers
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/md
  cp drivers/md/*.h  ${pkgdir}/usr/src/linux-${_kernver}/drivers/md
  # add inotify.h
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/include/linux
  cp include/linux/inotify.h ${pkgdir}/usr/src/linux-${_kernver}/include/linux/
  # add wireless headers
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/net/mac80211/
  cp net/mac80211/*.h ${pkgdir}/usr/src/linux-${_kernver}/net/mac80211/
  # add xfs and shmem for aufs building
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/fs/xfs
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/mm
  cp fs/xfs/xfs_sb.h ${pkgdir}/usr/src/linux-${_kernver}/fs/xfs/xfs_sb.h
  # add headers vor virtualbox
  # in reference to:
  # http://bugs.archlinux.org/task/14568
  cp -a include/drm $pkgdir/usr/src/linux-${_kernver}/include/
  # add headers for broadcom wl
  # in reference to:
  # http://bugs.archlinux.org/task/14568
  cp -a include/trace $pkgdir/usr/src/linux-${_kernver}/include/
  # copy in Kconfig files
  for i in `find . -name "Kconfig*"`; do
    mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/`echo $i | sed 's|/Kconfig.*||'`
    cp $i ${pkgdir}/usr/src/linux-${_kernver}/$i
  done

  # add header for aufs2-util
  cp -a ${srcdir}/linux-$_basekernel/include/asm-generic/bitsperlong.h ${pkgdir}/usr/src/linux-${_kernver}/include/asm/

  chown -R root.root ${pkgdir}/usr/src/linux-${_kernver}
  find ${pkgdir}/usr/src/linux-${_kernver} -type d -exec chmod 755 {} \;
  # remove unneeded architectures
  rm -rf ${pkgdir}/usr/src/linux-${_kernver}/arch/{alpha,arm,arm26,avr32,blackfin,cris,frv,h8300,ia64,m32r,m68k,m68knommu,mips,microblaze,mn10300,parisc,powerpc,ppc,s390,sh,sh64,sparc,sparc64,um,v850,xtensa}
}