Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- ; =========================================================================
- ; Pallete Fading Engine
- ; (C) 2011, Vladikcomper
- ; =========================================================================
- *sysPallete equ $FFFFFB00 ; Pallete Array
- *sysPalleteBuff equ $FFFFFB80 ; Target Pallete Array
- PalEngine_FadeLen equ $FFFFF626 ; b Fading length (bytes - 1)
- PalEngine_FadeFactor equ $FFFFF627 ; b Fade Factor (max = $10)
- ; =========================================================================
- ; =========================================================================
- ; -------------------------------------------------------------------------
- ; Cycle to fade to target palette
- ; -------------------------------------------------------------------------
- Pal_FadeTo move.b #$40-1,(PalEngine_FadeLen).w ; -- default length
- lea (sysPallete).w,a0
- lea $80(a0),a1
- Pal_FadeTo2 ; -- custom length
- move.b #$10,(PalEngine_FadeFactor).w ; do $10 frames
- @FadeLoop move.b #$12,($FFFFF62A).w
- bsr.w DelayProgram
- subq.b #1,(PalEngine_FadeFactor).w ; decrease fading power
- bmi.s @Return ; if fading is done, quit
- bsr.s Pal_SingleFadeTo
- bra.s @FadeLoop
- @Return rts
- ; =========================================================================
- ; -------------------------------------------------------------------------
- ; Perform fading to palette in a signle frame
- ; -------------------------------------------------------------------------
- ; a0 - Current palette
- ; a1 - Target palette
- ; -------------------------------------------------------------------------
- Pal_SingleFadeTo
- moveq #0,d5
- move.b (PalEngine_FadeLen).w,d5
- move.b (PalEngine_FadeFactor).w,d0 ; d0 -> Fade Factor
- andi.b #$E,d0 ; make sure fade factor is correct
- move.b d0,d1
- lsl.b #4,d1 ; d1 -> Fade Factor (2nd channel)
- lea (a0),a2 ; current active color
- lea (a1),a3 ; current target color
- @ParseColors:
- move.b (a3)+,d2 ; d2 -> B
- sub.b d0,d2 ; d2 -> B' (faded)
- bcc.s @outB
- moveq #0,d2
- @outB: move.b d2,(a2)+ ; output B'
- move.b (a3)+,d2 ; d2 -> GR
- move.b d2,d3
- andi.b #$E0,d3 ; d3 -> G0
- sub.b d1,d3 ; d3 -> G'0
- bcc.s @endG
- moveq #0,d3
- @endG:
- andi.b #$E,d2 ; d2 -> R
- sub.b d0,d2 ; d2 -> R'
- bcc.s @endR
- moveq #0,d2
- @endR:
- or.b d2,d3 ; d3 -> G'R'
- move.b d3,(a2)+ ; output G'R'
- dbf d5,@ParseColors
- rts
- ; =========================================================================
- ; -------------------------------------------------------------------------
- ; Cycle to fade from screen
- ; -------------------------------------------------------------------------
- Pal_FadeFrom move.b #$40-1,(PalEngine_FadeLen).w ; -- default length
- lea (sysPallete).w,a0
- Pal_FadeFrom2 ; -- custom length
- moveq #$10-1,d6 ; d6 -> do 16 frames
- @FadeLoop move.b #$12,($FFFFF62A).w
- bsr.w DelayProgram
- btst #0,d6 ; is d6 odd?
- beq.s @NextFrame ; if not, branch
- bsr.s Pal_SingleFadeFrom
- @NextFrame dbf d6,@FadeLoop
- rts
- ; =========================================================================
- ; -------------------------------------------------------------------------
- ; Perform fading to palette in a signle frame
- ; -------------------------------------------------------------------------
- ; a0 - Current palette
- ; -------------------------------------------------------------------------
- Pal_SingleFadeFrom
- lea (a0),a2 ; current color
- moveq #0,d5
- move.b (PalEngine_FadeLen).w,d5
- @ParseColors:
- tst.b (a2)+ ; is B zero?
- beq.s @Green ; if yes, branch
- subq.b #2,-1(a2) ; decrease B
- @Green: move.b (a2),d2 ; d2 -> GR
- move.b d2,d3
- andi.b #$E0,d2 ; d2 -> G0
- beq.s @Red
- subi.b #$20,d2
- @Red: andi.b #$E,d3 ; d3 -> 0R
- beq.s @GRout
- subq.b #2,d3
- @GRout: or.b d2,d3
- move.b d3,(a2)+
- dbf d5,@ParseColors
- rts
Add Comment
Please, Sign In to add comment
