FORM confirm_delivery USING iv_deliv TYPE vbeln iv_vbtyp TYPE vbtypl.

  DATA: ls_vbkok  TYPE vbkok,
        lt_vbpok  TYPE TABLE OF vbpok,
        ls_vbpok  TYPE vbpok,
        lv_error  TYPE c,
        lt_return TYPE TABLE OF prott.

  FIELD-SYMBOLS <fs_status> TYPE zsd_pod_status.
  CLEAR lt_prot.

  "Pobranie pozycji z dostawy
  SELECT vbeln, posnr, vgbel, vgpos, matnr, werks, lfimg
       FROM lips
       INTO TABLE @DATA(lt_deliv)
       WHERE vbeln = @iv_deliv.

  CHECK sy-subrc = 0.

  ASSIGN COMPONENT gv_log_name OF STRUCTURE ls_logs TO <fs_status>.

*  CHECK <fs_status> = 'D' OR <fs_status> = 'E'.

  SELECT SINGLE wbstk
  FROM likp
  INTO @DATA(lv_wbstk)
  WHERE vbeln = @iv_deliv.
  IF sy-subrc = 0 AND lv_wbstk = 'C'.
    "Ta dostawa już jest potwierdzona, idziemy do kolejnego kroku
    <fs_status> = 'X'.
    EXIT.
  ENDIF.

  ls_vbkok-vbeln_vl = iv_deliv.
  ls_vbkok-vbtyp_vl = iv_vbtyp.
  ls_vbkok-wabuc    = 'X'.
  ls_vbkok-komue    = 'X'.

  IF r_late = 'X'.
    ls_vbkok-wadat_ist = sy-datum.
  ELSE.

    ls_vbkok-wadat_ist = ls_likp-wadat.

    IF ls_vbkok-wadat_ist < sy-datum.
      ls_vbkok-bldat     = ls_likp-wadat.
    ENDIF.

  ENDIF.

  LOOP AT lt_deliv INTO DATA(ls_lips).

    CLEAR ls_vbpok.
    ls_vbpok-vbeln_vl = ls_lips-vbeln. " Delivery No
    ls_vbpok-posnr_vl = ls_lips-posnr. " Delivery Item
    ls_vbpok-vbeln    = ls_lips-vgbel. " Sales order - Ref Doc
    ls_vbpok-posnn    = ls_lips-vgpos. " SO Line item - Ref doc item
    ls_vbpok-matnr    = ls_lips-matnr. " Material No
    ls_vbpok-werks    = ls_lips-werks. " Plant
    ls_vbpok-pikmg    = ls_lips-lfimg. " Delivery Qty

    APPEND ls_vbpok TO lt_vbpok.

  ENDLOOP.

  CALL FUNCTION 'WS_DELIVERY_UPDATE'
    EXPORTING
      vbkok_wa                 = ls_vbkok
      delivery                 = iv_deliv
      if_error_messages_send_0 = space
    IMPORTING
      ef_error_any_0           = lv_error
    TABLES
      vbpok_tab                = lt_vbpok
      prot                     = lt_return.

  COMMIT WORK AND WAIT.

endform.