# Maintainer: SpepS <dreamspepser at yahoo dot it>
# Contributor: Jonathan Conder <jonno dot conder at gmail dot com>

_pkgbasename=gtk-engine-murrine
pkgname=lib32-$_pkgbasename
pkgver=0.98.2
pkgrel=1
pkgdesc="GTK2 engine to make your desktop look like a 'murrina', an italian word meaning the art glass works done by Venicians glass blowers. Multilib."
arch=('x86_64')
url="http://cimitan.com/murrine/project/murrine"
license=('GPL')
depends=('lib32-gtk2' "$_pkgbasename")
makedepends=('gcc-multilib' 'intltool' 'perl')
options=('!libtool')
source=("http://ftp.gnome.org/pub/GNOME/sources/murrine/${pkgver%.*}/murrine-$pkgver.tar.xz")
md5sums=('bf01e0097b5f1e164dbcf807f4b9745e')

build() {

  export CC='gcc -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

  cd "$srcdir/murrine-$pkgver"

  ./configure \
	--prefix=/usr \
	--libdir=/usr/lib32 \
	--enable-animation \
	--enable-animationrtl


  make
}

package() {

  cd "$srcdir/murrine-$pkgver"

  make DESTDIR="$pkgdir" install
  rm -rf "$pkgdir/usr/share"
}