PKGBUILD z-push-2.1.3-1892

# Contributor: C Anthony Risinger
# Contributer: Jörg Thalheim <joerg@higgsboson.tk>

pkgname=z-push
pkgver=2.1.3
pkgrel=1892
pkgdesc="open-source implementation of the ActiveSync protocol"
arch=('any')
url="http://z-push.sf.net/"
license=('AGPL3')
depends=('php')
install=z-push.install
backup=('etc/webapps/z-push/config.php'
        'etc/webapps/z-push/.htaccess'
        'etc/webapps/z-push/apache.conf'
        'etc/webapps/z-push/nginx.conf')
options=('!strip')
source=("http://download.z-push.org/final/2.1/${pkgname}-${pkgver}-${pkgrel}.tar.gz"
        "apache.conf"
        "nginx.conf"
        "htaccess"
        "z-push.ini")

md5sums=('a5bc26143cf1961988bbff1eb1442d98'
         '32a459bd61135b6c5e99e82e3a6b0007'
         'e768c5ed6e631d18e156f94b3bc46948'
         '1091aa1ba272ef05bf628f73b05c527a'
         'ceaa699636b0de6d678a2cf3af264d2b')

package() {
  mkdir -p ${pkgdir}/etc/webapps/z-push
  mkdir -p ${pkgdir}/etc/php/conf.d
  mkdir -p ${pkgdir}/usr/share/webapps/z-push
  mkdir -p ${pkgdir}/var/{lib,log}/z-push
  cd ${pkgdir}/usr/share/webapps/

  cp -r ${srcdir}/${pkgname}-${pkgver}-${pkgrel}/* z-push

  mv z-push/config.php ${pkgdir}/etc/webapps/z-push/config.php
  ln -s /etc/webapps/z-push/config.php z-push/config.php

  cp ${srcdir}/htaccess ${pkgdir}/etc/webapps/z-push/.htaccess
  ln -s /etc/webapps/z-push/.htaccess z-push/.htaccess

  cp ${srcdir}/{apache,nginx}.conf ${pkgdir}/etc/webapps/z-push/

  cp ${srcdir}/z-push.ini  ${pkgdir}/etc/php/conf.d/
}
~
~
~
~
~
~